# Copyright 2015 Jason Woofenden
# This file implements an WYSIWYG editor in the browser (no contenteditable)
#
# This program is free software: you can redistribute it and/or modify it under
# the terms of the GNU Affero General Public License as published by the Free
# Software Foundation, either version 3 of the License, or (at your option) any
# later version.
#
# This program is distributed in the hope that it will be useful, but WITHOUT
# ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
# FOR A PARTICULAR PURPOSE.  See the GNU Affero General Public License for more
# details.
#
# You should have received a copy of the GNU Affero General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.

# SETTINGS
overlay_padding = 10

timeout = (ms, cb) -> return setTimeout cb, ms
next_frame = (cb) ->
	if (window.requestAnimationFrame?)
		window.requestAnimationFrame cb
	else
		timeout 16, cb

this_url_sans_path = ->
	ret = "#{window.location.href}"
	clip = ret.lastIndexOf '#'
	if clip > -1
		ret = ret.substr 0, clip
	clip = ret.lastIndexOf '?'
	if clip > -1
		ret = ret.substr 0, clip
	clip = ret.lastIndexOf '/'
	if clip > -1
		ret = ret.substr 0, clip + 1
	return ret

# xml 1.0 spec, chromium and firefox accept these, plus lots of unicode chars
valid_attr_regex = new RegExp '^[a-zA-Z_:][-a-zA-Z0-9_:.]*$'
# html5 spec is much more lax, but chromium won't let me make at attribute with the name "4"
js_attr_regex = new RegExp '^[oO][nN].'

debug_dot_at = (doc, x, y) ->
	return # disabled
	el = doc.createElement 'div'
	el.setAttribute 'style', "position: absolute; left: #{x}px; top: #{y}px; width: 1px; height: 3px; background-color: red"
	doc.body.appendChild el
	#console.log(new Error().stack)

# text nodes don't have getBoundingClientRect(), so use selection api to find
# it.
get_el_bounds = (el) ->
	if el.getBoundingClientRect?
		rect = el.getBoundingClientRect()
	else
		# text nodes don't have getBoundingClientRect(), so use range api
		range = el.ownerDocument.createRange()
		range.selectNodeContents el
		rect = range.getBoundingClientRect()
	doc = el.ownerDocument.documentElement
	win = el.ownerDocument.defaultView
	y_fix = win.pageYOffset - doc.clientTop
	x_fix = win.pageXOffset - doc.clientLeft
	return {
		x: rect.left + x_fix
		y: rect.top + y_fix
		w: rect.width ? (rect.right - rect.left)
		h: rect.height ? (rect.top - rect.bottom)
	}

is_display_block = (el) ->
	if el.currentStyle?
		return el.currentStyle.display is 'block'
	else
		return window.getComputedStyle(el, null).getPropertyValue('display') is 'block'

# Pass return value from dom event handlers to this.
# If they return false, this will addinionally stop propagation and default.
event_return = (e, bool) ->
	if bool is false
		if e.stopPropagation?
			e.stopPropagation()
		if e.preventDefault?
			e.preventDefault()
	return bool
# Warning: currently assumes you're asking about a single character
# Note: chromium returns multiple bounding rects for a space at a line-break
# Note: chromium's getBoundingClientRect() is broken (when zero-area client rects)
# Note: sometimes returns null (eg for whitespace that is not visible)
text_range_bounds = (el, start, end) ->
	range = document.createRange()
	range.setStart el, start
	range.setEnd el, end
	rects = range.getClientRects()
	if rects.length > 0
		rect = rects[0]
	else
		return null
	doc = el.ownerDocument.documentElement
	win = el.ownerDocument.defaultView
	y_fix = win.pageYOffset - doc.clientTop
	x_fix = win.pageXOffset - doc.clientLeft
	return {
		x: rect.left + x_fix
		y: rect.top + y_fix
		w: rect.width ? (rect.right - rect.left)
		h: rect.height ? (rect.top - rect.bottom)
		rects: rects
		bounding: range.getBoundingClientRect()
	}

# figure out the x/y coordinates of where the cursor should be if it's at
# position ``i`` within text node ``n``
# sometimes returns null (eg for whitespace that is not visible)
window.cursor_to_xyh = cursor_to_xyh = (n, i) ->
	range = document.createRange()
	if n.text.length is 0
		ret = text_range_bounds n.el, 0, 0
	else if i is n.text.length
		ret = text_range_bounds n.el, i - 1, i
		if ret?
			ret.x += ret.w
	else
		ret = text_range_bounds n.el, i, i + 1
	if ret?
		debug_dot_at n.el.ownerDocument, ret.x, ret.y
	return ret

# encode text so it can be safely placed inside an html attribute
enc_attr_regex = new RegExp '(&)|(")|(\u00A0)', 'g'
enc_attr = (txt) ->
	return txt.replace enc_attr_regex, (match, amp, quote) ->
		return '&amp;' if (amp)
		return '&quot;' if (quote)
		return '&nbsp;'
enc_text_regex = new RegExp '(&)|(<)|(\u00A0)', 'g'
enc_text = (txt) ->
	return txt.replace enc_text_regex, (match, amp, lt) ->
		return '&amp;' if (amp)
		return '&lt;' if (lt)
		return '&nbsp;'

void_elements = {
	area: true
	base: true
	br: true
	col: true
	embed: true
	hr: true
	img: true
	input: true
	keygen: true
	link: true
	meta: true
	param: true
	source: true
	track: true
	wbr: true
}
# TODO make these always pretty-print (on the inside) like blocks
no_text_elements = { # these elements never contain text
	select: true
	table: true
	tr: true
	thead: true
	tbody: true
	ul: true
	ol: true
}

domify = (doc, hash) ->
	for tag, attrs of hash
		if tag is 'text'
			return document.createTextNode attrs
		el = document.createElement tag
		for k, v of attrs
			if k is 'children'
				for child in v
					el.appendChild child
			else
				el.setAttribute k, v
	return el

outer_css = (args) ->
	w = args.w ? 300
	h = args.h ? 300
	inner_padding = args.inner_padding ? overlay_padding
	frame_width = args.frame_width ? inner_padding
	# TODO editor controls height...
	occupy = (left, top = left, right = left, bottom = top) ->
		w -= left + right
		h -= top + bottom
		return Math.max(left, top, right, bottom)
	ret = ''
	ret += 'body {'
	ret +=     'margin: 0;'
	ret +=     'padding: 0;'
	ret +=     'color: black;'
	ret +=     'background: white;'
	ret += '}'
	ret += '#wrap1 {'
	ret +=     "border: #{occupy 1}px solid black;"
	ret +=     "padding: #{occupy frame_width}px;"
	ret += '}'
	ret += '#wrap2 {'
	ret +=     "border: #{occupy 1}px solid black;"
	ret +=     "padding: #{occupy inner_padding}px;"
	ret +=     "padding-right: #{inner_padding + occupy 0, 0, 15, 0}px;" # for scroll bar
	ret +=     "width: #{w}px;"
	ret +=     "height: #{h}px;"
	ret +=     'overflow-x: hidden;'
	ret +=     'overflow-y: scroll;'
	ret += '}'
	ret += '#wrap3 {'
	ret +=     'position: relative;'
	ret +=     "width: #{w}px;"
	ret +=     "min-height: #{h}px;"
	ret += '}'
	ret += 'iframe {'
	ret +=     'box-sizing: border-box;'
	ret +=     'margin: 0;'
	ret +=     'border: none;'
	ret +=     'padding: 0;'
	ret +=     "width: #{w}px;"
	#ret +=     "height: #{h}px;" # height auto-set when content set/changed
	ret +=     '-ms-user-select: none;'
	ret +=     '-webkit-user-select: none;'
	ret +=     '-moz-user-select: none;'
	ret +=     'user-select: none;'
	ret += '}'
	ret += '#overlay {'
	ret +=     'position: absolute;'
	ret +=     "left: -#{inner_padding}px;"
	ret +=     "top: -#{inner_padding}px;"
	ret +=     "right: -#{inner_padding}px;"
	ret +=     "bottom: -#{inner_padding}px;"
	ret +=     'overflow: hidden;'
	ret += '}'
	ret += '.lightbox {'
	ret +=     'position: absolute;'
	ret +=     'background: rgba(100,100,100,0.2);'
	ret += '}'
	ret += '#cursor {'
	ret +=     'position: absolute;'
	ret +=     'width: 2px;'
	ret +=     'background: linear-gradient(0deg, rgba(0,0,0,1), rgba(255,255,255,1), rgba(0,0,0,1), rgba(255,255,255,1), rgba(0,0,0,1), rgba(255,255,255,1), rgba(0,0,0,1), rgba(255,255,255,1), rgba(0,0,0,1));'
	ret +=     'background-size: 200% 200%;'
	ret +=     '-webkit-animation: blink 1s linear normal infinite;'
	ret +=     'animation: blink 1s linear normal infinite;'
	ret += '}'
	ret += '@-webkit-keyframes blink {'
	ret +=     '0%{background-position:0% 0%}'
	ret +=     '100%{background-position:0% -100%}'
	ret += '}'
	ret += '@keyframes blink { '
	ret +=     '0%{background-position:0% 0%}'
	ret +=     '100%{background-position:0% -100%}'
	ret += '}'
	ret += '.ann_box {'
	ret +=     'z-index: 5;'
	ret +=     'position: absolute;'
	ret +=     'border: 1px solid rgba(0,0,0,0.1);'
	ret +=     'outline: 1px solid rgba(255,255,255,0.1);' # in case there's a black background
	ret += '}'
	ret += '.ann_tag {'
	ret +=     'z-index: 10;'
	ret +=     'position: absolute;'
	ret +=     'font-size: 8px;'
	ret +=     'white-space: pre;'
	ret +=     'background: rgba(255,255,255,0.4);'
	ret +=     '-ms-user-select: none;'
	ret +=     '-webkit-user-select: none;'
	ret +=     '-moz-user-select: none;'
	ret +=     'user-select: none;'
	ret += '}'
	return ret


ignore_key_codes =
	'18': true # alt
	'20': true # capslock
	'17': true # ctrl
	'144': true # numlock
	'16': true # shift
	'91': true # windows "start" key
# key codes: (valid on keydown, not keypress)
KEY_LEFT = 37
KEY_UP = 38
KEY_RIGHT = 39
KEY_DOWN = 40
KEY_BACKSPACE = 8 # <--
KEY_DELETE = 46 # -->
KEY_END = 35
KEY_ENTER = 13
KEY_ESCAPE = 27
KEY_HOME = 36
KEY_INSERT = 45
KEY_PAGE_UP = 33
KEY_PAGE_DOWN = 34
KEY_TAB = 9
control_key_codes = # we react to these, but they aren't typing
	'37': KEY_LEFT
	'38': KEY_UP
	'39': KEY_RIGHT
	'40': KEY_DOWN
	'35': KEY_END
	'8':  KEY_BACKSPACE
	'46': KEY_DELETE
	'13': KEY_ENTER
	'27': KEY_ESCAPE
	'36': KEY_HOME
	'45': KEY_INSERT
	'33': KEY_PAGE_UP
	'34': KEY_PAGE_DOWN
	'9':  KEY_TAB

instantiate_tree = (tree, parent) ->
	remove = []
	for c, i in tree
		switch c.type
			when 'text'
				c.el = parent.ownerDocument.createTextNode c.text
				parent.appendChild c.el
			when 'tag'
				if c.name in ['script', 'object', 'iframe', 'link']
					# TODO put placeholders instead
					remove.unshift i
					continue
				# TODO create in correct namespace
				c.el = parent.ownerDocument.createElement c.name
				for k, v of c.attrs
					# FIXME if attr_whitelist[k]?
					if valid_attr_regex.test k
						unless js_attr_regex.test k
							c.el.setAttribute k, v
				parent.appendChild c.el
				if c.children.length
					instantiate_tree c.children, c.el
	for i in remove
		tree.splice i, 1

traverse_tree = (tree, cb) ->
	done = false
	for c in tree
		done = cb c
		return done if done
		if c.children.length
			done = traverse_tree c.children, cb
			return done if done
	return done

find_next_cursor_position = (tree, n, i) ->
	if n.type is 'text' and n.text.length > i
		orig_xyh = cursor_to_xyh n, i
		unless orig_xyh?
			console.log "ERROR: couldn't find xy for current cursor location"
			return
		for next_i in [i+1 .. n.text.length] # inclusive is valid (after last char)
			next_xyh = cursor_to_xyh n, next_i
			if next_xyh?
				if next_xyh.x > orig_xyh.x or next_xyh.y > orig_xyh.y
					return [n, next_i]
	state_before = true
	found = null
	traverse_tree tree, (node, state) ->
		if node.type is 'text' and state_before is false
			if cursor_to_xyh(node, 0)?
				found = node
				return true
		if node is n
			state_before = false
		return false
	if found?
		return [found, 0]
	return null

find_prev_cursor_position = (tree, n, i) ->
	if n? and n.type is 'text' and i > 0
		orig_xyh = cursor_to_xyh n, i
		unless orig_xyh?
			console.log "ERROR: couldn't find xy for current cursor location"
			return
		for prev_i in [i-1 .. 0]
			prev_xyh = cursor_to_xyh n, prev_i
			if prev_xyh?
				if prev_xyh.x < orig_xyh.x or prev_xyh.y < orig_xyh.y
					return [n, prev_i]
		return [n, i - 1]
	found_prev = n?
	found = null
	traverse_tree tree, (node) ->
		if node.type is 'text'
			if node is n
				if found_prev?
					found = found_prev
				return true
			found_prev = node
		return false
	if found?
		if cursor_to_xyh found, found.text.length # text visible?
			return [found, found.text.length]
		return find_prev_cursor_position tree, found, 0
	return null

find_loc_cursor_position = (tree, loc) ->
	for c in tree
		if c.type is 'tag' or c.type is 'text'
			bounds = get_el_bounds c.el
			continue if loc.x < bounds.x
			continue if loc.x > bounds.x + bounds.w
			continue if loc.y < bounds.y
			continue if loc.y > bounds.y + bounds.h
			if c.children.length
				ret = find_loc_cursor_position c.children, loc
				return ret if ret?
			if c.type is 'text'
				# click is within bounding box that contains all text.
				return [c, 0] if c.text.length is 0
				before_i = 0
				before = cursor_to_xyh c, before_i
				unless before?
					console.log "error: failed to find cursor pixel location for start of", c
					return
				after_i = c.text.length
				after = cursor_to_xyh c, after_i
				unless after?
					console.log "error: failed to find cursor pixel location for end of", c
					return
				if loc.y < before.y + before.h and loc.x < before.x
					# console.log 'before first char on first line'
					continue
				if loc.y > after.y and loc.x > after.x
					# console.log 'after last char on last line'
					continue
				if loc.y < before.y
					console.log "Warning: click in bounding box but above first line"
					continue # above first line (runaround?)
				if loc.y > after.y + after.h
					console.log "Warning: click in bounding box but below last line", loc.y, after.y, after.h
					continue # below last line (shouldn't happen?)
				while after_i - before_i > 1
					cur_i = Math.round((before_i + after_i) / 2)
					cur = cursor_to_xyh c, cur_i
					unless loc?
						console.log "error: failed to find cursor pixel location for", c, cur_i
						return
					if loc.y < cur.y or (loc.y <= cur.y + cur.h and loc.x < cur.x)
						after_i = cur_i
						after = cur
					else
						before_i = cur_i
						before = cur
				# which one is closest?
				if Math.abs(before.x - loc.x) < Math.abs(after.x - loc.x)
					return [c, before_i]
				else
					return [c, after_i]
	return null

# browsers collapse these (html5 spec calls these "space characters")
is_space_code = (char_code) ->
	switch char_code
		when 9, 10, 12, 13, 32
			return true
	return false
is_space = (chr) ->
	return is_space_code chr.charCodeAt 0

tree_remove_empty_text_nodes = (tree) ->
	empties = []
	traverse_tree tree, (n) ->
		if n.type is 'text'
			if n.text.length is 0
				empties.unshift n
		return false
	for n in empties
		# don't completely empty the tree
		if tree.length is 1
			if tree[0].type is 'text'
				console.log "oop, leaving a blank node because it's the only thing"
				return
		n.el.parentNode.removeChild n.el
		for c, i in n.parent.children
			if c is n
				n.parent.children.splice i, 1
				break

# pass a array of nodes (from parser library, ie it should have .el and .text)
tree_dedup_space = (tree) ->
	prev = cur = next = null
	prev_i = cur_i = next_i = 0
	prev_pos = pos = next_pos = null
	prev_px = cur_px = next_px = null
	first = true
	removed_char = null

	tree_remove_empty_text_nodes(tree)

	iterate = (tree, cb) ->
		for n in tree
			if n.type is 'text'
				i = 0
				while i < n.text.length # don't foreach, cb might remove chars
					advance = cb n, i
					if advance
						i += 1
			if n.type is 'tag'
				block = is_display_block n.el
				if block
					cb null
				if n.children.length > 0
					iterate n.children, cb
				if block
					cb null
	# remove cur char
	remove = ->
		removed_char = cur.text.charAt(cur_i)
		cur.el.textContent = cur.text = (cur.text.substr 0, cur_i) + (cur.text.substr cur_i + 1)
		if next is cur # in same text node
			if next_i is 0
				throw "how is this possible?"
			next_i -= 1
		return true
	# undo remove()
	put_it_back = ->
		cur.el.textContent = cur.text = (cur.text.substr 0, cur_i) + removed_char + (cur.text.substr cur_i)
		if next is cur # in same text node
			next_i += 1
		return false
	# return true if cur was removed from the dom (ie re-use same prev)
	operate = ->
		# cur definitately set
		# prev and/or next might be null, indicating the start/end of a display:block
		return false unless is_space_code cur.text.charCodeAt cur_i
		bounds = text_range_bounds cur.el, cur_i, cur_i + 1
		# consistent cases:
		# 1. zero rects returned by getClientRects() means collapsed space
		if bounds is null
			return remove()
		# 2. width greater than zero means visible space
		if bounds.w > 0
			return false
		# now the weird edge cases...
		#
		# firefox and chromium both report zero width for characters at the end
		# of a line where the text wraps (automatically, due to word-wrap) to
		# the next line. These do not appear to be distinguishable from
		# collapsed spaces via the range/bounds api, so...
		#
		# remove it from the dom, and if prev or next moves, put it back.
		if prev? and not prev_px?
			prev_px = cursor_to_xyh prev, prev_i
		if next? and not next_px?
			next_px = cursor_to_xyh next, next_i
		#if prev is null and next is null
		#	parent_px = cur.parent.el.getBoundingClientRect()
		remove()
		if prev?
			if prev_px?
				new_prev_px = cursor_to_xyh prev, prev_i
				if new_prev_px.x isnt prev_px.x or new_prev_px.y isnt prev_px.y
					return put_it_back()
			else
				console.log "this shouldn't happen, we remove spaces that don't locate"
		if next?
			if next_px?
				new_next_px = cursor_to_xyh next, next_i
				if new_next_px.x isnt next_px.x or new_next_px.y isnt next_px.y
					return put_it_back()
			#else
			#	console.log "removing space becase space after it is collapsed"
		return true
	# pass null at start/end of display:block
	queue = (n, i) ->
		next = n
		next_i = i
		next_px = null
		advance = true
		if cur?
			removed = operate()
			# don't advance (to the next character next time) if we removed a
			# character from the same text node as ``next``, because doing so
			# renumbers the indexes in that string
			if removed and cur is next
				advance = false
		else
			removed = false
		unless removed
			prev = cur
			prev_i = cur_i
			prev_px = cur_px
		cur = next
		cur_i = next_i
		cur_px = next_px
		return advance
	queue null
	iterate tree, queue
	queue null

	tree_remove_empty_text_nodes(tree)

class PeachHTML5Editor
	# Options: (all optional)
	#   editor_id: "id" attribute for outer-most element created by/for editor
	#   css_file: filename of a css file to style editable content
	#   on_init: callback for when the editable content is in place
	constructor: (in_el, options) ->
		@options = options ? {}
		@in_el = in_el
		@tree = null
		@matting = []
		@init_1_called = false # when iframes have loaded
		@outer_iframe # iframe to hold editor
		@outer_idoc # "document" object for @outer_iframe
		@wrap2 = null # scrollbar is on this
		@iframe = null # iframe to hold editable content
		@idoc = null # "document" object for @iframe
		@cursor = null
		@cursor_el = null
		@cursor_visible = false
		@poll_for_blur_timeout = null
		@iframe_offset = null
		@iframe_height = null
		opt_fragment = @options.fragment ? true
		@parser_opts = {}
		if opt_fragment
			@parser_opts.fragment = 'body'

		@outer_iframe = domify document, iframe: {}
		outer_iframe_style = 'border: none !important; margin: 0 !important; padding: 0 !important; height: 100% !important; width: 100% !important;'
		if @options.editor_id?
			@outer_iframe.setAttribute 'id', @options.editor_id
		@outer_iframe.onload = =>
			@outer_idoc = @outer_iframe.contentDocument
			icss = domify @outer_idoc, style: children: [
				domify @outer_idoc, text: css
			]
			@outer_idoc.head.appendChild icss
			@iframe = domify @outer_idoc, iframe: sandbox: 'allow-same-origin allow-scripts'
			@iframe.onload = =>
				@init_1()
			timeout 200, => # firefox never fires this onload
				@init_1() unless @init_1_called
			@outer_idoc.body.appendChild(
				domify @outer_idoc, div: id: 'wrap1', children: [
					domify @outer_idoc, div: style: "position: absolute; top: 0; left: 1px; font-size: 10px", children: [ domify @outer_idoc, text: "Peach HTML5 Editor" ]
					@wrap2 = domify @outer_idoc, div: id: 'wrap2', children: [
						domify @outer_idoc, div: id: 'wrap3', children: [
							@iframe
							@overlay = domify @outer_idoc, div: id: 'overlay'
						]
					]
				]
			)
		outer_wrap = domify document, div: class: 'peach_html5_editor'
		@in_el.parentNode.appendChild outer_wrap
		outer_bounds = get_el_bounds outer_wrap
		if outer_bounds.w < 300
			outer_bounds.w = 300
		if outer_bounds.h < 300
			outer_bounds.h = 300
		outer_iframe_style += "width: #{outer_bounds.w}px; height: #{outer_bounds.h}px;"
		@outer_iframe.setAttribute 'style', outer_iframe_style
		css = outer_css w: outer_bounds.w, h: outer_bounds.h
		outer_wrap.appendChild @outer_iframe
	init_1: -> # @iframe has loaded (but not it's css)
		@idoc = @iframe.contentDocument
		@init_1_called = true
		# chromium doesn't resolve relative urls as though they were at the same domain
		# so add a <base> tag
		@idoc.head.appendChild domify @idoc, base: href: this_url_sans_path()
		# don't let @iframe have scrollbars
		@idoc.head.appendChild domify @idoc, style: children: [domify @idoc, text: "body { overflow: hidden; }"]
		# load css file
		if @options.css_file
			istyle = domify @idoc, link: rel: 'stylesheet', href: @options.css_file
			istyle.onload = =>
				@init_2()
			@idoc.head.appendChild istyle
		else
			@init_2()
	init_2: -> # @iframe and it's css file(s) are ready
		@overlay.onclick = (e) =>
			@have_focus()
			return event_return e, @onclick e
		@overlay.ondoubleclick = (e) =>
			@have_focus()
			return event_return e, @ondoubleclick e
		@outer_idoc.body.onkeyup = (e) =>
			@have_focus()
			return event_return e, @onkeyup e
		@outer_idoc.body.onkeydown = (e) =>
			@have_focus()
			return event_return e, @onkeydown e
		@outer_idoc.body.onkeypress = (e) =>
			@have_focus()
			return event_return e, @onkeypress e
		@load_html @in_el.value
		if @options.on_init?
			@options.on_init()
	overlay_event_to_inner_xy: (e) ->
		unless @iframe_offset?
			@iframe_offset = get_el_bounds @iframe
		x = e.pageX # TODO ?cross-browserify
		y = e.pageY + @wrap2.scrollTop # TODO ?cross-browserify
		# TODO adjust for scrolling
		return x: x - @iframe_offset.x, y: y - @iframe_offset.y
	onclick: (e) ->
		xy = @overlay_event_to_inner_xy e
		new_cursor = find_loc_cursor_position @tree, xy
		if new_cursor?
			@move_cursor new_cursor
		else
			@kill_cursor()
		return false
	ondoubleclick: (e) ->
		return false
	onkeyup: (e) ->
		return if e.ctrlKey
		return false if ignore_key_codes[e.keyCode]?
		#return false if control_key_codes[e.keyCode]?
	onkeydown: (e) ->
		return if e.ctrlKey
		return false if ignore_key_codes[e.keyCode]?
		#return false if control_key_codes[e.keyCode]?
		switch e.keyCode
			when KEY_LEFT
				if @cursor?
					new_cursor = find_prev_cursor_position @tree, @cursor...
					if new_cursor?
						@move_cursor new_cursor
				else
					for c in @tree
						new_cursor = find_next_cursor_position @tree, c, -1
						if new_cursor?
							@move_cursor new_cursor
							break
				return false
			when KEY_UP
				return false
			when KEY_RIGHT
				if @cursor?
					new_cursor = find_next_cursor_position @tree, @cursor...
					if new_cursor?
						@move_cursor new_cursor
				else
					for c in @tree
						new_cursor = find_prev_cursor_position @tree, c, -1
						if new_cursor?
							@move_cursor new_cursor
							break
				return false
			when KEY_DOWN
				return false
			when KEY_END
				return false
			when KEY_BACKSPACE
				return false unless @cursor?
				return false unless @cursor[1] > 0
				@cursor[0].text = @cursor[0].text.substr(0, @cursor[1] - 1) + @cursor[0].text.substr(@cursor[1])
				@cursor[0].el.nodeValue = @cursor[0].text
				@move_cursor [@cursor[0], @cursor[1] - 1]
				@changed()
				return false
			when KEY_DELETE
				return false unless @cursor?
				return false unless @cursor[1] < @cursor[0].text.length
				@cursor[0].text = @cursor[0].text.substr(0, @cursor[1]) + @cursor[0].text.substr(@cursor[1] + 1)
				@cursor[0].el.nodeValue = @cursor[0].text
				@move_cursor [@cursor[0], @cursor[1]]
				@changed()
				return false
			when KEY_ENTER
				return false
			when KEY_ESCAPE
				return false
			when KEY_HOME
				return false
			when KEY_INSERT
				return false
			when KEY_PAGE_UP
				return false
			when KEY_PAGE_DOWN
				return false
			when KEY_TAB
				return false
	onkeypress: (e) ->
		return if e.ctrlKey
		return false if ignore_key_codes[e.keyCode]?
		# return false if control_key_codes[e.keyCode]? # handled in keydown
		char = e.charCode ? e.keyCode
		if char and @cursor?
			char = String.fromCharCode char
			if @cursor[1] is 0
				@cursor[0].text = char + @cursor[0].text
			else if @cursor[1] is @cursor[0].text.length - 1
				@cursor[0].text += char
			else
				@cursor[0].text =
					@cursor[0].text.substr(0, @cursor[1]) +
					char +
					@cursor[0].text.substr(@cursor[1])
			@cursor[0].el.nodeValue = @cursor[0].text
			@move_cursor [@cursor[0], @cursor[1] + 1]
			@changed()
		return false
	clear_dom: -> # remove all the editable content (and cursor, overlays, etc)
		while @idoc.body.childNodes.length
			@idoc.body.removeChild @idoc.body.childNodes[0]
		@kill_cursor()
		return
	load_html: (html) ->
		@tree = peach_parser.parse html, @parser_opts
		@clear_dom()
		instantiate_tree @tree, @idoc.body
		tree_dedup_space @tree
		@changed()
	changed: ->
		@in_el.onchange = null
		@in_el.value = @pretty_html @tree
		@in_el.onchange = =>
			@load_html @in_el.value
		@adjust_iframe_height()
	adjust_iframe_height: ->
		h = parseInt(@idoc.body.scrollHeight, 10)
		if @iframe_height isnt h
			@iframe_height = h
			s = @wrap2.scrollTop
			@iframe.style.height = "0"
			@iframe.style.height = "#{h}px"
			@wrap2.scrollTop = s
	kill_cursor: -> # remove it, forget where it was
		if @cursor_visible
			@cursor_el.parentNode.removeChild @cursor_el
			@cursor_visible = false
		@cursor = null
		@matt null
	move_cursor: (cursor) ->
		loc = cursor_to_xyh cursor[0], cursor[1]
		unless loc?
			console.log "error: tried to move cursor to position that has no pixel location", cursor[0], cursor[1]
			return
		@cursor = cursor
		# replace cursor element, to reset blink animation
		if @cursor_visible
			@cursor_el.parentNode.removeChild @cursor_el
		@cursor_el = domify @outer_idoc, div: id: 'cursor'
		@overlay.appendChild @cursor_el
		@cursor_visible = true
		@cursor_el.style.left = "#{loc.x + overlay_padding - 1}px"
		if loc.h < 5
			height = 12
		else
			height = loc.h
		@cursor_el.style.top = "#{loc.y + overlay_padding + Math.round(height * .07)}px"
		@cursor_el.style.height = "#{Math.round height * 0.82}px"
		@matt cursor[0]
	matt: (n) ->
		while @matting.length > 0
			@overlay.removeChild @matting[0]
			@matting.shift()
		return unless n?
		prev_bounds = x: 0, y: 0, w: 0, h: 0
		alpha = 0.1
		while n?.el?
			if n.type is 'text'
				n = n.parent
				continue
			bounds = get_el_bounds n.el
			return unless bounds?
			if bounds.x is prev_bounds.x and bounds.y is prev_bounds.y and bounds.w is prev_bounds.w and bounds.h is prev_bounds.h
				n = n.parent
				continue
			matt = domify @outer_idoc, div: class: 'ann_box', style: "left: #{bounds.x - 1 + overlay_padding}px; top: #{bounds.y - 2 + overlay_padding}px; width: #{bounds.w}px; height: #{bounds.h}px" # outline: 1000px solid rgba(0,153,255,#{alpha});
			@overlay.appendChild matt
			@matting.push matt
			ann = domify @outer_idoc, div: class: 'ann_tag', style: "left: #{bounds.x + 1 + overlay_padding}px; top: #{bounds.y - 7 + overlay_padding}px", children: [domify @outer_idoc, text: " #{n.name} "]
			@overlay.appendChild ann
			@matting.push ann
			n = n.parent
			alpha *= 1.5
	pretty_html: (tree, indent = '', parent_flags = pre_ish: false, block: true, want_nl: false) ->
		ret = ''
		want_nl = parent_flags.want_nl
		prev_in_flow_is_text = false
		prev_in_flow_is_block = false
		for n, i in tree
			# figure out flags
			inner_flags = want_nl: true
			is_br = false
			switch n.type
				when 'tag'
					if n.name is 'br'
						is_br = true
					is_text = false
					if n.el.currentStyle?
						cs = n.el.currentStyle
						whitespace = cs['white-space']
						display = cs['display']
						position = cs['position']
						float = cs['float']
						visibility = cs['visibility']
					else
						cs = @iframe.contentWindow.getComputedStyle(n.el, null)
						whitespace = cs.getPropertyValue 'white-space'
						display = cs.getPropertyValue 'display'
						position = cs.getPropertyValue 'position'
						float = cs.getPropertyValue 'float'
						visibility = cs.getPropertyValue 'visibility'
					if n.name is 'textarea'
						inner_flags.pre_ish = true
					else
						inner_flags.pre_ish = whitespace.substr(0, 3) is 'pre'
					switch float
						when 'left', 'right'
							in_flow = false
						else
							switch position
								when 'absolute', 'fixed'
									in_flow = false
								else
									if 'display' is 'none'
										in_flow = false
									else
										switch visibility
											when 'hidden', 'collapse'
												in_flow = false
											else # visible
												in_flow = true
					switch display
						when 'inline', 'none'
							inner_flags.block = false
							is_block = in_flow_block = false
						when 'inline-black'
							inner_flags.block = true
							is_block = in_flow_block = false
						else # block, table, etc
							inner_flags.block = true
							is_block = true
							in_flow_block = in_flow
				when 'text'
					is_text = true
					is_block = false
					in_flow = true
					in_flow_block = false
				else # 'comment', 'doctype'
					is_text = false
					is_block = false
					in_flow = false
					in_flow_block = false
			# print whitespace if we can
			unless parent_flags.pre_ish
				unless prev_in_flow_is_text and is_br
					if (i is 0 and parent_flags.block) or in_flow_block or prev_in_flow_is_block
						if want_nl
							ret += "\n"
						ret += indent
			switch n.type
				when 'tag'
					ret += '<' + n.name
					attr_keys = []
					for k of n.attrs
						attr_keys.unshift k
					#attr_keys.sort()
					for k in attr_keys
						ret += " #{k}"
						if n.attrs[k].length > 0
							ret += "=\"#{enc_attr n.attrs[k]}\""
					ret += '>'
					unless void_elements[n.name]?
						if inner_flags.block
							next_indent = indent + '    '
						else
							next_indent = indent
						if n.children.length
							ret += @pretty_html n.children, next_indent, inner_flags
						ret += "</#{n.name}>"
				when 'text'
					ret += enc_text n.text
				when 'comment'
					ret += "<!--#{n.text}-->" # TODO encode?
				when 'doctype'
					ret += "<!DOCTYPE #{n.name}"
					if n.public_identifier? and n.public_identifier.length > 0
						ret += " \"#{n.public_identifier}\""
					if n.system_identifier? and n.system_identifier.length > 0
						ret += " \"#{n.system_identifier}\""
					ret += ">"
			want_nl = true
			if in_flow
				prev_in_flow_is_text = is_text
				prev_in_flow_is_block = is_block or (in_flow and is_br)
		if tree.length
			# output final newline if allowed
			unless parent_flags.pre_ish
				if prev_in_flow_is_block or parent_flags.block
					ret += "\n#{indent.substr 4}"
		return ret
	onblur: ->
		@kill_cursor()
	have_focus: ->
		@editor_is_focused = true
		@poll_for_blur()
	poll_for_blur: ->
		return if @poll_for_blur_timeout? # already polling
		@poll_for_blur_timeout = timeout 150, =>
			next_frame => # pause polling when browser knows we're not active/visible/etc.
				@poll_for_blur_timeout = null
				if document.activeElement is @outer_iframe
					@poll_for_blur()
				else
					@editor_is_focused = false
					@onblur()

window.peach_html5_editor = (args...) ->
	return new PeachHTML5Editor args...

# test in browser: peach_html5_editor(document.getElementsByTagName('textarea')[0])