main.coffee

   1 #   HexBog, a word game
   2 #   Copyright (C) 2012 Jason Woofenden
   3
   4 #   This program is free software: you can redistribute it and/or modify
   5 #   it under the terms of the GNU Affero General Public License as published by
   6 #   the Free Software Foundation, either version 3 of the License, or
   7 #   (at your option) any later version.
   8
   9 #   This program is distributed in the hope that it will be useful,
  10 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 #   GNU Affero General Public License for more details.
  13
  14 #   You should have received a copy of the GNU Affero General Public License
  15 #   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16
  17 ##############################################
  18 ##############    settings    ################
  19 ##############################################
  20
  21 tile_radius = 26
  22 tile_width = tile_radius * 2
  23
  24 fade_ms = 400
  25 slide_ms = 2000
  26
  27 board_col_heights = [5, 6, 7, 8, 7, 6, 5]
  28
  29
  30 ##############################################################
  31 ##############    fix javascript some more    ################
  32 ##############################################################
  33
  34 # so annoying that setTimeout has its arguments in the wrong order
  35 timeout = (ms, callback) ->
  36         setTimeout callback, ms
  37
  38 # warning: it's shalow (sub-elements are not cloned)
  39 Array::clone = ->
  40         return this.slice(0)
  41
  42 Array::sum = ->
  43         ret = 0
  44         ret += i for i in this
  45         return ret
  46
  47 # ascending. All values must be Numbers
  48 Array::num_sort = -> return this.sort((a, b) -> return a - b)
  49
  50 Array::last = ->
  51         return this[this.length - 1]
  52
  53
  54 ##############################################################
  55 ##############    cookies (auto-save game)    ################
  56 ##############################################################
  57
  58 set_cookie = (name, value, days) ->
  59         date = new Date()
  60         date.setTime date.getTime()+(days*24*60*60*1000)
  61         cookie = "#{name}=#{value}; expires=#{date.toGMTString()}; path=/"
  62         document.cookie = cookie
  63 window.sc = set_cookie
  64
  65 get_cookie = (name) ->
  66         key = name + '='
  67         for c in document.cookie.split /; */
  68                 if c.indexOf key is 0
  69                         return c.substr key.length
  70         return null
  71
  72 delete_cookie = (name) ->
  73         set_cookie name, '', -1
  74 window.dc = delete_cookie
  75
  76
  77 board_cols = board_col_heights.length
  78 board_tiles = board_col_heights.sum()
  79 board_col_top_px = []
  80 score = 0
  81 board = new Array(board_tiles) # letters ("Qu" or single letter)
  82 board_neighbors = [] # array of tile numbers "next to" this one
  83 tile_top_px = [] # array of pixel coordinates for top of column
  84 board_left_px = [] # array of pixel coordinates for left of column
  85 board_aboves = [] # array of tile numbers above, starting from top
  86 board_below = [] # tile number of next tile below or false
  87
  88 selected = []
  89
  90 letters = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
  91 letter_distribution = [
  92         14355 # a
  93          3968 # b
  94          6325 # c
  95          7045 # d
  96         20258 # e
  97          2739 # f
  98          5047 # g
  99          4372 # h
 100         13053 # i
 101           516 # j
 102          2600 # k
 103          9631 # l
 104          5115 # m
 105         10082 # n
 106         11142 # o
 107          5292 # p
 108           287 # qu
 109         12341 # r
 110         16571 # s
 111         10215 # t
 112          6131 # u
 113          1728 # v
 114          2184 # w
 115           619 # x
 116          3512 # y
 117           831 # z
 118
 119 ]
 120
 121 letter_distribution_total = 175973 # letter_distribution.sum()
 122
 123
 124 new_letter_queue = []
 125 new_letter = ->
 126         if new_letter_queue.length
 127                 l = new_letter_queue.shift()
 128                 if l is 'Q'
 129                         return 'Qu'
 130                 else
 131                         return l
 132         r = Math.floor Math.random() * (letter_distribution_total + 1)
 133         for i in [0..25]
 134                 r -= letter_distribution[i]
 135                 if r <= 0
 136                         if letters[i] is 'Q'
 137                                 return 'Qu'
 138                         return letters[i]
 139         return 'Z' # just in case
 140
 141
 142
 143 # in memory it's layed out like this:
 144 # a c f j m
 145 # b d g k n
 146 #   e h l
 147 #     i
 148 # for display, columns are slid vertically like so:
 149 #       f
 150 #     c   j
 151 #   a   g   m
 152 #     d   k
 153 #   b   h   n
 154 #     e   l
 155 #       i
 156 #
 157 # work out which grid spaces are connected
 158 init_board_layout = () ->
 159         col_offset = 0
 160         middle_col = (board_cols - 1) / 2
 161
 162         # how many tiles before the current tile?
 163         for col_num in [0 .. board_cols - 1]
 164                 if col_num < middle_col
 165                         fw_other = 1
 166                 else
 167                         fw_other = -1
 168
 169                 if col_num > middle_col
 170                         bw_other = 1
 171                 else
 172                         bw_other = -1
 173
 174                 is_first_col = col_num is 0
 175                 is_last_col = col_num is board_cols - 1
 176
 177                 neighbors = []
 178                 push = (offset) ->
 179                         neighbors.push col_offset + offset
 180
 181                 col_top_px = Math.abs col_num - middle_col
 182                 col_top_px *= tile_radius
 183                 board_col_top_px.push col_top_px
 184
 185                 above = []
 186                 for i in [0 .. board_col_heights[col_num] - 1]
 187                         is_top_tile = i is 0
 188                         is_bottom_tile = i is board_col_heights[col_num] - 1
 189
 190                         # link tile number to pixel "top" and "left" of containing column
 191                         tile_top_px.push col_top_px + i * tile_width
 192                         board_left_px.push col_num * tile_width
 193
 194                         # aboves (array of tile numbers above, starting from top)
 195                         board_aboves.push above.clone()
 196                         above.push i + col_offset
 197
 198                         # below (SINGLE tile number of tile below or false)
 199                         if is_bottom_tile
 200                                 board_below.push false
 201                         else
 202                                 board_below.push col_offset + i + 1
 203
 204                         # neighbors (array of tile numbers "next to" this one)
 205                         neighbors = []
 206                         unless is_top_tile # upward link
 207                                 push i - 1
 208                         unless is_bottom_tile # downward links
 209                                 push i + 1
 210                         unless is_first_col # leftward links
 211                                 unless is_bottom_tile and bw_other is -1
 212                                         push i - board_col_heights[col_num - 1]
 213                                 unless is_top_tile and bw_other is -1
 214                                         push i - board_col_heights[col_num - 1] + bw_other
 215                         unless is_last_col # rightward links
 216                                 unless is_bottom_tile and fw_other is -1
 217                                         push i + board_col_heights[col_num]
 218                                 unless is_top_tile and fw_other is -1
 219                                         push i + board_col_heights[col_num] + fw_other
 220
 221                         board_neighbors.push neighbors.clone()
 222
 223                 col_offset += board_col_heights[col_num]
 224
 225
 226 init_board = ->
 227         encoded = window.location.hash
 228         if encoded? and encoded.charAt 0 is '#'
 229                 encoded = encoded.substr 1
 230         unless encoded? and encoded.length > board_tiles
 231                 encoded = get_cookie 'hexbog'
 232         if encoded? and encoded.length > board_tiles
 233                 new_letter_queue = (encoded.substr 0, board_tiles).split ''
 234                 score = parseInt(encoded.substr(board_tiles), 10)
 235
 236         # work out which grid spaces are connected
 237         # (neighbors, above, down)
 238         init_board_layout()
 239
 240 $selection_display = null # initialized by init_html_board
 241 $score_display = null # initialized by init_html_board
 242 $definition_body = null # initialized by init_html_board
 243 update_selection_display = ->
 244         word = selected_word()
 245         $selection_display.html word
 246
 247         # color the selected tiles according to whether they're a word or not
 248         if word.length
 249                 classes = ['selected_word', 'selected']
 250                 if is_word word
 251                         c = 0
 252                 else
 253                         c = 1
 254                 for num in selected
 255                         html_tiles[num].addClass classes[c]
 256                         html_tiles[num].removeClass classes[1 - c]
 257
 258 # unselects the last tile of the selecetion
 259 unselect_tile = ->
 260         _unselect_tile()
 261         update_selection_display()
 262
 263 _unselect_tile = ->
 264         num = selected.pop()
 265         html_tile = html_tiles[num]
 266         html_tile.removeClass 'selected_word'
 267         html_tile.removeClass 'selected'
 268
 269 unselect_all = ->
 270         while selected.length
 271                 _unselect_tile()
 272         update_selection_display()
 273
 274 shrink_selection = (leave_count) ->
 275         while selected.length > leave_count
 276                 _unselect_tile()
 277         update_selection_display()
 278
 279 selected_word = ->
 280         word = ''
 281         word += board[i] for i in selected
 282         return word.toLowerCase()
 283
 284 save_game = ->
 285         encoded = ''
 286         for t in board
 287                 encoded += t.substr 0, 1
 288         encoded += score
 289         set_cookie 'hexbog', encoded, 365
 290         window.location.hash = encoded
 291
 292 # remove the selected tiles from the board, create new tiles, and slide everything into place
 293 blip_selection = ->
 294         faders = selected.num_sort()
 295         selected = []
 296         update_selection_display()
 297         for i in faders
 298                 html_tiles[i].unbind('click').fadeOut fade_ms
 299         timeout fade_ms + 1, ->
 300                 # which tiles need to be slid down
 301                 sliders = (false for i in board)
 302
 303                 prev_col_top = null
 304                 next_new_y = null
 305                 for deleted in faders
 306                         # find the tile number of the top tile in this column
 307                         if board_aboves[deleted].length is 0
 308                                 col_top = deleted
 309                         else
 310                                 col_top = board_aboves[deleted][0]
 311
 312                         # reset location where new tiles appear when we change columns
 313                         if prev_col_top isnt col_top
 314                                 next_new_y = -10 - tile_width
 315                                 prev_col_top = col_top
 316
 317                         html_tiles[deleted].remove()
 318
 319                         # For each each tile above the one we've deleted:
 320                         # 1. move it down one slot in the data scructures
 321                         # 2. mark it as needing to slide
 322                         dest = deleted
 323                         aboves = board_aboves[deleted].clone().reverse()
 324                         for above in aboves
 325                                 html_tiles[dest] = html_tiles[above]
 326                                 html_tiles[dest].data 'tile_number', dest
 327                                 board[dest] = board[above]
 328                                 sliders[dest] = true
 329                                 --dest
 330                         sliders[col_top] = true # the new tile needs to be slid down too
 331
 332                         new_tile col_top, board_left_px[col_top], next_new_y
 333                         next_new_y -= tile_width + 50
 334
 335                 for slide, i in sliders
 336                         if slide
 337                                 html_tiles[i].animate {top: "#{tile_top_px[i]}px"}, slide_ms
 338                                 sliders[i] = false
 339                 save_game()
 340
 341 activate_selection = ->
 342         word = selected_word()
 343         if word.length < 3
 344                 # FIXME make this a hint
 345                 log "Too short: \"#{word}\""
 346                 return
 347         unless is_word word
 348                 # FIXME make this automatically part of the selection display
 349                 log "Not on word list: \"#{word}\""
 350                 return
 351         word_score = Math.round(Math.pow(1.7, word.length))
 352         score += word_score
 353         $score_display.html score
 354         # FIXME make some kind of animation showing score gain
 355         log "blipped \"#{word}\" for #{word_score} points"
 356         blip_selection()
 357         look_up_definition word
 358         $('#definition').click()
 359
 360
 361 show_definition = (word, type, definition, language) ->
 362         html = "<a href=\"http://en.wiktionary.org/wiki/#{word}\" target=\"_blank\">"
 363         html += "#{word.substr(0, 1).toUpperCase() + word.substr(1)}</a>, #{type}"
 364         if language isnt 'English'
 365                 html += " (#{language})"
 366         html += ': '
 367         html += definition
 368         html += '<div id="definition_credit">Definition &copy;<a href="http://en.wiktionary.org/" target="_blank">wiktionary.org</a> CC-BY-SA</div>'
 369         $definition_body.html html
 370
 371
 372 select_tile = (num) ->
 373         html_tile = html_tiles[num]
 374         # html_tile.css backgroundColor: tile_selected_color
 375         selected.push num
 376         update_selection_display()
 377         return
 378
 379 new_tile = (num, x, y) ->
 380         letter = new_letter()
 381
 382         html_tile = $("<div class=\"tile\" style=\"left: #{x}px; top: #{y}px\" unselectable=\"on\">#{letter}</div>")
 383         $board.append(html_tile)
 384
 385         html_tile.data 'tile_number', num
 386         board[num] = letter
 387         html_tiles[num] = html_tile
 388
 389         html_tile.click ->
 390                 me = $(this)
 391                 num = me.data 'tile_number'
 392                 if num in selected
 393                         nth_of_word = selected.indexOf(num)
 394                         first = nth_of_word is 0
 395                         last = nth_of_word is selected.length - 1
 396
 397                         if first and last
 398                                 unselect_all() # Clicking only selected letter unselects it
 399                         else if first and !last
 400                                 shrink_selection 1 # Clicking start of word goes back to just that letter
 401                                 # should this unselect all?
 402                         else if last
 403                                 activate_selection()
 404                         else
 405                                 shrink_selection nth_of_word + 1
 406                 else # (not clicking on selected tile)
 407                         if selected.length is 0
 408                                 select_tile num
 409                         else
 410                                 unless num in board_neighbors[selected.last()]
 411                                         unselect_all()
 412                                 select_tile num
 413
 414
 415 $board = null
 416 html_tiles = []
 417 init_html_board = ->
 418         $('#loading').remove()
 419         $selection_display = $('#selection')
 420         $score_display = $('#score')
 421         $score_display.html score
 422         $definition_body = $('#definition_body')
 423         $board = $('#board')
 424         # make html for board
 425         tile_number = 0
 426         for col_num in [0 .. board_cols - 1]
 427                 for num in [0 .. board_col_heights[col_num] - 1]
 428                         x = col_num * tile_width
 429                         y = board_col_top_px[col_num] + num * tile_width
 430                         new_tile tile_number, x, y
 431                         tile_number++
 432
 433 word_bins = []; word_bins.push(',') for [0...997]
 434 hash_word = (word) ->
 435         h = 0
 436         for i in [0...word.length]
 437                 h ^= word.charCodeAt(i) << ((i*3) % 21)
 438         return h % 997
 439 is_word = (str) ->
 440         word_bins[hash_word str].indexOf(",#{str},") > -1
 441
 442 # this is called automatically by the compressed wordlist
 443 parse_word_list = (compressed) ->
 444         prefix = ''
 445         cap_a = "A".charCodeAt 0
 446         i = 0
 447         next_chunk = ->
 448                 chunk = compressed[i]
 449                 for word in chunk.match(/[a-z]*[A-Z]/g)
 450                         # the capital letter (at the end of the match) says how many characters
 451                         # from the end of the previous word should be removed to create the prefix
 452                         # for the next word. "A" for 0, "B" for 1, "C" for 2, etc
 453                         bs = word[word.length - 1].charCodeAt(0) - cap_a
 454                         word = prefix + word[0 ... word.length - 1]
 455                         word_bins[hash_word word] += word + ','
 456                         prefix = word[0 ... word.length - bs]
 457                 if ++i is compressed.length
 458                         return
 459                 else
 460                         timeout 1, next_chunk
 461         timeout 1, next_chunk
 462
 463 extract_wiktionary_definiton = (html) ->
 464         found = false
 465         finds = {}
 466         language = false
 467         part = false
 468
 469         # clean HTML
 470         ##################
 471         # when we instantiate the html so we can use dom traversal, the browser
 472         # will start loading images and such. This section attempts to mangle the
 473         # html so no resources are loaded when the html is parsed.
 474
 475         # attributes
 476         #                            src: <img>, <audio>, etc
 477         #                         onload: only <body>?
 478         #   archive,codebase,data,usemap: <object>
 479         #                           href: <link>
 480         #                 id,class,style: background: url(foo.png), etc
 481         html = html.replace /(src|onload|archive|codebase|data|usemap|href|style|id|class)=['"][^"']*['"]/ig, '', html
 482
 483         elements = $(html)
 484
 485         valid_parts = ["Abbreviation", "Adjective", "Adverb", "Article", "Cardinal number", "Conjunction", "Determiner", "Interjection", "Noun", "Numeral", "Particle", "Preposition", "Pronoun", "Verb"]
 486
 487         edit_link_regex = new RegExp(' ?\\[edit\\] ?')
 488
 489         elements.each (i, el) ->
 490                 #which tag: el.tagName
 491                 if el.tagName is 'H2'
 492                         # if we found a definition in the previous language section, run with it
 493                         # (we only stop for verbs, in hopes of finding one in english)
 494                         if found
 495                                 return false # break
 496                         part = false # mark us not being in a definition section unless the next section finds a part of speach header
 497                         language = $(el).text().replace(edit_link_regex, '')
 498                 if language and el.tagName is 'H3' or el.tagName is 'H4' # eg yak def uses one for english and one for dutch
 499                         part = false
 500                         text = $(el).text().replace(edit_link_regex, '')
 501                         for p in valid_parts
 502                                 if text is "#{p}"
 503                                         part = p.toLowerCase()
 504                                         # FIXME break
 505                 if part and el.tagName is 'OL'
 506                         $(el).children().each (i, el) ->
 507                                 new_def = $(el).text()
 508                                 if new_def.substr(0, 9) is '(obsolete' or new_def.substr(0, 8) is "(archaic"
 509                                         key = 'obsolete'
 510                                 else
 511                                         if part is 'verb'
 512                                                 key = 'verb'
 513                                         else
 514                                                 key = 'nonverb'
 515                                 finds[key] ?= [part, new_def, language]
 516                                 found = true
 517                                 if part is 'verb'
 518                                         # verbs are the best! stop scanning when we find one
 519                                         return false # break
 520                         if found.verb
 521                                 return false # break
 522
 523         part_defs = (finds[i] for i in ['verb', 'nonverb', 'obsolete'] when finds[i])
 524         unless part_defs.length
 525                 return false
 526
 527         return part_defs[0]
 528
 529
 530 look_up_definition = (word) ->
 531         $definition_body.html "Looking up definition for \"#{word}\"."
 532         $.ajax({
 533                 url: "http://en.wiktionary.org/w/api.php?action=parse&format=json&page=#{word}"
 534                 jsonpCallback: "lud_#{word}" # always use the same callback for the same word so it's cacheable
 535                 dataType: 'jsonp'
 536                 cache: true
 537                 success: (data, error_msg, xhr) ->
 538                         if data?.parse?.text?['*']?
 539                                 tdl = extract_wiktionary_definiton data.parse.text['*']
 540                                 if tdl
 541                                         show_definition word, tdl[0], tdl[1], tdl[2]
 542                                 else
 543                                         $definition_body.html "Oops, could't find a definition for \"#{word}\"."
 544                         else
 545                                 $definition_body.html "Sorry, couldn't find a definition for \"#{word}\"."
 546         })
 547
 548 board_as_txt = ->
 549         ret = ''
 550         index = 0
 551         for i in [0 .. board_min_height * 2]
 552                 unless i % 2
 553                         ret += '   ' + board[j] for j in [board_min_height + index .. board_tiles - 1] by 2 * board_min_height + 1
 554                 else
 555                         ret += ' ' + board[j] + '  ' for j in [index .. board_tiles - 1] by 2 * board_min_height + 1
 556                         index += 1
 557
 558                 ret += '\n'
 559         return ret
 560
 561 start_over = ->
 562         selected = []
 563         score = 0
 564         $score_display.html score
 565         for i in [0...board_tiles]
 566                 selected.push i
 567         blip_selection()
 568
 569 init_start_over_link = ->
 570         $('#start-over').click (event) ->
 571                 event.preventDefault()
 572                 if confirm "Are you sure you want to start over? There is no undo."
 573                         start_over()
 574
 575 cur_tab = 'instructions'
 576 tabtab_height = 20
 577 tab_height = 150
 578 init_tab = (t) ->
 579         $('#' + t).click ->
 580                 return if t is cur_tab
 581                 $('#' + cur_tab).removeClass('selected-tab').addClass('tab').animate({height: tabtab_height}, 1000)
 582                 $('#' + t).removeClass('tab').addClass('selected-tab').animate({height: tab_height}, 1000)
 583                 cur_tab = t
 584 init_tabs = ->
 585         for t in ['instructions', 'definition', 'donate', 'restart']
 586                 init_tab t
 587
 588 init_keybinding = ->
 589         $(window).keydown (e) ->
 590                 switch e.keyCode
 591                         when 32, 10, 13
 592                                 activate_selection()
 593                         when 27
 594                                 unselect_all()
 595
 596 $log = undefined
 597 init_log = ->
 598         $log = $('#log')
 599 log = (msg) ->
 600         console.log msg if console.log?
 601
 602 init_game = ->
 603         init_log()
 604         if $(window).height() >= 440
 605                 $('#centerer').css('margin-top', '25px')
 606         init_keybinding()
 607         init_tabs()
 608         init_board()
 609         init_html_board()
 610         init_start_over_link()
 611
 612 $(init_game)