terminal.coffee

   1 # this file is used by the client and server.
   2
   3 # work around lack of module system in the browser:
   4 if exports?
   5         my_exports = exports
   6 else
   7         window.terminal = {}
   8         my_exports = window.terminal
   9
  10 class Terminal
  11         # public:
  12         constructor: (width, height) ->
  13                 @width = 1
  14                 @height = 1
  15                 @text = []
  16                 @attributes = []
  17                 @x = 0
  18                 @y = 0
  19                 @a = 0x000007 # cursor attributes
  20                 @partial = ''
  21                 @saved_normal_screen = null
  22                 @resize width, height
  23
  24         resize: (width, height) ->
  25                 # FIXME: write a version that retains some of the data
  26                 @width = width
  27                 @height = height
  28                 @text = []
  29                 @attributes = []
  30                 for y in [0...height]
  31                         @text[y] = []
  32                         @attributes[y] = []
  33                         for x in [0...width]
  34                                 @text[y].push ' '
  35                                 @attributes[y].push 0
  36
  37         # pass data from stdout
  38         update: (data) ->
  39                 return unless data?.length > 0
  40                 if @partial.length > 0
  41                         data = @partial + data
  42                         @partial = ''
  43                 parts = data.split(/\x1b\[/)
  44                 if parts.length > 1
  45                         if -1 is @escape_sequence_length parts[parts.length - 1]
  46                                 @partial = parts.pop()
  47                 if parts.length > 0
  48                         for i in [0...parts.length]
  49                                 if i is 0
  50                                         @update_text parts[i]
  51                                 else
  52                                         @update_sequence_then_text parts[i]
  53                 return
  54
  55         add_new_line: ->
  56                 # clear top line
  57                 for i in [0...@width]
  58                         @text[0][i] = ' '
  59                         @attributes[0][i] = 0
  60                 # move (newly cleared) top line to the bottom
  61                 tmp = @text.shift()
  62                 @text.push(tmp)
  63                 tmp = @attributes.shift()
  64                 @attributes.push(tmp)
  65                 # slide cursor up with rest of text
  66                 @y -= 1
  67
  68         wrap_to_next_line: ->
  69                 if @y is @height - 1
  70                         @add_new_line()
  71                 @y += 1
  72                 @x = 0
  73
  74         # str has no escape sequences
  75         update_text: (str) ->
  76                 return unless str.length > 0
  77                 for c in str
  78                         switch c
  79                                 when '\t' # tab
  80                                         @update_text "        ".substr(@x % 8)
  81                                 when '\x07' # bell
  82                                         false
  83                                 when '\x0d' # cr
  84                                         @x = 0
  85                                 when '\x08' # backspace
  86                                         if @x > 0
  87                                                 @x -= 1
  88                                                 @text[@y][@x] = ' '
  89                                                 # should this set the attribute too?
  90                                 when '\x0a', '\x0b' # lf, vertical tab (same thing)
  91                                         @wrap_to_next_line()
  92                                 else
  93                                         @text[@y][@x] = c
  94                                         @attributes[@y][@x] = @a
  95                                         @x += 1
  96                                         if @x is @width
  97                                                 @wrap_to_next_line()
  98                 return
  99
 100         set_attribute_bits: (mask, value) ->
 101                 @a = (@a & ~mask) | value
 102
 103         # we're supposed to ignore leeding zeros, and while we're at it, lets swap
 104         # in the default for blank or missing values
 105         fix_esc_arg: (value, deef_alt) ->
 106                 if value? and value != ''
 107                         while value[0] is '0' and value.length > 1
 108                                 value = value.substr 1
 109                         return value
 110                 else
 111                         return deef_alt
 112
 113         # set cursor position (one based)
 114         csi_H: (row, column) ->
 115                 row = 0 + @fix_esc_arg row, 1
 116                 column = 0 + @fix_esc_arg column, 1
 117
 118                 # convert to 0 base
 119                 column -= 1
 120
 121                 #clamp values
 122                 if column < 0
 123                         column = 0
 124                 else if column >= @width
 125                         column = @width - 1
 126                 if row < 0
 127                         row = 0
 128                 if row >= @height
 129                         row = @height - 1
 130
 131                 #move the cursor
 132                 @x = column
 133                 @y = row
 134
 135         # clear lines (implemented inclusive of the current line)
 136         csi_J: (direction) ->
 137                 switch @fix_esc_arg direction, '0'
 138                         when '0' # erase down
 139                                 for row in [@y...@height]
 140                                         for i in [0...@width]
 141                                                 @text[row][i] = ' '
 142                                                 @attributes[row][i] = @a
 143                         when '1' # erase up
 144                                 for row in [0..@y]
 145                                         for i in [0...@width]
 146                                                 @text[row][i] = ' '
 147                                                 @attributes[row][i] = @a
 148                         when '2' # erase everything
 149                                 for row in [0...@height]
 150                                         for i in [0...@width]
 151                                                 @text[row][i] = ' '
 152                                                 @attributes[row][i] = @a
 153                         else
 154                                 console.log "confusing arg for csi_J: #{direction}"
 155
 156         # clear (some or all of) current line
 157         csi_K: (direction) ->
 158                 switch @fix_esc_arg direction, '0'
 159                         when '0' # erase to right
 160                                 for i in [@x...@width]
 161                                         @text[@y][i] = ' '
 162                                         @attributes[@y][i] = @a
 163                         when '1' # erase to left
 164                                 for i in [0...@x]
 165                                         @text[@y][i] = ' '
 166                                         @attributes[@y][i] = @a
 167                         when '2' # erase whole line
 168                                 for i in [0...@width]
 169                                         @text[@y][i] = ' '
 170                                         @attributes[@y][i] = @a
 171                         else
 172                                 console.log "confusing arg for csi_K: #{direction}"
 173
 174         # misc
 175         csiq_h: ->
 176                 args = []
 177                 for i in arguments
 178                         switch @fix_esc_arg i, ''
 179                                 when '1049'
 180                                         if @saved_normal_screen?
 181                                                 console.log "ignoring request to switch to the alt screen because we're already on the alt screen"
 182                                                 return
 183                                         @saved_normal_screen = [@x, @y, @text, @attributes]
 184                                         @text = []
 185                                         @attributes = []
 186                                         for y in [0...@height]
 187                                                 @text[y] = []
 188                                                 @attributes[y] = []
 189                                                 for x in [0...@width]
 190                                                         @text[y].push ' '
 191                                                         @attributes[y].push 0
 192         # unmisc
 193         csiq_l: ->
 194                 args = []
 195                 for i in arguments
 196                         switch @fix_esc_arg i, ''
 197                                 when '1049'
 198                                         if not @saved_normal_screen?
 199                                                 console.log "ignoring request to switch to the normal screen because we're already on the normal screen"
 200                                                 return
 201                                         @x = @saved_normal_screen[0]
 202                                         @y = @saved_normal_screen[1]
 203                                         @text = @saved_normal_screen[2]
 204                                         @attributes = @saved_normal_screen[3]
 205                                         @saved_normal_screen = null
 206
 207         # set color, bold, underline, etc
 208         csi_m: ->
 209                 args = []
 210                 for i in arguments
 211                         args.push @fix_esc_arg i, 0
 212
 213                 while args.length > 0
 214                         switch args.shift()
 215
 216                                 # remove all style/color
 217                                 when '0'
 218                                         @set_attribute_bits 0xffffff, 0x000007
 219
 220                                 # style attributes
 221                                 when '1' # bold
 222                                         @set_attribute_bits 0x10000, 0x10000
 223                                 when '4' # underline
 224                                         @set_attribute_bits 0x20000, 0x20000
 225                                 when '5' # blink
 226                                         @set_attribute_bits 0x40000, 0x40000
 227                                 when '8' # invisible
 228                                         @set_attribute_bits 0x80000, 0x80000
 229
 230                                 # disable style attributes
 231                                 when '22' # not bold... according to a page
 232                                         @set_attribute_bits 0x10000, 0
 233                                 when '21' # ... though this would make more sense for "not bold"
 234                                         @set_attribute_bits 0x10000, 0
 235                                 when '24' # not underline
 236                                         @set_attribute_bits 0x20000, 0
 237                                 when '25' # not blink
 238                                         @set_attribute_bits 0x40000, 0
 239                                 when '28' # not invisible
 240                                         @set_attribute_bits 0x80000, 0
 241
 242                                 when '100' # reset colors but not other attributes
 243                                         @set_attribute_bits 0xffff, 0x0007
 244
 245                                 # 8 fg colors
 246                                 when '30' # fg black
 247                                         @set_attribute_bits 0xff, 0x00
 248                                 when '31' # fg red
 249                                         @set_attribute_bits 0xff, 0x01
 250                                 when '32' # fg green
 251                                         @set_attribute_bits 0xff, 0x02
 252                                 when '33' # fg yellow
 253                                         @set_attribute_bits 0xff, 0x03
 254                                 when '34' # fg blue
 255                                         @set_attribute_bits 0xff, 0x04
 256                                 when '35' # fg magenta
 257                                         @set_attribute_bits 0xff, 0x05
 258                                 when '36' # fg cyan
 259                                         @set_attribute_bits 0xff, 0x06
 260                                 when '37', '39' # fg white  (39 is default)
 261                                         @set_attribute_bits 0xff, 0x07
 262
 263                                 when '38'
 264                                         if args.length >= 2 and args[0] is '5'
 265                                                 args.shift()
 266                                                 @set_attribute_bits 0xff, (0xff & args.shift())
 267                                         else
 268                                                 @set_attribute_bits 0x20000, 0x20000
 269
 270                                 # 8 bg colors
 271                                 when '40' # bg black
 272                                         @set_attribute_bits 0xff00, 0x0000
 273                                 when '41' # bg red
 274                                         @set_attribute_bits 0xff00, 0x0100
 275                                 when '42' # bg green
 276                                         @set_attribute_bits 0xff00, 0x0200
 277                                 when '43' # bg yellow
 278                                         @set_attribute_bits 0xff00, 0x0300
 279                                 when '44' # bg blue
 280                                         @set_attribute_bits 0xff00, 0x0400
 281                                 when '45' # bg magenta
 282                                         @set_attribute_bits 0xff00, 0x0500
 283                                 when '46' # bg cyan
 284                                         @set_attribute_bits 0xff00, 0x0600
 285                                 when '47' # bg white
 286                                         @set_attribute_bits 0xff00, 0x0700
 287                                 when '49' # bg default
 288                                         @set_attribute_bits 0xff00, 0x0000
 289
 290                                 when '48'
 291                                         if args.length >= 2 and args[0] is '5'
 292                                                 args.shift()
 293                                                 @set_attribute_bits 0xff00, ((0xff & args.shift()) << 8)
 294                                         else
 295                                                 @set_attribute_bits 0x20000, 0x20000
 296
 297                                 # bright fg colors
 298                                 when '90' # fg bright black
 299                                         @set_attribute_bits 0xff, 0x08
 300                                 when '91' # fg bright red
 301                                         @set_attribute_bits 0xff, 0x09
 302                                 when '92' # fg bright green
 303                                         @set_attribute_bits 0xff, 0x0a
 304                                 when '93' # fg bright yellow
 305                                         @set_attribute_bits 0xff, 0x0b
 306                                 when '94' # fg bright blue
 307                                         @set_attribute_bits 0xff, 0x0c
 308                                 when '95' # fg bright magenta
 309                                         @set_attribute_bits 0xff, 0x0d
 310                                 when '96' # fg bright cyan
 311                                         @set_attribute_bits 0xff, 0x0e
 312                                 when '97' # fg bright white
 313                                         @set_attribute_bits 0xff, 0x0f
 314
 315                                 # bright bg colors
 316                                 when '100' # bg bright black
 317                                         @set_attribute_bits 0xff, 0x08
 318                                 when '101' # bg bright red
 319                                         @set_attribute_bits 0xff, 0x09
 320                                 when '102' # bg bright green
 321                                         @set_attribute_bits 0xff, 0x0a
 322                                 when '103' # bg bright yellow
 323                                         @set_attribute_bits 0xff, 0x0b
 324                                 when '104' # bg bright blue
 325                                         @set_attribute_bits 0xff, 0x0c
 326                                 when '105' # bg bright magenta
 327                                         @set_attribute_bits 0xff, 0x0d
 328                                 when '106' # bg bright cyan
 329                                         @set_attribute_bits 0xff, 0x0e
 330                                 when '107' # bg bright white
 331                                         @set_attribute_bits 0xff, 0x0f
 332
 333
 334                                 else
 335                                         # if we don't recognize the style, go back to default
 336                                         @set_attribute_bits 0xffffff, 0
 337                 return
 338
 339         # str is the whole escape sequence (minus the esc[ prefix)
 340         update_sequence: (str) ->
 341                 prefix = 'csi_'
 342                 if str[0] is '?'
 343                         prefix = 'csiq_'
 344                         str = str.substr 1
 345                 command = @[prefix + str.substr(str.length - 1)]
 346                 if not command?
 347                         console.log "Unrecognized sequence: ESC[#{str}"
 348                         return
 349                 args = str.substr(0, str.length - 1).split ';'
 350                 command.call this, args...
 351
 352         update_sequence_then_text: (str) ->
 353                 len = @escape_sequence_length str
 354                 if len is -1
 355                         console.log "couldn't find escape sequence here: #{str.substr 0, 25}"
 356                         @update_text "ESC[" + str
 357                 else
 358                         @update_sequence str.substr 0, len
 359                         @update_text str.substr len
 360
 361         escape_sequence_length: (str) ->
 362                 parts = str.match(/^[0-9;?]{0,25}./)
 363                 return -1 unless parts?
 364                 return parts[0].length
 365
 366 my_exports.new = (width, height) ->
 367         return new Terminal width, height