# Copyright 2015 Jason Woofenden
# This file implements an WYSIWYG editor in the browser (no contenteditable)
#
# This program is free software: you can redistribute it and/or modify it under
# the terms of the GNU Affero General Public License as published by the Free
# Software Foundation, either version 3 of the License, or (at your option) any
# later version.
#
# This program is distributed in the hope that it will be useful, but WITHOUT
# ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
# FOR A PARTICULAR PURPOSE.  See the GNU Affero General Public License for more
# details.
#
# You should have received a copy of the GNU Affero General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.

TYPE_TAG = peach_parser.TYPE_TAG
TYPE_TEXT = peach_parser.TYPE_TEXT
TYPE_COMMENT = peach_parser.TYPE_COMMENT
TYPE_DOCTYPE = peach_parser.TYPE_DOCTYPE

get_el_bounds = (el) ->
	rect = el.getBoundingClientRect()
	doc = el.ownerDocument.documentElement
	win = el.ownerDocument.defaultView
	y_fix = win.pageYOffset - doc.clientTop
	x_fix = win.pageXOffset - doc.clientLeft
	return {
		x: rect.left + x_fix
		y: rect.top + y_fix
		w: rect.width ? (rect.right - rect.left)
		h: rect.height ? (rect.top - rect.bottom)
	}

# figure out the top/left coordinates of where the cursor should be if it's at
# position ``i`` within text node ``n``
#
# implementation: insert a span tag where we want the cursor, and ask the
# browser where it put that span
cursor_to_loc = (n, i) ->
	span = domify span: style: "height: 1em; border-left: 1px solid black; margin-left: -1px"
	parent = n.el.parentNode
	els = []
	txts = []
	plus_width = false
	if n.text.length < 2
		bounds = get_el_offset n.el
		if i is 1
			plus_width = true
	else
		if i is 0 # cursor at start of text
			check_i = 0
			txts.push n.text.substr 0, 1
			txts.push n.text.substr 1
		else if i is n.text.length # cursor at end of text
			check_i = 1
			plus_width = true
			txts.push n.text.substr 0, n.text.length - 1
			txts.push n.text.substr n.text.length - 1
		else
			check_i = 1
			txts.push n.text.substr 0, i
			txts.push n.text.substr i, 1
			txts.push n.text.substr i + 1
		for txt, txt_i in txts
			el = n.el.ownerDocument.createTextNode txt
			if txt_i is check_i
				span = n.el.ownerDocument.createElement 'span'
				span.appendChild el
				el = span
			els.push el
			parent.insertBefore el, n.el
		parent.removeChild n.el
		bounds = get_el_bounds els[check_i]
		parent.insertBefore n.el, els[0]
		for el in els
			parent.removeChild el
	ret = top: bounds.y, left: bounds.x
	if plus_width
		ret.left += bounds.w
	# fudge case where bounds are BS because we're on non-significant whitespace
	if i > 0
		first = cursor_to_loc n, 0
		if ret.left <= first.left
			# no need for a loop here, because recursion
			ret = cursor_to_loc n, i - 1
	return ret

# TODO
#loc_to_cursor = (n, i) ->
#	return top: , left:

# encode text so it can be safely placed inside an html attribute
enc_attr_regex = new RegExp '(&)|(")|(\u00A0)', 'g'
enc_attr = (txt) ->
	return txt.replace enc_attr_regex, (match, amp, quote) ->
		return '&amp;' if (amp)
		return '&quot;' if (quote)
		return '&nbsp;'

void_elements = {
	area: true
	base: true
	br: true
	col: true
	embed: true
	hr: true
	img: true
	input: true
	keygen: true
	link: true
	meta: true
	param: true
	source: true
	track: true
	wbr: true
}
dom_to_html = (dom) ->
	ret = ''
	for el in dom
		switch el.type
			when TYPE_TAG
				ret += '<' + el.name
				attr_keys = []
				for k of el.attrs
					attr_keys.unshift k
				#attr_keys.sort()
				for k in attr_keys
					ret += " #{k}"
					if el.attrs[k].length > 0
						ret += "=\"#{enc_attr el.attrs[k]}\""
				ret += '>'
				unless void_elements[el.name]
					if el.children.length
						ret += dom_to_html el.children
					ret += "</#{el.name}>"
			when TYPE_TEXT
				ret += el.text
			when TYPE_COMMENT
				ret += "<!--#{el.text}-->"
			when TYPE_DOCTYPE
				ret += "<!DOCTYPE #{el.name}"
				if el.public_identifier? and el.public_identifier.length > 0
					ret += " \"#{el.public_identifier}\""
				if el.system_identifier? and el.system_identifier.length > 0
					ret += " \"#{el.system_identifier}\""
				ret += ">\n"
	return ret

domify = (h) ->
	for tag, attrs of h
		if tag is 'text'
			return document.createTextNode attrs
		el = document.createElement tag
		for k, v of attrs
			if k is 'children'
				for child in v
					el.appendChild child
			else
				el.setAttribute k, v
	return el

css = ''
css += 'div#peach_html5_editor_cursor {'
css +=     'position: absolute;'
css +=     'height: 1em;'
css +=     'width: 2px;'
css +=     'margin-left: -1px;'
css +=     'margin-right: -1px;'
css +=     'background: #000;'
css +=     '-webkit-animation: 1s blink step-end infinite;'
css +=     'animation: 1s blink step-end infinite;'
css += '}'
css += '@-webkit-keyframes "blink" {'
css +=     'from, to { background: #000; }'
css +=     '50% { background: transparent; }'
css += '}'
css += '@keyframes "blink" {'
css +=     'from, to { background: #000; }'
css +=     '50% { background: transparent; }'
css += '}'

# key codes:
KEY_LEFT = 37
KEY_UP = 38
KEY_RIGHT = 39
KEY_DOWN = 40
KEY_BACKSPACE = 8 # <--
KEY_DELETE = 46 # -->
KEY_END = 35
KEY_ENTER = 13
KEY_ESCAPE = 27
KEY_HOME = 36
KEY_INSERT = 45
KEY_PAGE_UP = 33
KEY_PAGE_DOWN = 34
KEY_TAB = 9

instantiate_tree = (tree, parent) ->
	for c in tree
		switch c.type
			when TYPE_TEXT
				c.el = parent.ownerDocument.createTextNode c.text
				parent.appendChild c.el
			when TYPE_TAG
				# TODO create in correct namespace
				c.el = parent.ownerDocument.createElement c.name
				for k, v of c.attrs
					# FIXME if attr_whitelist[k]?
					c.el.setAttribute k, v
				parent.appendChild c.el
				if c.children.length
					instantiate_tree c.children, c.el

traverse_tree = (tree, state, cb) ->
	for c in tree
		cb c, state
		break if state.done?
		if c.children.length
			traverse_tree c.children, state, cb
			break if state.done?
	return state
# find the next element in top (and decendants) that is after n and can contain text
# TODO make it so cursor can go places that don't have text but could
find_next_cursor_position = (top, n, i) ->
	if n? and n.type is TYPE_TEXT and n.text.length > i
		return [n, i + 1]
	found = traverse_tree top, before: n?, (node, state) ->
		if node.type is TYPE_TEXT and state.before is false
			state.node = node
			state.done = true
		if node is n
			state.before = false
	if found.node?
		return [found.node, 0]
	return null

# TODO make it so cursor can go places that don't have text but could
find_prev_cursor_position = (top, n, i) ->
	if n? and n.type is TYPE_TEXT and i > 0
		return [n, i - 1]
	found = traverse_tree top, before: n?, (node, state) ->
		if node.type is TYPE_TEXT
			unless n?
				state.node = node
				state.done = true
			if node is n
				if state.prev?
					state.node = state.prev
				state.done = true
			if node
				state.prev = node
	if found.node?
		return [found.node, found.node.text.length]
	return null

class PeachHTML5Editor
	constructor: (in_el, options = {}) ->
		@in_el = in_el
		@tree = []
		@iframe = domify iframe: class: 'peach_html5_editor'
		@cursor = null
		@cursor_el = null
		@cursor_visible = false
		opt_fragment = options.fragment ? true
		@parser_opts = {}
		if opt_fragment
			@parser_opts.fragment = 'body'

		@iframe.onload = =>
			@idoc = @iframe.contentDocument

			ignore_key_codes =
				'18': true # alt
				'20': true # capslock
				'17': true # ctrl
				'144': true # numlock
				'16': true # shift
				'91': true # windows "start" key
			control_key_codes = # we react to these, but they aren't typing
				'37': KEY_LEFT
				'38': KEY_UP
				'39': KEY_RIGHT
				'40': KEY_DOWN
				'35': KEY_END
				'8':  KEY_BACKSPACE
				'46': KEY_DELETE
				'13': KEY_ENTER
				'27': KEY_ESCAPE
				'36': KEY_HOME
				'45': KEY_INSERT
				'33': KEY_PAGE_UP
				'34': KEY_PAGE_DOWN
				'9':  KEY_TAB

			@idoc.body.onkeyup = (e) =>
				return if e.ctrlKey
				return false if ignore_key_codes[e.keyCode]?
				#return false if control_key_codes[e.keyCode]?
			@idoc.body.onkeydown = (e) =>
				return if e.ctrlKey
				return false if ignore_key_codes[e.keyCode]?
				#return false if control_key_codes[e.keyCode]?
				switch e.keyCode
					when KEY_LEFT
						if @cursor?
							new_cursor = find_prev_cursor_position @tree, @cursor...
							if new_cursor?
								@move_cursor new_cursor
						else
							for c in @tree
								new_cursor = find_next_cursor_position @tree, c, -1
								if new_cursor?
									@move_cursor new_cursor
									break
						return false
					when KEY_UP
						return false
					when KEY_RIGHT
						if @cursor?
							new_cursor = find_next_cursor_position @tree, @cursor...
							if new_cursor?
								@move_cursor new_cursor
						else
							for c in @tree
								new_cursor = find_prev_cursor_position @tree, c, -1
								if new_cursor?
									@move_cursor new_cursor
									break
						return false
					when KEY_DOWN
						return false
					when KEY_END
						return false
					when KEY_BACKSPACE
						return false
					when KEY_DELETE
						return false
					when KEY_ENTER
						return false
					when KEY_ESCAPE
						return false
					when KEY_HOME
						return false
					when KEY_INSERT
						return false
					when KEY_PAGE_UP
						return false
					when KEY_PAGE_DOWN
						return false
					when KEY_TAB
						return false
			@idoc.body.onkeypress = (e) =>
				return if e.ctrlKey
				return false if ignore_key_codes[e.keyCode]?
				return false if control_key_codes[e.keyCode]? # handled in keydown
				char = e.charCode ? e.keyCode
				if char and @cursor?
					char = String.fromCharCode char
					if @cursor[1] is 0
						@cursor[0].text = char + @cursor[0].text
					else if @cursor[1] is @cursor[0].text.length - 1
						@cursor[0].text += char
					else
						@cursor[0].text =
							@cursor[0].text.substr(0, @cursor[1]) +
							char +
							@cursor[0].text.substr(@cursor[1])
					@cursor[0].el.nodeValue = @cursor[0].text
					@move_cursor [@cursor[0], @cursor[1] + 1]
				return false
			if options.stylesheet # TODO test this
				istyle = @idoc.createElement 'style'
				istyle.setAttribute 'src', options.stylesheet
				@idoc.head.appendChild istyle
			icss = @idoc.createElement 'style'
			icss.appendChild @idoc.createTextNode css
			@idoc.head.appendChild icss
			@load_html @in_el.value

		@in_el.parentNode.appendChild @iframe
	clear_dom: ->
		# FIXME add parent node, so we don't empty body and delete cursor_el
		while @idoc.body.childNodes.length
			@idoc.body.removeChild @idoc.body.childNodes[0]
		@cursor_visible = false
		return
	load_html: (html) ->
		@tree = peach_parser.parse html, @parser_opts
		#as_html = dom_to_html @tree
		#@iframe.contentDocument.body.innerHTML = as_html
		@clear_dom()
		instantiate_tree @tree, @idoc.body
	move_cursor: (cursor) ->
		return if @cursor? and cursor? and @cursor[0] is cursor[0] and @cursor[1] is cursor[1]
		@cursor = cursor
		# replace cursor, to reset blink animation
		if @cursor_visible
			@cursor_el.parentNode.removeChild @cursor_el
		@cursor_el = domify div: id: 'peach_html5_editor_cursor'
		@idoc.body.appendChild @cursor_el
		@cursor_visible = true
		# TODO figure out top/left coords for cursor
		loc = cursor_to_loc cursor[0], cursor[1]
		@cursor_el.style.top = "#{loc.top}px"
		@cursor_el.style.left = "#{loc.left}px"

window.peach_html5_editor = (args...) ->
	return new PeachHTML5Editor args...

# test in browser: peach_html5_editor(document.getElementsByTagName('textarea')[0])