main.coffee

   1 #   HexBog, a word game
   2 #   Copyright (C) 2012 Jason Woofenden
   3
   4 #   This program is free software: you can redistribute it and/or modify
   5 #   it under the terms of the GNU Affero General Public License as published by
   6 #   the Free Software Foundation, either version 3 of the License, or
   7 #   (at your option) any later version.
   8
   9 #   This program is distributed in the hope that it will be useful,
  10 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 #   GNU Affero General Public License for more details.
  13
  14 #   You should have received a copy of the GNU Affero General Public License
  15 #   along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16
  17 ##############################################
  18 ##############    settings    ################
  19 ##############################################
  20
  21 tile_radius = 26
  22 tile_width = tile_radius * 2
  23
  24 fade_ms = 400
  25 slide_ms = 2000
  26
  27 board_col_heights = [5, 6, 7, 8, 7, 6, 5]
  28
  29
  30 ##############################################################
  31 ##############    fix javascript some more    ################
  32 ##############################################################
  33
  34 # so annoying that setTimeout has its arguments in the wrong order
  35 timeout = (ms, callback) ->
  36         setTimeout callback, ms
  37
  38 # warning: it's shalow (sub-elements are not cloned)
  39 Array::clone = ->
  40         return this.slice(0)
  41
  42 Array::sum = ->
  43         ret = 0
  44         ret += i for i in this
  45         return ret
  46
  47 # ascending. All values must be Numbers
  48 Array::num_sort = -> return this.sort((a, b) -> return a - b)
  49
  50 Array::last = ->
  51         return this[this.length - 1]
  52
  53
  54 ##############################################################
  55 ##############    cookies (auto-save game)    ################
  56 ##############################################################
  57
  58 set_cookie = (name, value, days) ->
  59         date = new Date()
  60         date.setTime date.getTime()+(days*24*60*60*1000)
  61         cookie = "#{name}=#{value}; expires=#{date.toGMTString()}; path=/"
  62         document.cookie = cookie
  63 window.sc = set_cookie
  64
  65 get_cookie = (name) ->
  66         key = name + '='
  67         for c in document.cookie.split /; */
  68                 if c.indexOf key is 0
  69                         return c.substr key.length
  70         return null
  71
  72 delete_cookie = (name) ->
  73         set_cookie name, '', -1
  74 window.dc = delete_cookie
  75
  76
  77 board_cols = board_col_heights.length
  78 board_tiles = board_col_heights.sum()
  79 board_col_top_px = []
  80 score = 0
  81 board = new Array(board_tiles) # letters ("Qu" or single letter)
  82 board_neighbors = [] # array of tile numbers "next to" this one
  83 tile_top_px = [] # array of pixel coordinates for top of column
  84 board_left_px = [] # array of pixel coordinates for left of column
  85 board_aboves = [] # array of tile numbers above, starting from top
  86 board_below = [] # tile number of next tile below or false
  87
  88 selected = []
  89
  90 letters = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
  91 letter_distribution = [
  92         14355 # a
  93          3968 # b
  94          6325 # c
  95          7045 # d
  96         20258 # e
  97          2739 # f
  98          5047 # g
  99          4372 # h
 100         13053 # i
 101           516 # j
 102          2600 # k
 103          9631 # l
 104          5115 # m
 105         10082 # n
 106         11142 # o
 107          5292 # p
 108           287 # qu
 109         12341 # r
 110         16571 # s
 111         10215 # t
 112          6131 # u
 113          1728 # v
 114          2184 # w
 115           619 # x
 116          3512 # y
 117           831 # z
 118
 119 ]
 120
 121 letter_distribution_total = 175973 # letter_distribution.sum()
 122
 123
 124 new_letter_queue = []
 125 new_letter = ->
 126         if new_letter_queue.length
 127                 l = new_letter_queue.shift()
 128                 if l is 'Q'
 129                         return 'Qu'
 130                 else
 131                         return l
 132         r = Math.floor Math.random() * (letter_distribution_total + 1)
 133         for i in [0..25]
 134                 r -= letter_distribution[i]
 135                 if r <= 0
 136                         if letters[i] is 'Q'
 137                                 return 'Qu'
 138                         return letters[i]
 139         return 'Z' # just in case
 140
 141
 142
 143 # in memory it's layed out like this:
 144 # a c f j m
 145 # b d g k n
 146 #   e h l
 147 #     i
 148 # for display, columns are slid vertically like so:
 149 #       f
 150 #     c   j
 151 #   a   g   m
 152 #     d   k
 153 #   b   h   n
 154 #     e   l
 155 #       i
 156 #
 157 # work out which grid spaces are connected
 158 init_board_layout = () ->
 159         col_offset = 0
 160         middle_col = (board_cols - 1) / 2
 161
 162         # how many tiles before the current tile?
 163         for col_num in [0 .. board_cols - 1]
 164                 if col_num < middle_col
 165                         fw_other = 1
 166                 else
 167                         fw_other = -1
 168
 169                 if col_num > middle_col
 170                         bw_other = 1
 171                 else
 172                         bw_other = -1
 173
 174                 is_first_col = col_num is 0
 175                 is_last_col = col_num is board_cols - 1
 176
 177                 neighbors = []
 178                 push = (offset) ->
 179                         neighbors.push col_offset + offset
 180
 181                 col_top_px = Math.abs col_num - middle_col
 182                 col_top_px *= tile_radius
 183                 board_col_top_px.push col_top_px
 184
 185                 above = []
 186                 for i in [0 .. board_col_heights[col_num] - 1]
 187                         is_top_tile = i is 0
 188                         is_bottom_tile = i is board_col_heights[col_num] - 1
 189
 190                         # link tile number to pixel "top" and "left" of containing column
 191                         tile_top_px.push col_top_px + i * tile_width
 192                         board_left_px.push col_num * tile_width
 193
 194                         # aboves (array of tile numbers above, starting from top)
 195                         board_aboves.push above.clone()
 196                         above.push i + col_offset
 197
 198                         # below (SINGLE tile number of tile below or false)
 199                         if is_bottom_tile
 200                                 board_below.push false
 201                         else
 202                                 board_below.push col_offset + i + 1
 203
 204                         # neighbors (array of tile numbers "next to" this one)
 205                         neighbors = []
 206                         unless is_top_tile # upward link
 207                                 push i - 1
 208                         unless is_bottom_tile # downward links
 209                                 push i + 1
 210                         unless is_first_col # leftward links
 211                                 unless is_bottom_tile and bw_other is -1
 212                                         push i - board_col_heights[col_num - 1]
 213                                 unless is_top_tile and bw_other is -1
 214                                         push i - board_col_heights[col_num - 1] + bw_other
 215                         unless is_last_col # rightward links
 216                                 unless is_bottom_tile and fw_other is -1
 217                                         push i + board_col_heights[col_num]
 218                                 unless is_top_tile and fw_other is -1
 219                                         push i + board_col_heights[col_num] + fw_other
 220
 221                         board_neighbors.push neighbors.clone()
 222
 223                 col_offset += board_col_heights[col_num]
 224
 225
 226 init_board = ->
 227         encoded = window.location.hash
 228         if encoded? and encoded.charAt 0 is '#'
 229                 encoded = encoded.substr 1
 230         unless encoded? and encoded.length > board_tiles
 231                 encoded = get_cookie 'hexbog'
 232         if encoded? and encoded.length > board_tiles
 233                 new_letter_queue = (encoded.substr 0, board_tiles).split ''
 234                 score = parseInt(encoded.substr(board_tiles), 10)
 235
 236         # work out which grid spaces are connected
 237         # (neighbors, above, down)
 238         init_board_layout()
 239
 240 $big_tip = null # initialized by init_html_board
 241 $little_tip = null # initialized by init_html_board
 242 $score_display = null # initialized by init_html_board
 243 $definition_body = null # initialized by init_html_board
 244 update_selection_display = ->
 245         word = selected_word()
 246         $big_tip.removeClass('good')
 247         if word.length > 0
 248                 $big_tip.html word
 249                 if word.length < 3
 250                         $little_tip.html "Click more tiles (3 minimum)"
 251                 else
 252                         if is_word word
 253                                 if word.indexOf(word.substr(word.length - 1)) < word.length - 1
 254                                         last = 'last '
 255                                 else
 256                                         last = ''
 257                                 $little_tip.html "Click the #{last}\"#{word.substr(word.length - 1)}\" for #{score_for word} points"
 258                                 $big_tip.addClass('good')
 259                         else
 260                                 $little_tip.html "\"#{word}\" is not in the word list."
 261         else
 262                 $big_tip.html "← Click a word"
 263                 $little_tip.html "(tiles must be touching)"
 264
 265         # color the selected tiles according to whether they're a word or not
 266         if word.length
 267                 classes = ['selected_word', 'selected']
 268                 if is_word word
 269                         c = 0
 270                 else
 271                         c = 1
 272                 for num in selected
 273                         html_tiles[num].addClass classes[c]
 274                         html_tiles[num].removeClass classes[1 - c]
 275
 276 # unselects the last tile of the selecetion
 277 unselect_tile = ->
 278         _unselect_tile()
 279         update_selection_display()
 280
 281 _unselect_tile = ->
 282         num = selected.pop()
 283         html_tile = html_tiles[num]
 284         html_tile.removeClass 'selected_word'
 285         html_tile.removeClass 'selected'
 286
 287 unselect_all = ->
 288         while selected.length
 289                 _unselect_tile()
 290         update_selection_display()
 291
 292 shrink_selection = (leave_count) ->
 293         while selected.length > leave_count
 294                 _unselect_tile()
 295         update_selection_display()
 296
 297 selected_word = ->
 298         word = ''
 299         word += board[i] for i in selected
 300         return word.toLowerCase()
 301
 302 save_game = ->
 303         encoded = ''
 304         for t in board
 305                 encoded += t.substr 0, 1
 306         encoded += score
 307         set_cookie 'hexbog', encoded, 365
 308         window.location.hash = encoded
 309
 310 # remove the selected tiles from the board, create new tiles, and slide everything into place
 311 blip_selection = ->
 312         faders = selected.num_sort()
 313         selected = []
 314         update_selection_display()
 315         for i in faders
 316                 html_tiles[i].unbind('click').fadeOut fade_ms
 317         timeout fade_ms + 1, ->
 318                 # which tiles need to be slid down
 319                 sliders = (false for i in board)
 320
 321                 prev_col_top = null
 322                 next_new_y = null
 323                 for deleted in faders
 324                         # find the tile number of the top tile in this column
 325                         if board_aboves[deleted].length is 0
 326                                 col_top = deleted
 327                         else
 328                                 col_top = board_aboves[deleted][0]
 329
 330                         # reset location where new tiles appear when we change columns
 331                         if prev_col_top isnt col_top
 332                                 next_new_y = -10 - tile_width
 333                                 prev_col_top = col_top
 334
 335                         html_tiles[deleted].remove()
 336
 337                         # For each each tile above the one we've deleted:
 338                         # 1. move it down one slot in the data scructures
 339                         # 2. mark it as needing to slide
 340                         dest = deleted
 341                         aboves = board_aboves[deleted].clone().reverse()
 342                         for above in aboves
 343                                 html_tiles[dest] = html_tiles[above]
 344                                 html_tiles[dest].data 'tile_number', dest
 345                                 board[dest] = board[above]
 346                                 sliders[dest] = true
 347                                 --dest
 348                         sliders[col_top] = true # the new tile needs to be slid down too
 349
 350                         new_tile col_top, board_left_px[col_top], next_new_y
 351                         next_new_y -= tile_width + 50
 352
 353                 for slide, i in sliders
 354                         if slide
 355                                 html_tiles[i].animate {top: "#{tile_top_px[i]}px"}, slide_ms
 356                                 sliders[i] = false
 357                 save_game()
 358
 359 score_for = (word) -> Math.round(Math.pow(1.7, word.length))
 360
 361 activate_selection = ->
 362         word = selected_word()
 363         if word.length < 3
 364                 # FIXME make this a hint
 365                 log "Too short: \"#{word}\""
 366                 return
 367         unless is_word word
 368                 # FIXME make this automatically part of the selection display
 369                 log "Not on word list: \"#{word}\""
 370                 return
 371         word_score = score_for word
 372         score += word_score
 373         $score_display.html score
 374         # FIXME make some kind of animation showing score gain
 375         log "blipped \"#{word}\" for #{word_score} points"
 376         blip_selection()
 377         look_up_definition word
 378         $('#definition').click()
 379
 380
 381 show_definition = (word, type, definition, language) ->
 382         html = "<a href=\"http://en.wiktionary.org/wiki/#{word}\" target=\"_blank\">"
 383         html += "#{word.substr(0, 1).toUpperCase() + word.substr(1)}</a>, #{type}"
 384         if language isnt 'English'
 385                 html += " (#{language})"
 386         html += ': '
 387         html += definition
 388         html += '<div id="definition_credit">Definition &copy;<a href="http://en.wiktionary.org/" target="_blank">wiktionary.org</a> CC-BY-SA</div>'
 389         $definition_body.html html
 390
 391
 392 select_tile = (num) ->
 393         html_tile = html_tiles[num]
 394         # html_tile.css backgroundColor: tile_selected_color
 395         selected.push num
 396         update_selection_display()
 397         return
 398
 399 new_tile = (num, x, y) ->
 400         letter = new_letter()
 401
 402         html_tile = $("<div class=\"tile\" style=\"left: #{x}px; top: #{y}px\" unselectable=\"on\">#{letter}</div>")
 403         $board.append(html_tile)
 404
 405         html_tile.data 'tile_number', num
 406         board[num] = letter
 407         html_tiles[num] = html_tile
 408
 409         html_tile.click ->
 410                 me = $(this)
 411                 num = me.data 'tile_number'
 412                 if num in selected
 413                         nth_of_word = selected.indexOf(num)
 414                         first = nth_of_word is 0
 415                         last = nth_of_word is selected.length - 1
 416
 417                         if first and last
 418                                 unselect_all() # Clicking only selected letter unselects it
 419                         else if first and !last
 420                                 shrink_selection 1 # Clicking start of word goes back to just that letter
 421                                 # should this unselect all?
 422                         else if last
 423                                 activate_selection()
 424                         else
 425                                 shrink_selection nth_of_word + 1
 426                 else # (not clicking on selected tile)
 427                         if selected.length is 0
 428                                 select_tile num
 429                         else
 430                                 unless num in board_neighbors[selected.last()]
 431                                         unselect_all()
 432                                 select_tile num
 433
 434
 435 $board = null
 436 html_tiles = []
 437 init_html_board = ->
 438         $('#loading').remove()
 439         $big_tip = $('#big_tip')
 440         $little_tip = $('#little_tip')
 441         $score_display = $('#score')
 442         $score_display.html score
 443         $definition_body = $('#definition_body')
 444         $board = $('#board')
 445         # make html for board
 446         tile_number = 0
 447         for col_num in [0 .. board_cols - 1]
 448                 for num in [0 .. board_col_heights[col_num] - 1]
 449                         x = col_num * tile_width
 450                         y = board_col_top_px[col_num] + num * tile_width
 451                         new_tile tile_number, x, y
 452                         tile_number++
 453
 454 word_bins = []; word_bins.push(',') for [0...997]
 455 hash_word = (word) ->
 456         h = 0
 457         for i in [0...word.length]
 458                 h ^= word.charCodeAt(i) << ((i*3) % 21)
 459         return h % 997
 460 is_word = (str) ->
 461         word_bins[hash_word str].indexOf(",#{str},") > -1
 462
 463 # this is called automatically by the compressed wordlist
 464 parse_word_list = (compressed) ->
 465         prefix = ''
 466         cap_a = "A".charCodeAt 0
 467         i = 0
 468         next_chunk = ->
 469                 chunk = compressed[i]
 470                 for word in chunk.match(/[a-z]*[A-Z]/g)
 471                         # the capital letter (at the end of the match) says how many characters
 472                         # from the end of the previous word should be removed to create the prefix
 473                         # for the next word. "A" for 0, "B" for 1, "C" for 2, etc
 474                         bs = word[word.length - 1].charCodeAt(0) - cap_a
 475                         word = prefix + word[0 ... word.length - 1]
 476                         word_bins[hash_word word] += word + ','
 477                         prefix = word[0 ... word.length - bs]
 478                 if ++i is compressed.length
 479                         return
 480                 else
 481                         timeout 1, next_chunk
 482         timeout 1, next_chunk
 483
 484 extract_wiktionary_definiton = (html) ->
 485         found = false
 486         finds = {}
 487         language = false
 488         part = false
 489
 490         # clean HTML
 491         ##################
 492         # when we instantiate the html so we can use dom traversal, the browser
 493         # will start loading images and such. This section attempts to mangle the
 494         # html so no resources are loaded when the html is parsed.
 495
 496         # attributes
 497         #                            src: <img>, <audio>, etc
 498         #                         onload: only <body>?
 499         #   archive,codebase,data,usemap: <object>
 500         #                           href: <link>
 501         #                 id,class,style: background: url(foo.png), etc
 502         html = html.replace /(src|onload|archive|codebase|data|usemap|href|style|id|class)=['"][^"']*['"]/ig, '', html
 503
 504         elements = $(html)
 505
 506         valid_parts = ["Abbreviation", "Adjective", "Adverb", "Article", "Cardinal number", "Conjunction", "Determiner", "Interjection", "Noun", "Numeral", "Particle", "Preposition", "Pronoun", "Verb"]
 507
 508         edit_link_regex = new RegExp(' ?\\[edit\\] ?')
 509
 510         elements.each (i, el) ->
 511                 #which tag: el.tagName
 512                 if el.tagName is 'H2'
 513                         # if we found a definition in the previous language section, run with it
 514                         # (we only stop for verbs, in hopes of finding one in english)
 515                         if found
 516                                 return false # break
 517                         part = false # mark us not being in a definition section unless the next section finds a part of speach header
 518                         language = $(el).text().replace(edit_link_regex, '')
 519                 if language and el.tagName is 'H3' or el.tagName is 'H4' # eg yak def uses one for english and one for dutch
 520                         part = false
 521                         text = $(el).text().replace(edit_link_regex, '')
 522                         for p in valid_parts
 523                                 if text is "#{p}"
 524                                         part = p.toLowerCase()
 525                                         # FIXME break
 526                 if part and el.tagName is 'OL'
 527                         $(el).children().each (i, el) ->
 528                                 new_def = $(el).text()
 529                                 if new_def.substr(0, 9) is '(obsolete' or new_def.substr(0, 8) is "(archaic"
 530                                         key = 'obsolete'
 531                                 else
 532                                         if part is 'verb'
 533                                                 key = 'verb'
 534                                         else
 535                                                 key = 'nonverb'
 536                                 finds[key] ?= [part, new_def, language]
 537                                 found = true
 538                                 if part is 'verb'
 539                                         # verbs are the best! stop scanning when we find one
 540                                         return false # break
 541                         if found.verb
 542                                 return false # break
 543
 544         part_defs = (finds[i] for i in ['verb', 'nonverb', 'obsolete'] when finds[i])
 545         unless part_defs.length
 546                 return false
 547
 548         return part_defs[0]
 549
 550
 551 look_up_definition = (word) ->
 552         $definition_body.html "Looking up definition for \"#{word}\"..."
 553         $.ajax({
 554                 url: "http://en.wiktionary.org/w/api.php?action=parse&format=json&page=#{word}"
 555                 jsonpCallback: "lud_#{word}" # always use the same callback for the same word so it's cacheable
 556                 dataType: 'jsonp'
 557                 cache: true
 558                 success: (data, error_msg, xhr) ->
 559                         if data?.parse?.text?['*']?
 560                                 tdl = extract_wiktionary_definiton data.parse.text['*']
 561                                 if tdl
 562                                         show_definition word, tdl[0], tdl[1], tdl[2]
 563                                 else
 564                                         $definition_body.html "Oops, could't find a definition for \"#{word}\"."
 565                         else
 566                                 $definition_body.html "Sorry, couldn't find a definition for \"#{word}\"."
 567         })
 568
 569 board_as_txt = ->
 570         ret = ''
 571         index = 0
 572         for i in [0 .. board_min_height * 2]
 573                 unless i % 2
 574                         ret += '   ' + board[j] for j in [board_min_height + index .. board_tiles - 1] by 2 * board_min_height + 1
 575                 else
 576                         ret += ' ' + board[j] + '  ' for j in [index .. board_tiles - 1] by 2 * board_min_height + 1
 577                         index += 1
 578
 579                 ret += '\n'
 580         return ret
 581
 582 start_over = ->
 583         selected = []
 584         score = 0
 585         $score_display.html score
 586         for i in [0...board_tiles]
 587                 selected.push i
 588         blip_selection()
 589
 590 init_start_over_link = ->
 591         $('#start-over').click (event) ->
 592                 event.preventDefault()
 593                 if confirm "Are you sure you want to start over? There is no undo."
 594                         start_over()
 595
 596 cur_tab = 'instructions'
 597 tabtab_height = 20
 598 tab_height = 150
 599 init_tab = (t) ->
 600         $('#' + t).click ->
 601                 return if t is cur_tab
 602                 $('#' + cur_tab).removeClass('selected-tab').addClass('tab').animate({height: tabtab_height}, 1000)
 603                 $('#' + t).removeClass('tab').addClass('selected-tab').animate({height: tab_height}, 1000)
 604                 cur_tab = t
 605 init_tabs = ->
 606         for t in ['instructions', 'definition', 'donate', 'restart']
 607                 init_tab t
 608
 609 init_keybinding = ->
 610         $(window).keydown (e) ->
 611                 switch e.keyCode
 612                         when 32, 10, 13
 613                                 activate_selection()
 614                         when 27
 615                                 unselect_all()
 616
 617 $log = undefined
 618 init_log = ->
 619         $log = $('#log')
 620 log = (msg) ->
 621         console.log msg if console.log?
 622
 623 init_game = ->
 624         init_log()
 625         if $(window).height() >= 440
 626                 $('#centerer').css('margin-top', '25px')
 627         init_keybinding()
 628         init_tabs()
 629         init_board()
 630         init_html_board()
 631         init_start_over_link()
 632         update_selection_display()
 633
 634 $(init_game)