client.coffee

   1 # globals
   2 $table = null
   3 table_height = 0
   4 card_height = 0
   5 state = null
   6 server_url = null
   7 top_card_z = 0 # css z-index of front-most card
   8
   9 show_message = (txt) -> txt
  10         # FIXME implement chat box or something
  11
  12 # timeout function with args in convenient order
  13 timeout = (ms, func) -> setTimeout func, ms
  14
  15 unless Array::shuffle?
  16         Array::shuffle = ->
  17                 return if @length is 0
  18                 top = @length
  19
  20                 while --top
  21                         current = Math.floor(Math.random() * (top + 1))
  22                         tmp = @[current]
  23                         @[current] = @[top]
  24                         @[top] = tmp
  25                 return
  26
  27 new_button = (text) -> $ $ "<div class=\"button\">#{text}</div>"
  28
  29 # transform coordinates from client-side coords to server-side coords (or back)
  30 # this makes it so p2 view everything upside down (mirrored), but still sends coords rightside up
  31 transform_x = (x) -> x
  32 transform_y = (y) ->
  33         return y unless state.agent is 'p2'
  34         return table_height - card_height - y
  35
  36 next_card_z = -> return top_card_z += 1
  37
  38 bring_card_to_front = (card) ->
  39         card.view.css "z-index": next_card_z()
  40
  41 instantiate_card = (card) ->
  42         text = card.text
  43         if card.owner is state.agent
  44                 card_class = 'my_card'
  45         else
  46                 card_class = 'your_card'
  47
  48         view = $ $ "<div class=\"card #{card_class}\" style=\"left: #{transform_x(card.x)}px; top: #{transform_y(card.y)}px; z-index: #{next_card_z()}\"><span class=\"cardtext\">#{text}</span></div>"
  49         button_box = $ $ '<div/>'
  50         flip_button = new_button "flip over"
  51         mark_button = new_button "mark"
  52         flip_button.bind 'click', ->
  53                 state.flip state.agent, card.number, ! view.hasClass 'flipped'
  54         mark_button.bind 'click', ->
  55                 state.mark state.agent, card.number, ! view.hasClass 'marked'
  56         button_box.append flip_button
  57         button_box.append mark_button
  58         view.append button_box
  59         if card.marked
  60                 view.addClass 'marked'
  61         if card.flipped
  62                 view.addClass 'flipped'
  63         $table.append view
  64         view.draggable stack: '.card'
  65         view.bind 'dragstop', (event, ui) ->
  66                 top_card_z = parseInt view.css 'z-index'
  67                 p = view.position()
  68                 state.move state.agent, card.number, transform_x(p.left), transform_y(p.top)
  69         card.view = view
  70
  71 error_lag = 3
  72
  73 outgoing_messages = []
  74 # message should be [agent, method, args...]
  75 # don't forget the agent (state.agent)
  76 tell_server = (message) ->
  77         outgoing_messages.push message
  78         send_updates()
  79
  80 send_updates = ->
  81         return if outgoing_messages.length is 0
  82
  83         messages = outgoing_messages
  84         outgoing_messages = []
  85
  86         $.ajax "#{server_url}/set", {
  87                 cache: false
  88                 data: {
  89                         agent: state.agent
  90                         game: 'test' # FIXME, and it the /get call too
  91                         messages: JSON.stringify(messages)
  92                 }
  93                 type: 'POST'
  94                 dataType: 'json'
  95                 error: (xhr, status, error) ->
  96                         show_message "Network error while sending, you might want to refresh. Trying again in #{error_lag} seconds. (Status: #{status}, Error: #{error})"
  97                         for message in messages
  98                                 outgoing_messages.unshift message
  99                         timeout error_lag * 1000, send_updates
 100                         error_lag *= 2
 101                 success: (data, status, xhr) ->
 102                         show_message "update sent"
 103                         error_lag = 3
 104         }
 105
 106 error_lag = 3
 107 poll_for_updates = ->
 108         $.ajax "#{server_url}/get?agent=#{state.agent}&game=test", {
 109                 cache: false
 110                 type: 'GET'
 111                 dataType: 'json'
 112                 error: (xhr, status, error) ->
 113                         message "Network error, you might want to refresh. Trying again in #{error_lag} seconds. (Status: #{status}, Error: #{error})"
 114                         timeout error_lag * 1000, poll_for_updates
 115                         error_lag *= 2
 116                 success: (data, status, xhr) ->
 117                         state.process_messages data
 118                         timeout 100, poll_for_updates
 119                         error_lag = 3
 120         }
 121
 122 init = ->
 123         if window.location.hash? and window.location.hash.length > 0
 124                 me = window.location.hash.substr 1
 125                 winloc = "#{window.location}"
 126                 server_url = winloc.substr 0, winloc.length - window.location.hash.length
 127         else
 128                 me = 'p1'
 129                 server_url = window.location
 130
 131         state = window.game_model.new me
 132         state.on 'move', (agent, card, x, y) ->
 133                 # FIXME add/handle pile argument
 134                 if agent is me
 135                         tell_server ['move', agent, card, x, y]
 136                 else
 137                         bring_card_to_front state.cards[card]
 138                         state.cards[card].view.animate { left: "#{transform_x x}px", top: "#{transform_y y}px"}, 800
 139         state.on 'mark', (agent, card, state) ->
 140                 @cards[card].view.toggleClass 'marked', state
 141                 if agent is me
 142                         tell_server ['mark', agent, card, state]
 143         state.on 'flip', (agent, card, state) ->
 144                 @cards[card].view.toggleClass 'flipped', state
 145                 if agent is me
 146                         tell_server ['flip', agent, card, state]
 147         state.on 'set_cards', (agent, cards) ->
 148                 # FIXME add agent arg and tell server if it's not us
 149                 $('.card').remove()
 150                 for card in cards
 151                         instantiate_card card
 152                 if agent is me
 153                         tell_server ['set_cards', agent, cards]
 154
 155         # timeout so browser will stop showing that we're loading
 156         timeout 1, poll_for_updates
 157         timeout 2, ->
 158                 # ask for initial state
 159                 tell_server ['send_state', state.agent]
 160
 161 $ ->
 162         $table = $ '#table'
 163         table_height = $table.height()
 164         card_height = $('#loading-card').outerHeight()
 165
 166         init()