# this file is used by the client and server.

# work around lack of module system in the browser:
if exports?
	my_exports = exports
else
	window.terminal = {}
	my_exports = window.terminal

class Terminal
	# public:
	constructor: (width, height) ->
		@width = 1
		@height = 1
		@text = []
		@attributes = []
		@x = 0
		@y = 0
		@a = 0x000007 # cursor attributes
		@partial = ''
		@saved_normal_screen = null
		@resize width, height

	resize: (width, height) ->
		# FIXME: write a version that retains some of the data
		@width = width
		@height = height
		@text = []
		@attributes = []
		for y in [0...height]
			@text[y] = []
			@attributes[y] = []
			for x in [0...width]
				@text[y].push ' '
				@attributes[y].push 0

	# pass data from stdout
	update: (data) ->
		return unless data?.length > 0
		if @partial.length > 0
			data = @partial + data
			@partial = ''
		parts = data.split(/\x1b\[/)
		if parts.length > 1
			if -1 is @escape_sequence_length parts[parts.length - 1]
				@partial = parts.pop()
		if parts.length > 0
			for i in [0...parts.length]
				if i is 0
					@update_text parts[i]
				else
					@update_sequence_then_text parts[i]
		return

	add_new_line: ->
		# clear top line
		for i in [0...@width]
			@text[0][i] = ' '
			@attributes[0][i] = 0
		# move (newly cleared) top line to the bottom
		tmp = @text.shift()
		@text.push(tmp)
		tmp = @attributes.shift()
		@attributes.push(tmp)
		# slide cursor up with rest of text
		@y -= 1

	wrap_to_next_line: ->
		if @y is @height - 1
			@add_new_line()
		@y += 1
		@x = 0

	# str has no escape sequences
	update_text: (str) ->
		return unless str.length > 0
		for c in str
			switch c
				when '\t' # tab
					@update_text "        ".substr(@x % 8)
				when '\x07' # bell
					false
				when '\x0d' # cr
					@x = 0
				when '\x08' # backspace
					if @x is 0
						@x = @width - 1
						if @y > 0
							@y -= 1
					else
						@x -= 1
				when '\x0a', '\x0b' # lf, vertical tab (same thing)
					@wrap_to_next_line()
				else
					if @x >= @width
						@wrap_to_next_line()
					@text[@y][@x] = c
					@attributes[@y][@x] = @a
					@x += 1
		return

	set_attribute_bits: (mask, value) ->
		@a = ((@a & ~mask) | value)

	# we're supposed to ignore leeding zeros, and while we're at it, lets swap
	# in the default for blank or missing values
	fix_esc_arg: (value, deef_alt) ->
		if value? and value != ''
			while value[0] is '0' and value.length > 1
				value = value.substr 1
			return value
		else
			return deef_alt

	# csi_@: rxvt does nothing I can detect

	# move cursor up
	csi_A: (lines) ->
		lines = parseInt @fix_esc_arg lines, '1'
		@y -= lines
		if @y < 0
			@y = 0

	# move cursor down
	csi_B: (lines) ->
		lines = parseInt @fix_esc_arg lines, '1'
		@y += lines
		if @y >= @height
			@y = @height - 1

	# move cursor right
	csi_C: (cols) ->
		cols = parseInt @fix_esc_arg cols, '1'
		@x += cols
		if @x >= @width
			@x = @width - 1

	# move cursor left
	csi_D: (cols) ->
		cols = parseInt @fix_esc_arg cols, '1'
		@x -= cols
		if @x < 0
			@x = 0

	# set cursor position (one based)
	csi_H: (row, column) ->
		# handle blank/missing args and convert to 0 base
		row = -1 + parseInt @fix_esc_arg row, '1'
		column = -1 + parseInt @fix_esc_arg column, '1'

		#clamp values
		if column < 0
			column = 0
		else if column >= @width
			column = @width - 1
		if row < 0
			row = 0
		if row >= @height
			row = @height - 1

		#move the cursor
		@x = column
		@y = row

	# clear to screen edge(es)
	csi_J: (direction) ->
		switch @fix_esc_arg direction, '0'
			when '0' # erase down
				# rest of current line
				@csi_K direction
				# rest of lines
				for row in [@y...@height]
					for i in [0...@width]
						@text[row][i] = ' '
						@attributes[row][i] = @a
			when '1' # erase up
				# beginning of current line
				@csi_K direction
				# all previous lines
				for row in [0..@y]
					for i in [0...@width]
						@text[row][i] = ' '
						@attributes[row][i] = @a
			when '2' # erase everything
				for row in [0...@height]
					for i in [0...@width]
						@text[row][i] = ' '
						@attributes[row][i] = @a
			else
				console.log "confusing arg for csi_J: #{direction}"
		return

	# clear (some or all of) current line
	csi_K: (direction) ->
		switch @fix_esc_arg direction, '0'
			when '0' # erase to right
				for i in [@x...@width]
					@text[@y][i] = ' '
					@attributes[@y][i] = @a
			when '1' # erase to left
				# @x can equal @width (after printing to right-most column)
				if @x < @width
					max = @x
				else
					max = @width - 1
				for i in [0..max]
					@text[@y][i] = ' '
					@attributes[@y][i] = @a
			when '2' # erase whole line
				for i in [0...@width]
					@text[@y][i] = ' '
					@attributes[@y][i] = @a
			else
				console.log "confusing arg for csi_K: #{direction}"
		return
	
	# misc
	csiq_h: ->
		args = []
		for i in arguments
			arg = @fix_esc_arg i, ''
			switch arg
				when '1049'
					if @saved_normal_screen?
						console.log "ignoring request to switch to the alt screen because we're already on the alt screen"
						return
					@saved_normal_screen = [@x, @y, @text, @attributes]
					@text = []
					@attributes = []
					for y in [0...@height]
						@text[y] = []
						@attributes[y] = []
						for x in [0...@width]
							@text[y].push ' '
							@attributes[y].push 0
				else
					console.log "confusing arg for csiq_h: #{arg}"
	# unmisc
	csiq_l: ->
		args = []
		for i in arguments
			arg = @fix_esc_arg i, ''
			switch arg
				when '1049'
					if not @saved_normal_screen?
						console.log "ignoring request to switch to the normal screen because we're already on the normal screen"
						return
					@x = @saved_normal_screen[0]
					@y = @saved_normal_screen[1]
					@text = @saved_normal_screen[2]
					@attributes = @saved_normal_screen[3]
					@saved_normal_screen = null
				else
					console.log "confusing arg for csiq_l: #{arg}"

	# set color, bold, underline, etc
	csi_m: ->
		args = []
		for i in arguments
			args.push @fix_esc_arg i, '0'

		while args.length > 0
			arg = args.shift()
			switch arg
				# remove all style/color
				when '0'
					@a = 0x07

				# style attributes
				when '1' # bold
					@set_attribute_bits 0x010000, 0x010000
				when '3' # italic (rare)
					@set_attribute_bits 0x200000, 0x200000
				when '4' # underline
					@set_attribute_bits 0x020000, 0x020000
				when '5' # blink
					@set_attribute_bits 0x040000, 0x040000
				when '7' # inverse
					@set_attribute_bits 0x080000, 0x080000
				when '8' # invisible. urivt ignores this
					@set_attribute_bits 0x100000, 0x100000

				# disable style attributes
				when '21' # not bold (rare)
					@set_attribute_bits 0x010000, 0
				when '22' # not bold
					@set_attribute_bits 0x010000, 0
				when '23' # not italic (rare)
					@set_attribute_bits 0x200000, 0
				when '24' # not underline
					@set_attribute_bits 0x020000, 0
				when '25' # not blink
					@set_attribute_bits 0x040000, 0
				when '27' # not inverse
					@set_attribute_bits 0x080000, 0
				when '28' # not invisible
					@set_attribute_bits 0x100000, 0

				when '100' # reset colors but not other attributes
					@set_attribute_bits 0xffff, 0x0007

				# 8 fg colors
				when '30' # fg black
					@set_attribute_bits 0xff, 0x00
				when '31' # fg red
					@set_attribute_bits 0xff, 0x01
				when '32' # fg green
					@set_attribute_bits 0xff, 0x02
				when '33' # fg yellow
					@set_attribute_bits 0xff, 0x03
				when '34' # fg blue
					@set_attribute_bits 0xff, 0x04
				when '35' # fg magenta
					@set_attribute_bits 0xff, 0x05
				when '36' # fg cyan
					@set_attribute_bits 0xff, 0x06
				when '37', '39' # fg white  (39 is default)
					@set_attribute_bits 0xff, 0x07

				when '38'
					if args.length >= 2 and args[0] is '5'
						args.shift()
						@set_attribute_bits 0xff, (0xff & args.shift())
					else
						@set_attribute_bits 0x20000, 0x20000

				# 8 bg colors
				when '40' # bg black
					@set_attribute_bits 0xff00, 0x0000
				when '41' # bg red
					@set_attribute_bits 0xff00, 0x0100
				when '42' # bg green
					@set_attribute_bits 0xff00, 0x0200
				when '43' # bg yellow
					@set_attribute_bits 0xff00, 0x0300
				when '44' # bg blue
					@set_attribute_bits 0xff00, 0x0400
				when '45' # bg magenta
					@set_attribute_bits 0xff00, 0x0500
				when '46' # bg cyan
					@set_attribute_bits 0xff00, 0x0600
				when '47' # bg white
					@set_attribute_bits 0xff00, 0x0700
				when '49' # bg default
					@set_attribute_bits 0xff00, 0x0000

				when '48'
					if args.length >= 2 and args[0] is '5'
						args.shift()
						@set_attribute_bits 0xff00, ((0xff & args.shift()) << 8)
					else
						@set_attribute_bits 0x20000, 0x20000

				# bright fg colors
				when '90' # fg bright black
					@set_attribute_bits 0xff, 0x08
				when '91' # fg bright red
					@set_attribute_bits 0xff, 0x09
				when '92' # fg bright green
					@set_attribute_bits 0xff, 0x0a
				when '93' # fg bright yellow
					@set_attribute_bits 0xff, 0x0b
				when '94' # fg bright blue
					@set_attribute_bits 0xff, 0x0c
				when '95' # fg bright magenta
					@set_attribute_bits 0xff, 0x0d
				when '96' # fg bright cyan
					@set_attribute_bits 0xff, 0x0e
				when '97' # fg bright white
					@set_attribute_bits 0xff, 0x0f

				# bright bg colors
				when '100' # bg bright black
					@set_attribute_bits 0xff, 0x08
				when '101' # bg bright red
					@set_attribute_bits 0xff, 0x09
				when '102' # bg bright green
					@set_attribute_bits 0xff, 0x0a
				when '103' # bg bright yellow
					@set_attribute_bits 0xff, 0x0b
				when '104' # bg bright blue
					@set_attribute_bits 0xff, 0x0c
				when '105' # bg bright magenta
					@set_attribute_bits 0xff, 0x0d
				when '106' # bg bright cyan
					@set_attribute_bits 0xff, 0x0e
				when '107' # bg bright white
					@set_attribute_bits 0xff, 0x0f

				else
					# if we don't recognize the style, go back to default
					console.log "unrecognized csi_m arg: \"#{arg}\""
					@a = 0
		return

	# str is the whole escape sequence (minus the esc[ prefix)
	update_sequence: (str) ->
		prefix = 'csi_'
		if str[0] is '?'
			prefix = 'csiq_'
			str = str.substr 1
		command = @[prefix + str.substr(str.length - 1)]
		if not command?
			console.log "Unrecognized sequence: ESC[#{str}"
			return
		args = str.substr(0, str.length - 1).split ';'
		command.call this, args...

	update_sequence_then_text: (str) ->
		len = @escape_sequence_length str
		if len is -1
			console.log "couldn't find escape sequence here: #{str.substr 0, 25}"
			@update_text "ESC[" + str
		else
			@update_sequence str.substr 0, len
			@update_text str.substr len

	escape_sequence_length: (str) ->
		parts = str.match(/^[0-9;?]{0,25}./)
		return -1 unless parts?
		return parts[0].length

my_exports.new = (width, height) ->
	return new Terminal width, height