terminal.coffee

   1 # this file is used by the client and server.
   2
   3 # work around lack of module system in the browser:
   4 if exports?
   5         my_exports = exports
   6 else
   7         window.terminal = {}
   8         my_exports = window.terminal
   9
  10 class Terminal
  11         # public:
  12         constructor: (width, height) ->
  13                 @width = 1
  14                 @height = 1
  15                 @text = []
  16                 @attributes = []
  17                 @x = 0
  18                 @y = 0
  19                 @a = 0x000007 # cursor attributes
  20                 @partial = ''
  21                 @saved_normal_screen = null
  22                 @resize width, height
  23
  24         resize: (width, height) ->
  25                 # FIXME: write a version that retains some of the data
  26                 @width = width
  27                 @height = height
  28                 @text = []
  29                 @attributes = []
  30                 for y in [0...height]
  31                         @text[y] = []
  32                         @attributes[y] = []
  33                         for x in [0...width]
  34                                 @text[y].push ' '
  35                                 @attributes[y].push 0
  36
  37         # pass data from stdout
  38         update: (data) ->
  39                 return unless data?.length > 0
  40                 if @partial.length > 0
  41                         data = @partial + data
  42                         @partial = ''
  43                 parts = data.split(/\x1b\[/)
  44                 if parts.length > 1
  45                         if -1 is @escape_sequence_length parts[parts.length - 1]
  46                                 @partial = parts.pop()
  47                 if parts.length > 0
  48                         for i in [0...parts.length]
  49                                 if i is 0
  50                                         @update_text parts[i]
  51                                 else
  52                                         @update_sequence_then_text parts[i]
  53                 return
  54
  55         add_new_line: ->
  56                 # clear top line
  57                 for i in [0...@width]
  58                         @text[0][i] = ' '
  59                         @attributes[0][i] = 0
  60                 # move (newly cleared) top line to the bottom
  61                 tmp = @text.shift()
  62                 @text.push(tmp)
  63                 tmp = @attributes.shift()
  64                 @attributes.push(tmp)
  65                 # slide cursor up with rest of text
  66                 @y -= 1
  67
  68         wrap_to_next_line: ->
  69                 if @y is @height - 1
  70                         @add_new_line()
  71                 @y += 1
  72                 @x = 0
  73
  74         # str has no escape sequences
  75         update_text: (str) ->
  76                 return unless str.length > 0
  77                 for c in str
  78                         switch c
  79                                 when '\t' # tab
  80                                         @update_text "        ".substr(@x % 8)
  81                                 when '\x07' # bell
  82                                         false
  83                                 when '\x0d' # cr
  84                                         @x = 0
  85                                 when '\x08' # backspace
  86                                         if @x is 0
  87                                                 @x = @width - 1
  88                                                 if @y > 0
  89                                                         @y -= 1
  90                                         else
  91                                                 @x -= 1
  92                                 when '\x0a', '\x0b' # lf, vertical tab (same thing)
  93                                         @wrap_to_next_line()
  94                                 else
  95                                         if @x >= @width
  96                                                 @wrap_to_next_line()
  97                                         @text[@y][@x] = c
  98                                         @attributes[@y][@x] = @a
  99                                         @x += 1
 100                 return
 101
 102         set_attribute_bits: (mask, value) ->
 103                 @a = (@a & ~mask) | value
 104
 105         # we're supposed to ignore leeding zeros, and while we're at it, lets swap
 106         # in the default for blank or missing values
 107         fix_esc_arg: (value, deef_alt) ->
 108                 if value? and value != ''
 109                         while value[0] is '0' and value.length > 1
 110                                 value = value.substr 1
 111                         return value
 112                 else
 113                         return deef_alt
 114
 115         # set cursor position (one based)
 116         csi_H: (row, column) ->
 117                 row = 0 + @fix_esc_arg row, 1
 118                 column = 0 + @fix_esc_arg column, 1
 119
 120                 # convert to 0 base
 121                 column -= 1
 122
 123                 #clamp values
 124                 if column < 0
 125                         column = 0
 126                 else if column >= @width
 127                         column = @width - 1
 128                 if row < 0
 129                         row = 0
 130                 if row >= @height
 131                         row = @height - 1
 132
 133                 #move the cursor
 134                 @x = column
 135                 @y = row
 136
 137         # clear to screen edge(es)
 138         csi_J: (direction) ->
 139                 switch @fix_esc_arg direction, '0'
 140                         when '0' # erase down
 141                                 # rest of current line
 142                                 @csi_K direction
 143                                 # rest of lines
 144                                 for row in [@y...@height]
 145                                         for i in [0...@width]
 146                                                 @text[row][i] = ' '
 147                                                 @attributes[row][i] = @a
 148                         when '1' # erase up
 149                                 # beginning of current line
 150                                 @csi_K direction
 151                                 # all previous lines
 152                                 for row in [0..@y]
 153                                         for i in [0...@width]
 154                                                 @text[row][i] = ' '
 155                                                 @attributes[row][i] = @a
 156                         when '2' # erase everything
 157                                 for row in [0...@height]
 158                                         for i in [0...@width]
 159                                                 @text[row][i] = ' '
 160                                                 @attributes[row][i] = @a
 161                         else
 162                                 console.log "confusing arg for csi_J: #{direction}"
 163
 164         # clear (some or all of) current line
 165         csi_K: (direction) ->
 166                 switch @fix_esc_arg direction, '0'
 167                         when '0' # erase to right
 168                                 for i in [@x...@width]
 169                                         @text[@y][i] = ' '
 170                                         @attributes[@y][i] = @a
 171                         when '1' # erase to left
 172                                 # @x can equal @width (after printing to right-most column)
 173                                 if @x < @width
 174                                         max = @x
 175                                 else
 176                                         max = @width - 1
 177                                 for i in [0..max]
 178                                         @text[@y][i] = ' '
 179                                         @attributes[@y][i] = @a
 180                         when '2' # erase whole line
 181                                 for i in [0...@width]
 182                                         @text[@y][i] = ' '
 183                                         @attributes[@y][i] = @a
 184                         else
 185                                 console.log "confusing arg for csi_K: #{direction}"
 186
 187         # misc
 188         csiq_h: ->
 189                 args = []
 190                 for i in arguments
 191                         switch @fix_esc_arg i, ''
 192                                 when '1049'
 193                                         if @saved_normal_screen?
 194                                                 console.log "ignoring request to switch to the alt screen because we're already on the alt screen"
 195                                                 return
 196                                         @saved_normal_screen = [@x, @y, @text, @attributes]
 197                                         @text = []
 198                                         @attributes = []
 199                                         for y in [0...@height]
 200                                                 @text[y] = []
 201                                                 @attributes[y] = []
 202                                                 for x in [0...@width]
 203                                                         @text[y].push ' '
 204                                                         @attributes[y].push 0
 205         # unmisc
 206         csiq_l: ->
 207                 args = []
 208                 for i in arguments
 209                         switch @fix_esc_arg i, ''
 210                                 when '1049'
 211                                         if not @saved_normal_screen?
 212                                                 console.log "ignoring request to switch to the normal screen because we're already on the normal screen"
 213                                                 return
 214                                         @x = @saved_normal_screen[0]
 215                                         @y = @saved_normal_screen[1]
 216                                         @text = @saved_normal_screen[2]
 217                                         @attributes = @saved_normal_screen[3]
 218                                         @saved_normal_screen = null
 219
 220         # set color, bold, underline, etc
 221         csi_m: ->
 222                 args = []
 223                 for i in arguments
 224                         args.push @fix_esc_arg i, 0
 225
 226                 while args.length > 0
 227                         switch args.shift()
 228
 229                                 # remove all style/color
 230                                 when '0'
 231                                         @set_attribute_bits 0xffffff, 0x000007
 232
 233                                 # style attributes
 234                                 when '1' # bold
 235                                         @set_attribute_bits 0x10000, 0x10000
 236                                 when '4' # underline
 237                                         @set_attribute_bits 0x20000, 0x20000
 238                                 when '5' # blink
 239                                         @set_attribute_bits 0x40000, 0x40000
 240                                 when '8' # invisible
 241                                         @set_attribute_bits 0x80000, 0x80000
 242
 243                                 # disable style attributes
 244                                 when '22' # not bold... according to a page
 245                                         @set_attribute_bits 0x10000, 0
 246                                 when '21' # ... though this would make more sense for "not bold"
 247                                         @set_attribute_bits 0x10000, 0
 248                                 when '24' # not underline
 249                                         @set_attribute_bits 0x20000, 0
 250                                 when '25' # not blink
 251                                         @set_attribute_bits 0x40000, 0
 252                                 when '28' # not invisible
 253                                         @set_attribute_bits 0x80000, 0
 254
 255                                 when '100' # reset colors but not other attributes
 256                                         @set_attribute_bits 0xffff, 0x0007
 257
 258                                 # 8 fg colors
 259                                 when '30' # fg black
 260                                         @set_attribute_bits 0xff, 0x00
 261                                 when '31' # fg red
 262                                         @set_attribute_bits 0xff, 0x01
 263                                 when '32' # fg green
 264                                         @set_attribute_bits 0xff, 0x02
 265                                 when '33' # fg yellow
 266                                         @set_attribute_bits 0xff, 0x03
 267                                 when '34' # fg blue
 268                                         @set_attribute_bits 0xff, 0x04
 269                                 when '35' # fg magenta
 270                                         @set_attribute_bits 0xff, 0x05
 271                                 when '36' # fg cyan
 272                                         @set_attribute_bits 0xff, 0x06
 273                                 when '37', '39' # fg white  (39 is default)
 274                                         @set_attribute_bits 0xff, 0x07
 275
 276                                 when '38'
 277                                         if args.length >= 2 and args[0] is '5'
 278                                                 args.shift()
 279                                                 @set_attribute_bits 0xff, (0xff & args.shift())
 280                                         else
 281                                                 @set_attribute_bits 0x20000, 0x20000
 282
 283                                 # 8 bg colors
 284                                 when '40' # bg black
 285                                         @set_attribute_bits 0xff00, 0x0000
 286                                 when '41' # bg red
 287                                         @set_attribute_bits 0xff00, 0x0100
 288                                 when '42' # bg green
 289                                         @set_attribute_bits 0xff00, 0x0200
 290                                 when '43' # bg yellow
 291                                         @set_attribute_bits 0xff00, 0x0300
 292                                 when '44' # bg blue
 293                                         @set_attribute_bits 0xff00, 0x0400
 294                                 when '45' # bg magenta
 295                                         @set_attribute_bits 0xff00, 0x0500
 296                                 when '46' # bg cyan
 297                                         @set_attribute_bits 0xff00, 0x0600
 298                                 when '47' # bg white
 299                                         @set_attribute_bits 0xff00, 0x0700
 300                                 when '49' # bg default
 301                                         @set_attribute_bits 0xff00, 0x0000
 302
 303                                 when '48'
 304                                         if args.length >= 2 and args[0] is '5'
 305                                                 args.shift()
 306                                                 @set_attribute_bits 0xff00, ((0xff & args.shift()) << 8)
 307                                         else
 308                                                 @set_attribute_bits 0x20000, 0x20000
 309
 310                                 # bright fg colors
 311                                 when '90' # fg bright black
 312                                         @set_attribute_bits 0xff, 0x08
 313                                 when '91' # fg bright red
 314                                         @set_attribute_bits 0xff, 0x09
 315                                 when '92' # fg bright green
 316                                         @set_attribute_bits 0xff, 0x0a
 317                                 when '93' # fg bright yellow
 318                                         @set_attribute_bits 0xff, 0x0b
 319                                 when '94' # fg bright blue
 320                                         @set_attribute_bits 0xff, 0x0c
 321                                 when '95' # fg bright magenta
 322                                         @set_attribute_bits 0xff, 0x0d
 323                                 when '96' # fg bright cyan
 324                                         @set_attribute_bits 0xff, 0x0e
 325                                 when '97' # fg bright white
 326                                         @set_attribute_bits 0xff, 0x0f
 327
 328                                 # bright bg colors
 329                                 when '100' # bg bright black
 330                                         @set_attribute_bits 0xff, 0x08
 331                                 when '101' # bg bright red
 332                                         @set_attribute_bits 0xff, 0x09
 333                                 when '102' # bg bright green
 334                                         @set_attribute_bits 0xff, 0x0a
 335                                 when '103' # bg bright yellow
 336                                         @set_attribute_bits 0xff, 0x0b
 337                                 when '104' # bg bright blue
 338                                         @set_attribute_bits 0xff, 0x0c
 339                                 when '105' # bg bright magenta
 340                                         @set_attribute_bits 0xff, 0x0d
 341                                 when '106' # bg bright cyan
 342                                         @set_attribute_bits 0xff, 0x0e
 343                                 when '107' # bg bright white
 344                                         @set_attribute_bits 0xff, 0x0f
 345
 346
 347                                 else
 348                                         # if we don't recognize the style, go back to default
 349                                         @set_attribute_bits 0xffffff, 0
 350                 return
 351
 352         # str is the whole escape sequence (minus the esc[ prefix)
 353         update_sequence: (str) ->
 354                 prefix = 'csi_'
 355                 if str[0] is '?'
 356                         prefix = 'csiq_'
 357                         str = str.substr 1
 358                 command = @[prefix + str.substr(str.length - 1)]
 359                 if not command?
 360                         console.log "Unrecognized sequence: ESC[#{str}"
 361                         return
 362                 args = str.substr(0, str.length - 1).split ';'
 363                 command.call this, args...
 364
 365         update_sequence_then_text: (str) ->
 366                 len = @escape_sequence_length str
 367                 if len is -1
 368                         console.log "couldn't find escape sequence here: #{str.substr 0, 25}"
 369                         @update_text "ESC[" + str
 370                 else
 371                         @update_sequence str.substr 0, len
 372                         @update_text str.substr len
 373
 374         escape_sequence_length: (str) ->
 375                 parts = str.match(/^[0-9;?]{0,25}./)
 376                 return -1 unless parts?
 377                 return parts[0].length
 378
 379 my_exports.new = (width, height) ->
 380         return new Terminal width, height