terminal.coffee

   1 # this file is used by the client and server.
   2
   3 # work around lack of module system in the browser:
   4 if exports?
   5         my_exports = exports
   6 else
   7         window.terminal = {}
   8         my_exports = window.terminal
   9
  10 class Terminal
  11         # public:
  12         constructor: (width, height) ->
  13                 @width = 1
  14                 @height = 1
  15                 @text = []
  16                 @attributes = []
  17                 @x = 0
  18                 @y = 0
  19                 @a = 0x000007 # cursor attributes
  20                 @partial = ''
  21                 @saved_normal_screen = null
  22                 @cursor_visible = true
  23                 @scroll_top = 0
  24                 @scroll_bottom = height - 1
  25                 @resize width, height
  26
  27         resize: (width, height) ->
  28                 # FIXME: write a version that retains some of the data
  29                 # FIXME: clamp variables (eg x, y, saved.*, scrolling region) if getting smaller
  30                 @width = width
  31                 @height = height
  32                 @text = []
  33                 @attributes = []
  34                 for y in [0...height]
  35                         @text[y] = []
  36                         @attributes[y] = []
  37                         for x in [0...width]
  38                                 @text[y].push ' '
  39                                 @attributes[y].push 0x07
  40
  41         # pass data from stdout
  42         update: (data) ->
  43                 return unless data?.length > 0
  44                 if @partial.length > 0
  45                         data = @partial + data
  46                         @partial = ''
  47                 parts = data.split(/\x1b\[/)
  48                 if parts.length > 1
  49                         if -1 is @escape_sequence_length parts[parts.length - 1]
  50                                 @partial = parts.pop()
  51                 if parts.length > 0
  52                         for i in [0...parts.length]
  53                                 if i is 0
  54                                         @update_text parts[i]
  55                                 else
  56                                         @update_sequence_then_text parts[i]
  57                 return
  58
  59         add_new_line: ->
  60                 # clear the line at the top of the scrolling region
  61                 for i in [0...@width]
  62                         @text[@scroll_top][i] = ' '
  63                         @attributes[@scroll_top][i] = 0x07
  64
  65                 rearrange = (a) =>
  66                         return [
  67                                 a[0...@scroll_top]..., # up to but not including scroll top
  68                                 a[@scroll_top + 1 .. @scroll_bottom]..., # scroll region except top line of it
  69                                 a[@scroll_top], # top line of scroll region (already cleared)
  70                                 a[@scroll_bottom + 1 ... @height]... # rest of screen
  71                         ]
  72                 @text = rearrange @text
  73                 @attributes = rearrange @attributes
  74
  75                 # slide cursor up with rest of text
  76                 @y -= 1
  77
  78         wrap_to_next_line: ->
  79                 if @y is @scroll_bottom
  80                         @add_new_line()
  81                 @y += 1
  82                 @x = 0
  83
  84         # str has no escape sequences
  85         update_text: (str) ->
  86                 return unless str.length > 0
  87                 for c in str
  88                         switch c
  89                                 when '\t' # tab
  90                                         @update_text "        ".substr(@x % 8)
  91                                 when '\x07' # bell
  92                                         false
  93                                 when '\x0d' # cr
  94                                         @x = 0
  95                                 when '\x08' # backspace
  96                                         if @x is 0
  97                                                 @x = @width - 1
  98                                                 if @y > 0
  99                                                         @y -= 1
 100                                         else
 101                                                 @x -= 1
 102                                 when '\x0a', '\x0b' # lf, vertical tab (same thing)
 103                                         @wrap_to_next_line()
 104                                 else
 105                                         if @x >= @width
 106                                                 @wrap_to_next_line()
 107                                         @text[@y][@x] = c
 108                                         @attributes[@y][@x] = @a
 109                                         @x += 1
 110                 return
 111
 112         set_attribute_bits: (mask, value) ->
 113                 @a = ((@a & ~mask) | value)
 114
 115         # we're supposed to ignore leeding zeros, and while we're at it, lets swap
 116         # in the default for blank or missing values
 117         fix_esc_arg: (value, deef_alt) ->
 118                 if value? and value != ''
 119                         while value[0] is '0' and value.length > 1
 120                                 value = value.substr 1
 121                         return value
 122                 else
 123                         return deef_alt
 124
 125         # csi_@: rxvt does nothing I can detect
 126
 127         # move cursor up
 128         csi_A: (lines) ->
 129                 lines = parseInt @fix_esc_arg lines, '1'
 130                 @y -= lines
 131                 if @y < 0
 132                         @y = 0
 133                 return
 134
 135         # move cursor down
 136         csi_B: (lines) ->
 137                 lines = parseInt @fix_esc_arg lines, '1'
 138                 @y += lines
 139                 if @y >= @height
 140                         @y = @height - 1
 141                 return
 142
 143         # move cursor right
 144         csi_C: (cols) ->
 145                 cols = parseInt @fix_esc_arg cols, '1'
 146                 @x += cols
 147                 if @x >= @width
 148                         @x = @width - 1
 149                 return
 150
 151         # move cursor left
 152         csi_D: (cols) ->
 153                 cols = parseInt @fix_esc_arg cols, '1'
 154                 @x -= cols
 155                 if @x < 0
 156                         @x = 0
 157                 return
 158
 159         # set cursor position (one based)
 160         csi_H: (row, column) ->
 161                 # handle blank/missing args and convert to 0 base
 162                 row = -1 + parseInt @fix_esc_arg row, '1'
 163                 column = -1 + parseInt @fix_esc_arg column, '1'
 164
 165                 #clamp values
 166                 if column < 0
 167                         column = 0
 168                 else if column >= @width
 169                         column = @width - 1
 170                 if row < 0
 171                         row = 0
 172                 if row >= @height
 173                         row = @height - 1
 174
 175                 #move the cursor
 176                 @x = column
 177                 @y = row
 178                 return
 179
 180         # clear to screen edge(es)
 181         csi_J: (direction) ->
 182                 switch @fix_esc_arg direction, '0'
 183                         when '0' # erase down
 184                                 # rest of current line
 185                                 @csi_K direction
 186                                 # rest of lines
 187                                 for row in [@y...@height]
 188                                         for i in [0...@width]
 189                                                 @text[row][i] = ' '
 190                                                 @attributes[row][i] = @a
 191                         when '1' # erase up
 192                                 # beginning of current line
 193                                 @csi_K direction
 194                                 # all previous lines
 195                                 for row in [0..@y]
 196                                         for i in [0...@width]
 197                                                 @text[row][i] = ' '
 198                                                 @attributes[row][i] = @a
 199                         when '2' # erase everything
 200                                 for row in [0...@height]
 201                                         for i in [0...@width]
 202                                                 @text[row][i] = ' '
 203                                                 @attributes[row][i] = @a
 204                         else
 205                                 console.log "confusing arg for csi_J: #{direction}"
 206                 return
 207
 208         # clear (some or all of) current line
 209         csi_K: (direction) ->
 210                 switch @fix_esc_arg direction, '0'
 211                         when '0' # erase to right
 212                                 for i in [@x...@width]
 213                                         @text[@y][i] = ' '
 214                                         @attributes[@y][i] = @a
 215                         when '1' # erase to left
 216                                 # @x can equal @width (after printing to right-most column)
 217                                 if @x < @width
 218                                         max = @x
 219                                 else
 220                                         max = @width - 1
 221                                 for i in [0..max]
 222                                         @text[@y][i] = ' '
 223                                         @attributes[@y][i] = @a
 224                         when '2' # erase whole line
 225                                 for i in [0...@width]
 226                                         @text[@y][i] = ' '
 227                                         @attributes[@y][i] = @a
 228                         else
 229                                 console.log "confusing arg for csi_K: #{direction}"
 230                 return
 231
 232         # move lines downwards (arg is how far)
 233         csi_L: (lines) ->
 234                 lines = parseInt @fix_esc_arg lines, '1'
 235
 236                 rearrange = (a) =>
 237                         return [
 238                                 a[0...@y]..., # keep everything above cursor
 239                                 a[@scroll_bottom - lines + 1 .. @scroll_bottom]..., # we'll clear these shortly
 240                                 a[@y..@scroll_bottom - lines]..., # lines that are moving down
 241                                 a[@scroll_bottom + 1 ... @height]... # rest of screen
 242                         ]
 243                 @text = rearrange @text
 244                 @attributes = rearrange @attributes
 245
 246                 # clear the lines we scrolled off (and put back in as "new")
 247                 for y in [@y...@y+lines]
 248                         for x in [0...@width]
 249                                 @text[y][x] = ' '
 250                                 @attributes[y][x] = 0x07
 251
 252         # misc
 253         csiq_h: ->
 254                 args = []
 255                 for i in arguments
 256                         arg = @fix_esc_arg i, ''
 257                         switch arg
 258                                 when '25'
 259                                         @cursor_visible = true
 260                                 when '1049'
 261                                         if @saved_normal_screen?
 262                                                 console.log "ignoring request to switch to the alt screen because we're already on the alt screen"
 263                                                 return
 264                                         @saved_normal_screen = [@x, @y, @text, @attributes]
 265                                         @text = []
 266                                         @attributes = []
 267                                         for y in [0...@height]
 268                                                 @text[y] = []
 269                                                 @attributes[y] = []
 270                                                 for x in [0...@width]
 271                                                         @text[y].push ' '
 272                                                         @attributes[y].push 0x07
 273                                 else
 274                                         console.log "confusing arg for csiq_h: #{arg}"
 275                 return
 276
 277         # unmisc
 278         csiq_l: ->
 279                 args = []
 280                 for i in arguments
 281                         arg = @fix_esc_arg i, ''
 282                         switch arg
 283                                 when '25'
 284                                         @cursor_visible = false
 285                                 when '1049'
 286                                         if not @saved_normal_screen?
 287                                                 console.log "ignoring request to switch to the normal screen because we're already on the normal screen"
 288                                                 return
 289                                         @x = @saved_normal_screen[0]
 290                                         @y = @saved_normal_screen[1]
 291                                         @text = @saved_normal_screen[2]
 292                                         @attributes = @saved_normal_screen[3]
 293                                         @saved_normal_screen = null
 294                                 else
 295                                         console.log "confusing arg for csiq_l: #{arg}"
 296                 return
 297
 298         # set color, bold, underline, etc
 299         csi_m: ->
 300                 args = []
 301                 for i in arguments
 302                         args.push @fix_esc_arg i, '0'
 303
 304                 while args.length > 0
 305                         arg = args.shift()
 306                         switch arg
 307                                 # remove all style/color
 308                                 when '0'
 309                                         @a = 0x07
 310
 311                                 # style attributes
 312                                 when '1' # bold
 313                                         @set_attribute_bits 0x010000, 0x010000
 314                                 when '3' # italic (rare)
 315                                         @set_attribute_bits 0x200000, 0x200000
 316                                 when '4' # underline
 317                                         @set_attribute_bits 0x020000, 0x020000
 318                                 when '5' # blink
 319                                         @set_attribute_bits 0x040000, 0x040000
 320                                 when '7' # inverse
 321                                         @set_attribute_bits 0x080000, 0x080000
 322                                 when '8' # invisible. urivt ignores this
 323                                         @set_attribute_bits 0x100000, 0x100000
 324
 325                                 # disable style attributes
 326                                 when '21' # not bold (rare)
 327                                         @set_attribute_bits 0x010000, 0
 328                                 when '22' # not bold
 329                                         @set_attribute_bits 0x010000, 0
 330                                 when '23' # not italic (rare)
 331                                         @set_attribute_bits 0x200000, 0
 332                                 when '24' # not underline
 333                                         @set_attribute_bits 0x020000, 0
 334                                 when '25' # not blink
 335                                         @set_attribute_bits 0x040000, 0
 336                                 when '27' # not inverse
 337                                         @set_attribute_bits 0x080000, 0
 338                                 when '28' # not invisible
 339                                         @set_attribute_bits 0x100000, 0
 340
 341                                 when '100' # reset colors but not other attributes
 342                                         @set_attribute_bits 0xffff, 0x0007
 343
 344                                 # 8 fg colors
 345                                 when '30' # fg black
 346                                         @set_attribute_bits 0xff, 0x00
 347                                 when '31' # fg red
 348                                         @set_attribute_bits 0xff, 0x01
 349                                 when '32' # fg green
 350                                         @set_attribute_bits 0xff, 0x02
 351                                 when '33' # fg yellow
 352                                         @set_attribute_bits 0xff, 0x03
 353                                 when '34' # fg blue
 354                                         @set_attribute_bits 0xff, 0x04
 355                                 when '35' # fg magenta
 356                                         @set_attribute_bits 0xff, 0x05
 357                                 when '36' # fg cyan
 358                                         @set_attribute_bits 0xff, 0x06
 359                                 when '37', '39' # fg white  (39 is default)
 360                                         @set_attribute_bits 0xff, 0x07
 361
 362                                 when '38'
 363                                         if args.length >= 2 and args[0] is '5'
 364                                                 args.shift()
 365                                                 @set_attribute_bits 0xff, (0xff & args.shift())
 366                                         else
 367                                                 @set_attribute_bits 0x20000, 0x20000
 368
 369                                 # 8 bg colors
 370                                 when '40' # bg black
 371                                         @set_attribute_bits 0xff00, 0x0000
 372                                 when '41' # bg red
 373                                         @set_attribute_bits 0xff00, 0x0100
 374                                 when '42' # bg green
 375                                         @set_attribute_bits 0xff00, 0x0200
 376                                 when '43' # bg yellow
 377                                         @set_attribute_bits 0xff00, 0x0300
 378                                 when '44' # bg blue
 379                                         @set_attribute_bits 0xff00, 0x0400
 380                                 when '45' # bg magenta
 381                                         @set_attribute_bits 0xff00, 0x0500
 382                                 when '46' # bg cyan
 383                                         @set_attribute_bits 0xff00, 0x0600
 384                                 when '47' # bg white
 385                                         @set_attribute_bits 0xff00, 0x0700
 386                                 when '49' # bg default
 387                                         @set_attribute_bits 0xff00, 0x0000
 388
 389                                 when '48'
 390                                         if args.length >= 2 and args[0] is '5'
 391                                                 args.shift()
 392                                                 @set_attribute_bits 0xff00, ((0xff & args.shift()) << 8)
 393                                         else
 394                                                 @set_attribute_bits 0x20000, 0x20000
 395
 396                                 # bright fg colors
 397                                 when '90' # fg bright black
 398                                         @set_attribute_bits 0xff, 0x08
 399                                 when '91' # fg bright red
 400                                         @set_attribute_bits 0xff, 0x09
 401                                 when '92' # fg bright green
 402                                         @set_attribute_bits 0xff, 0x0a
 403                                 when '93' # fg bright yellow
 404                                         @set_attribute_bits 0xff, 0x0b
 405                                 when '94' # fg bright blue
 406                                         @set_attribute_bits 0xff, 0x0c
 407                                 when '95' # fg bright magenta
 408                                         @set_attribute_bits 0xff, 0x0d
 409                                 when '96' # fg bright cyan
 410                                         @set_attribute_bits 0xff, 0x0e
 411                                 when '97' # fg bright white
 412                                         @set_attribute_bits 0xff, 0x0f
 413
 414                                 # bright bg colors
 415                                 when '100' # bg bright black
 416                                         @set_attribute_bits 0xff, 0x08
 417                                 when '101' # bg bright red
 418                                         @set_attribute_bits 0xff, 0x09
 419                                 when '102' # bg bright green
 420                                         @set_attribute_bits 0xff, 0x0a
 421                                 when '103' # bg bright yellow
 422                                         @set_attribute_bits 0xff, 0x0b
 423                                 when '104' # bg bright blue
 424                                         @set_attribute_bits 0xff, 0x0c
 425                                 when '105' # bg bright magenta
 426                                         @set_attribute_bits 0xff, 0x0d
 427                                 when '106' # bg bright cyan
 428                                         @set_attribute_bits 0xff, 0x0e
 429                                 when '107' # bg bright white
 430                                         @set_attribute_bits 0xff, 0x0f
 431
 432                                 else
 433                                         # if we don't recognize the style, go back to default
 434                                         console.log "unrecognized csi_m arg: \"#{arg}\""
 435                                         @a = 0
 436                 return
 437
 438         # set scrolling region
 439         csi_r: (top, bottom) ->
 440                 top = -1 + parseInt @fix_esc_arg top, '1'
 441                 bottom = -1 + parseInt @fix_esc_arg bottom, '10000'
 442                 if top < 0
 443                         top = 0
 444                 if bottom >= @height
 445                         bottom = @height - 1
 446                 @scroll_top = top
 447                 @scroll_bottom = bottom
 448                 return
 449
 450         # str is the whole escape sequence (minus the esc[ prefix)
 451         update_sequence: (str) ->
 452                 prefix = 'csi_'
 453                 if str[0] is '?'
 454                         prefix = 'csiq_'
 455                         str = str.substr 1
 456                 command = @[prefix + str.substr(str.length - 1)]
 457                 if not command?
 458                         console.log "Unrecognized sequence: ESC[#{str}"
 459                         return
 460                 args = str.substr(0, str.length - 1).split ';'
 461                 command.call this, args...
 462
 463         update_sequence_then_text: (str) ->
 464                 len = @escape_sequence_length str
 465                 if len is -1
 466                         console.log "couldn't find escape sequence here: #{str.substr 0, 25}"
 467                         @update_text "ESC[" + str
 468                 else
 469                         @update_sequence str.substr 0, len
 470                         @update_text str.substr len
 471
 472         escape_sequence_length: (str) ->
 473                 parts = str.match(/^[0-9;?]{0,25}./)
 474                 return -1 unless parts?
 475                 return parts[0].length
 476
 477 my_exports.new = (width, height) ->
 478         return new Terminal width, height