terminal.coffee

   1 # this file is used by the client and server.
   2
   3 # work around lack of module system in the browser:
   4 if exports?
   5         my_exports = exports
   6 else
   7         window.terminal = {}
   8         my_exports = window.terminal
   9
  10 class Terminal
  11         # public:
  12         constructor: (width, height) ->
  13                 @width = 1
  14                 @height = 1
  15                 @text = []
  16                 @attributes = []
  17                 @x = 0
  18                 @y = 0
  19                 @a = 0x000007 # cursor attributes
  20                 @partial = ''
  21                 @saved_normal_screen = null
  22                 @cursor_visible = true
  23                 @scroll_top = 0
  24                 @scroll_bottom = height - 1
  25                 @resize width, height
  26
  27         resize: (width, height) ->
  28                 # FIXME: write a version that retains some of the data
  29                 # FIXME: clamp variables (eg x, y, saved.*, scrolling region) if getting smaller
  30                 @width = width
  31                 @height = height
  32                 @text = []
  33                 @attributes = []
  34                 for y in [0...height]
  35                         @text[y] = []
  36                         @attributes[y] = []
  37                         for x in [0...width]
  38                                 @text[y].push ' '
  39                                 @attributes[y].push 0x07
  40
  41         # pass data from stdout
  42         update: (data) ->
  43                 return unless data?.length > 0
  44                 if @partial.length > 0
  45                         data = @partial + data
  46                         @partial = ''
  47                 parts = data.split(/\x1b\[/)
  48                 if parts.length > 1
  49                         if -1 is @escape_sequence_length parts[parts.length - 1]
  50                                 @partial = parts.pop()
  51                 if parts.length > 0
  52                         for i in [0...parts.length]
  53                                 if i is 0
  54                                         @update_text parts[i]
  55                                 else
  56                                         @update_sequence_then_text parts[i]
  57                 return
  58
  59         add_new_line: ->
  60                 # clear the line at the top of the scrolling region
  61                 for i in [0...@width]
  62                         @text[@scroll_top][i] = ' '
  63                         @attributes[@scroll_top][i] = 0x07
  64
  65                 # move (newly cleared) top line to the bottom of the scrolling region
  66                 @text = [
  67                         @text[0...@scroll_top]..., # up to but not including scroll top
  68                         @text[@scroll_top + 1 .. @scroll_bottom]..., # scroll region except top line of it
  69                         @text[@scroll_top], # top line of scroll region (already cleared)
  70                         @text[@scroll_bottom + 1 ... @height]... # rest of screen
  71                 ]
  72                 @attributes = [
  73                         @attributes[0...@scroll_top]..., # up to but not including scroll top
  74                         @attributes[@scroll_top + 1 .. @scroll_bottom]..., # scroll region except top line of it
  75                         @attributes[@scroll_top], # top line of scroll region (already cleared)
  76                         @attributes[@scroll_bottom + 1 ... @height]... # rest of screen
  77                 ]
  78
  79                 # slide cursor up with rest of text
  80                 @y -= 1
  81
  82         wrap_to_next_line: ->
  83                 if @y is @scroll_bottom
  84                         @add_new_line()
  85                 @y += 1
  86                 @x = 0
  87
  88         # str has no escape sequences
  89         update_text: (str) ->
  90                 return unless str.length > 0
  91                 for c in str
  92                         switch c
  93                                 when '\t' # tab
  94                                         @update_text "        ".substr(@x % 8)
  95                                 when '\x07' # bell
  96                                         false
  97                                 when '\x0d' # cr
  98                                         @x = 0
  99                                 when '\x08' # backspace
 100                                         if @x is 0
 101                                                 @x = @width - 1
 102                                                 if @y > 0
 103                                                         @y -= 1
 104                                         else
 105                                                 @x -= 1
 106                                 when '\x0a', '\x0b' # lf, vertical tab (same thing)
 107                                         @wrap_to_next_line()
 108                                 else
 109                                         if @x >= @width
 110                                                 @wrap_to_next_line()
 111                                         @text[@y][@x] = c
 112                                         @attributes[@y][@x] = @a
 113                                         @x += 1
 114                 return
 115
 116         set_attribute_bits: (mask, value) ->
 117                 @a = ((@a & ~mask) | value)
 118
 119         # we're supposed to ignore leeding zeros, and while we're at it, lets swap
 120         # in the default for blank or missing values
 121         fix_esc_arg: (value, deef_alt) ->
 122                 if value? and value != ''
 123                         while value[0] is '0' and value.length > 1
 124                                 value = value.substr 1
 125                         return value
 126                 else
 127                         return deef_alt
 128
 129         # csi_@: rxvt does nothing I can detect
 130
 131         # move cursor up
 132         csi_A: (lines) ->
 133                 lines = parseInt @fix_esc_arg lines, '1'
 134                 @y -= lines
 135                 if @y < 0
 136                         @y = 0
 137                 return
 138
 139         # move cursor down
 140         csi_B: (lines) ->
 141                 lines = parseInt @fix_esc_arg lines, '1'
 142                 @y += lines
 143                 if @y >= @height
 144                         @y = @height - 1
 145                 return
 146
 147         # move cursor right
 148         csi_C: (cols) ->
 149                 cols = parseInt @fix_esc_arg cols, '1'
 150                 @x += cols
 151                 if @x >= @width
 152                         @x = @width - 1
 153                 return
 154
 155         # move cursor left
 156         csi_D: (cols) ->
 157                 cols = parseInt @fix_esc_arg cols, '1'
 158                 @x -= cols
 159                 if @x < 0
 160                         @x = 0
 161                 return
 162
 163         # set cursor position (one based)
 164         csi_H: (row, column) ->
 165                 # handle blank/missing args and convert to 0 base
 166                 row = -1 + parseInt @fix_esc_arg row, '1'
 167                 column = -1 + parseInt @fix_esc_arg column, '1'
 168
 169                 #clamp values
 170                 if column < 0
 171                         column = 0
 172                 else if column >= @width
 173                         column = @width - 1
 174                 if row < 0
 175                         row = 0
 176                 if row >= @height
 177                         row = @height - 1
 178
 179                 #move the cursor
 180                 @x = column
 181                 @y = row
 182                 return
 183
 184         # clear to screen edge(es)
 185         csi_J: (direction) ->
 186                 switch @fix_esc_arg direction, '0'
 187                         when '0' # erase down
 188                                 # rest of current line
 189                                 @csi_K direction
 190                                 # rest of lines
 191                                 for row in [@y...@height]
 192                                         for i in [0...@width]
 193                                                 @text[row][i] = ' '
 194                                                 @attributes[row][i] = @a
 195                         when '1' # erase up
 196                                 # beginning of current line
 197                                 @csi_K direction
 198                                 # all previous lines
 199                                 for row in [0..@y]
 200                                         for i in [0...@width]
 201                                                 @text[row][i] = ' '
 202                                                 @attributes[row][i] = @a
 203                         when '2' # erase everything
 204                                 for row in [0...@height]
 205                                         for i in [0...@width]
 206                                                 @text[row][i] = ' '
 207                                                 @attributes[row][i] = @a
 208                         else
 209                                 console.log "confusing arg for csi_J: #{direction}"
 210                 return
 211
 212         # clear (some or all of) current line
 213         csi_K: (direction) ->
 214                 switch @fix_esc_arg direction, '0'
 215                         when '0' # erase to right
 216                                 for i in [@x...@width]
 217                                         @text[@y][i] = ' '
 218                                         @attributes[@y][i] = @a
 219                         when '1' # erase to left
 220                                 # @x can equal @width (after printing to right-most column)
 221                                 if @x < @width
 222                                         max = @x
 223                                 else
 224                                         max = @width - 1
 225                                 for i in [0..max]
 226                                         @text[@y][i] = ' '
 227                                         @attributes[@y][i] = @a
 228                         when '2' # erase whole line
 229                                 for i in [0...@width]
 230                                         @text[@y][i] = ' '
 231                                         @attributes[@y][i] = @a
 232                         else
 233                                 console.log "confusing arg for csi_K: #{direction}"
 234                 return
 235
 236         # misc
 237         csiq_h: ->
 238                 args = []
 239                 for i in arguments
 240                         arg = @fix_esc_arg i, ''
 241                         switch arg
 242                                 when '25'
 243                                         @cursor_visible = true
 244                                 when '1049'
 245                                         if @saved_normal_screen?
 246                                                 console.log "ignoring request to switch to the alt screen because we're already on the alt screen"
 247                                                 return
 248                                         @saved_normal_screen = [@x, @y, @text, @attributes]
 249                                         @text = []
 250                                         @attributes = []
 251                                         for y in [0...@height]
 252                                                 @text[y] = []
 253                                                 @attributes[y] = []
 254                                                 for x in [0...@width]
 255                                                         @text[y].push ' '
 256                                                         @attributes[y].push 0x07
 257                                 else
 258                                         console.log "confusing arg for csiq_h: #{arg}"
 259                 return
 260
 261         # unmisc
 262         csiq_l: ->
 263                 args = []
 264                 for i in arguments
 265                         arg = @fix_esc_arg i, ''
 266                         switch arg
 267                                 when '25'
 268                                         @cursor_visible = false
 269                                 when '1049'
 270                                         if not @saved_normal_screen?
 271                                                 console.log "ignoring request to switch to the normal screen because we're already on the normal screen"
 272                                                 return
 273                                         @x = @saved_normal_screen[0]
 274                                         @y = @saved_normal_screen[1]
 275                                         @text = @saved_normal_screen[2]
 276                                         @attributes = @saved_normal_screen[3]
 277                                         @saved_normal_screen = null
 278                                 else
 279                                         console.log "confusing arg for csiq_l: #{arg}"
 280                 return
 281
 282         # set color, bold, underline, etc
 283         csi_m: ->
 284                 args = []
 285                 for i in arguments
 286                         args.push @fix_esc_arg i, '0'
 287
 288                 while args.length > 0
 289                         arg = args.shift()
 290                         switch arg
 291                                 # remove all style/color
 292                                 when '0'
 293                                         @a = 0x07
 294
 295                                 # style attributes
 296                                 when '1' # bold
 297                                         @set_attribute_bits 0x010000, 0x010000
 298                                 when '3' # italic (rare)
 299                                         @set_attribute_bits 0x200000, 0x200000
 300                                 when '4' # underline
 301                                         @set_attribute_bits 0x020000, 0x020000
 302                                 when '5' # blink
 303                                         @set_attribute_bits 0x040000, 0x040000
 304                                 when '7' # inverse
 305                                         @set_attribute_bits 0x080000, 0x080000
 306                                 when '8' # invisible. urivt ignores this
 307                                         @set_attribute_bits 0x100000, 0x100000
 308
 309                                 # disable style attributes
 310                                 when '21' # not bold (rare)
 311                                         @set_attribute_bits 0x010000, 0
 312                                 when '22' # not bold
 313                                         @set_attribute_bits 0x010000, 0
 314                                 when '23' # not italic (rare)
 315                                         @set_attribute_bits 0x200000, 0
 316                                 when '24' # not underline
 317                                         @set_attribute_bits 0x020000, 0
 318                                 when '25' # not blink
 319                                         @set_attribute_bits 0x040000, 0
 320                                 when '27' # not inverse
 321                                         @set_attribute_bits 0x080000, 0
 322                                 when '28' # not invisible
 323                                         @set_attribute_bits 0x100000, 0
 324
 325                                 when '100' # reset colors but not other attributes
 326                                         @set_attribute_bits 0xffff, 0x0007
 327
 328                                 # 8 fg colors
 329                                 when '30' # fg black
 330                                         @set_attribute_bits 0xff, 0x00
 331                                 when '31' # fg red
 332                                         @set_attribute_bits 0xff, 0x01
 333                                 when '32' # fg green
 334                                         @set_attribute_bits 0xff, 0x02
 335                                 when '33' # fg yellow
 336                                         @set_attribute_bits 0xff, 0x03
 337                                 when '34' # fg blue
 338                                         @set_attribute_bits 0xff, 0x04
 339                                 when '35' # fg magenta
 340                                         @set_attribute_bits 0xff, 0x05
 341                                 when '36' # fg cyan
 342                                         @set_attribute_bits 0xff, 0x06
 343                                 when '37', '39' # fg white  (39 is default)
 344                                         @set_attribute_bits 0xff, 0x07
 345
 346                                 when '38'
 347                                         if args.length >= 2 and args[0] is '5'
 348                                                 args.shift()
 349                                                 @set_attribute_bits 0xff, (0xff & args.shift())
 350                                         else
 351                                                 @set_attribute_bits 0x20000, 0x20000
 352
 353                                 # 8 bg colors
 354                                 when '40' # bg black
 355                                         @set_attribute_bits 0xff00, 0x0000
 356                                 when '41' # bg red
 357                                         @set_attribute_bits 0xff00, 0x0100
 358                                 when '42' # bg green
 359                                         @set_attribute_bits 0xff00, 0x0200
 360                                 when '43' # bg yellow
 361                                         @set_attribute_bits 0xff00, 0x0300
 362                                 when '44' # bg blue
 363                                         @set_attribute_bits 0xff00, 0x0400
 364                                 when '45' # bg magenta
 365                                         @set_attribute_bits 0xff00, 0x0500
 366                                 when '46' # bg cyan
 367                                         @set_attribute_bits 0xff00, 0x0600
 368                                 when '47' # bg white
 369                                         @set_attribute_bits 0xff00, 0x0700
 370                                 when '49' # bg default
 371                                         @set_attribute_bits 0xff00, 0x0000
 372
 373                                 when '48'
 374                                         if args.length >= 2 and args[0] is '5'
 375                                                 args.shift()
 376                                                 @set_attribute_bits 0xff00, ((0xff & args.shift()) << 8)
 377                                         else
 378                                                 @set_attribute_bits 0x20000, 0x20000
 379
 380                                 # bright fg colors
 381                                 when '90' # fg bright black
 382                                         @set_attribute_bits 0xff, 0x08
 383                                 when '91' # fg bright red
 384                                         @set_attribute_bits 0xff, 0x09
 385                                 when '92' # fg bright green
 386                                         @set_attribute_bits 0xff, 0x0a
 387                                 when '93' # fg bright yellow
 388                                         @set_attribute_bits 0xff, 0x0b
 389                                 when '94' # fg bright blue
 390                                         @set_attribute_bits 0xff, 0x0c
 391                                 when '95' # fg bright magenta
 392                                         @set_attribute_bits 0xff, 0x0d
 393                                 when '96' # fg bright cyan
 394                                         @set_attribute_bits 0xff, 0x0e
 395                                 when '97' # fg bright white
 396                                         @set_attribute_bits 0xff, 0x0f
 397
 398                                 # bright bg colors
 399                                 when '100' # bg bright black
 400                                         @set_attribute_bits 0xff, 0x08
 401                                 when '101' # bg bright red
 402                                         @set_attribute_bits 0xff, 0x09
 403                                 when '102' # bg bright green
 404                                         @set_attribute_bits 0xff, 0x0a
 405                                 when '103' # bg bright yellow
 406                                         @set_attribute_bits 0xff, 0x0b
 407                                 when '104' # bg bright blue
 408                                         @set_attribute_bits 0xff, 0x0c
 409                                 when '105' # bg bright magenta
 410                                         @set_attribute_bits 0xff, 0x0d
 411                                 when '106' # bg bright cyan
 412                                         @set_attribute_bits 0xff, 0x0e
 413                                 when '107' # bg bright white
 414                                         @set_attribute_bits 0xff, 0x0f
 415
 416                                 else
 417                                         # if we don't recognize the style, go back to default
 418                                         console.log "unrecognized csi_m arg: \"#{arg}\""
 419                                         @a = 0
 420                 return
 421
 422         # set scrolling region
 423         csi_r: (top, bottom) ->
 424                 top = -1 + parseInt @fix_esc_arg top, '1'
 425                 bottom = -1 + parseInt @fix_esc_arg bottom, '10000'
 426                 if top < 0
 427                         top = 0
 428                 if bottom >= @height
 429                         bottom = @height - 1
 430                 @scroll_top = top
 431                 @scroll_bottom = bottom
 432                 return
 433
 434         # str is the whole escape sequence (minus the esc[ prefix)
 435         update_sequence: (str) ->
 436                 prefix = 'csi_'
 437                 if str[0] is '?'
 438                         prefix = 'csiq_'
 439                         str = str.substr 1
 440                 command = @[prefix + str.substr(str.length - 1)]
 441                 if not command?
 442                         console.log "Unrecognized sequence: ESC[#{str}"
 443                         return
 444                 args = str.substr(0, str.length - 1).split ';'
 445                 command.call this, args...
 446
 447         update_sequence_then_text: (str) ->
 448                 len = @escape_sequence_length str
 449                 if len is -1
 450                         console.log "couldn't find escape sequence here: #{str.substr 0, 25}"
 451                         @update_text "ESC[" + str
 452                 else
 453                         @update_sequence str.substr 0, len
 454                         @update_text str.substr len
 455
 456         escape_sequence_length: (str) ->
 457                 parts = str.match(/^[0-9;?]{0,25}./)
 458                 return -1 unless parts?
 459                 return parts[0].length
 460
 461 my_exports.new = (width, height) ->
 462         return new Terminal width, height