editor.coffee

   1 # Copyright 2015 Jason Woofenden
   2 # This file implements an WYSIWYG editor in the browser (no contenteditable)
   3 #
   4 # This program is free software: you can redistribute it and/or modify it under
   5 # the terms of the GNU Affero General Public License as published by the Free
   6 # Software Foundation, either version 3 of the License, or (at your option) any
   7 # later version.
   8 #
   9 # This program is distributed in the hope that it will be useful, but WITHOUT
  10 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  11 # FOR A PARTICULAR PURPOSE.  See the GNU Affero General Public License for more
  12 # details.
  13 #
  14 # You should have received a copy of the GNU Affero General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16
  17 # SETTINGS
  18 overlay_padding = 10
  19
  20 timeout = (ms, cb) -> return setTimeout cb, ms
  21 next_frame = (cb) ->
  22         if (window.requestAnimationFrame?)
  23                 window.requestAnimationFrame cb
  24         else
  25                 timeout 16, cb
  26
  27 this_url_sans_path = ->
  28         ret = "#{window.location.href}"
  29         clip = ret.lastIndexOf '#'
  30         if clip > -1
  31                 ret = ret.substr 0, clip
  32         clip = ret.lastIndexOf '?'
  33         if clip > -1
  34                 ret = ret.substr 0, clip
  35         clip = ret.lastIndexOf '/'
  36         if clip > -1
  37                 ret = ret.substr 0, clip + 1
  38         return ret
  39
  40 # table too look up the properties of various values for css's white-space
  41 ws_props =
  42         normal:
  43                 space: false            # spaces are not preserved/rendered
  44                 newline: false          # newlines are not preserved/rendered
  45                 wrap: true              # text is word-wrapped
  46                 to_preserve: 'pre-wrap' # to preservespaces, change white-space to this
  47         nowrap:
  48                 space: false
  49                 newline: false
  50                 wrap: false
  51                 to_preserve: 'pre'
  52         'pre-line':
  53                 space: false
  54                 newline: true
  55                 wrap: true
  56                 to_preserve: 'pre-wrap'
  57         pre:
  58                 space: true
  59                 newline: true
  60                 wrap: false
  61         'pre-wrap':
  62                 space: true
  63                 newline: true
  64                 wrap: true
  65
  66 # xml 1.0 spec, chromium and firefox accept these, plus lots of unicode chars
  67 valid_attr_regex = new RegExp '^[a-zA-Z_:][-a-zA-Z0-9_:.]*$'
  68 # html5 spec is much more lax, but chromium won't let me make at attribute with the name "4"
  69 js_attr_regex = new RegExp '^[oO][nN].'
  70
  71 debug_dot_at = (doc, x, y) ->
  72         return # disabled
  73         el = doc.createElement 'div'
  74         el.setAttribute 'style', "position: absolute; left: #{x}px; top: #{y}px; width: 1px; height: 3px; background-color: red"
  75         doc.body.appendChild el
  76         #console.log(new Error().stack)
  77
  78 # text nodes don't have getBoundingClientRect(), so use selection api to find
  79 # it.
  80 get_el_bounds = window.bounds = (el) ->
  81         if el.getBoundingClientRect?
  82                 rect = el.getBoundingClientRect()
  83         else
  84                 # text nodes don't have getBoundingClientRect(), so use range api
  85                 range = el.ownerDocument.createRange()
  86                 range.selectNodeContents el
  87                 rect = range.getBoundingClientRect()
  88         doc = el.ownerDocument.documentElement
  89         win = el.ownerDocument.defaultView
  90         y_fix = win.pageYOffset - doc.clientTop
  91         x_fix = win.pageXOffset - doc.clientLeft
  92         return {
  93                 x: rect.left + x_fix
  94                 y: rect.top + y_fix
  95                 w: rect.width ? (rect.right - rect.left)
  96                 h: rect.height ? (rect.top - rect.bottom)
  97         }
  98
  99 is_display_block = (el) ->
 100         if el.currentStyle?
 101                 return el.currentStyle.display is 'block'
 102         else
 103                 return window.getComputedStyle(el, null).getPropertyValue('display') is 'block'
 104
 105 # Pass return value from dom event handlers to this.
 106 # If they return false, this will addinionally stop propagation and default.
 107 event_return = (e, bool) ->
 108         if bool is false
 109                 if e.stopPropagation?
 110                         e.stopPropagation()
 111                 if e.preventDefault?
 112                         e.preventDefault()
 113         return bool
 114 # Warning: currently assumes you're asking about a single character
 115 # Note: chromium returns multiple bounding rects for a space at a line-break
 116 # Note: chromium's getBoundingClientRect() is broken (when zero-area client rects)
 117 # Note: sometimes returns null (eg for whitespace that is not visible)
 118 text_range_bounds = (el, start, end) ->
 119         range = document.createRange()
 120         range.setStart el, start
 121         range.setEnd el, end
 122         rects = range.getClientRects()
 123         if rects.length > 0
 124                 if rects.length > 1
 125                         if rects[1].width > rects[0].width
 126                                 rect = rects[1]
 127                         else
 128                                 rect = rects[0]
 129                 else
 130                         rect = rects[0]
 131         else
 132                 return null
 133         doc = el.ownerDocument.documentElement
 134         win = el.ownerDocument.defaultView
 135         y_fix = win.pageYOffset - doc.clientTop
 136         x_fix = win.pageXOffset - doc.clientLeft
 137         return {
 138                 x: rect.left + x_fix
 139                 y: rect.top + y_fix
 140                 w: rect.width ? (rect.right - rect.left)
 141                 h: rect.height ? (rect.top - rect.bottom)
 142                 rects: rects
 143                 bounding: range.getBoundingClientRect()
 144         }
 145
 146 class CursorPosition
 147         constructor: (args) ->
 148                 @n = args.n ? null
 149                 @i = args.i ? null
 150                 if args.x?
 151                         @x = args.x
 152                         @y = args.y
 153                         @h = args.h
 154                 else
 155                         @set_xyh()
 156                 return
 157         set_xyh: ->
 158                 range = document.createRange()
 159                 if @n.text.length is 0
 160                         ret = text_range_bounds @n.el, 0, 0
 161                 else if @i is @n.text.length
 162                         ret = text_range_bounds @n.el, @i - 1, @i
 163                         if ret?
 164                                 ret.x += ret.w
 165                 else
 166                         ret = text_range_bounds @n.el, @i, @i + 1
 167                 if ret?
 168                         @x = ret.x
 169                         @y = ret.y
 170                         @h = ret.h
 171                 else
 172                         @x = null
 173                         @y = null
 174                         @h = null
 175                 return ret
 176
 177 new_cursor_position = (args) ->
 178         ret = new CursorPosition args
 179         if ret.x?
 180                 return ret
 181         return null
 182
 183 # encode text so it can be safely placed inside an html attribute
 184 enc_attr_regex = new RegExp '(&)|(")|(\u00A0)', 'g'
 185 enc_attr = (txt) ->
 186         return txt.replace enc_attr_regex, (match, amp, quote) ->
 187                 return '&amp;' if (amp)
 188                 return '&quot;' if (quote)
 189                 return '&nbsp;'
 190 enc_text_regex = new RegExp '(&)|(<)|(\u00A0)', 'g'
 191 enc_text = (txt) ->
 192         return txt.replace enc_text_regex, (match, amp, lt) ->
 193                 return '&amp;' if (amp)
 194                 return '&lt;' if (lt)
 195                 return '&nbsp;'
 196
 197 void_elements = {
 198         area: true
 199         base: true
 200         br: true
 201         col: true
 202         embed: true
 203         hr: true
 204         img: true
 205         input: true
 206         keygen: true
 207         link: true
 208         meta: true
 209         param: true
 210         source: true
 211         track: true
 212         wbr: true
 213 }
 214 # TODO make these always pretty-print (on the inside) like blocks
 215 no_text_elements = { # these elements never contain text
 216         select: true
 217         table: true
 218         tr: true
 219         thead: true
 220         tbody: true
 221         ul: true
 222         ol: true
 223 }
 224
 225 domify = (doc, hash) ->
 226         for tag, attrs of hash
 227                 if tag is 'text'
 228                         return document.createTextNode attrs
 229                 el = document.createElement tag
 230                 for k, v of attrs
 231                         if k is 'children'
 232                                 for child in v
 233                                         el.appendChild child
 234                         else
 235                                 el.setAttribute k, v
 236         return el
 237
 238
 239
 240 ignore_key_codes =
 241         '18': true # alt
 242         '20': true # capslock
 243         '17': true # ctrl
 244         '144': true # numlock
 245         '16': true # shift
 246         '91': true # windows "start" key
 247 # key codes: (valid on keydown, not keypress)
 248 KEY_LEFT = 37
 249 KEY_UP = 38
 250 KEY_RIGHT = 39
 251 KEY_DOWN = 40
 252 KEY_BACKSPACE = 8 # <--
 253 KEY_DELETE = 46 # -->
 254 KEY_END = 35
 255 KEY_ENTER = 13
 256 KEY_ESCAPE = 27
 257 KEY_HOME = 36
 258 KEY_INSERT = 45
 259 KEY_PAGE_UP = 33
 260 KEY_PAGE_DOWN = 34
 261 KEY_TAB = 9
 262 control_key_codes = # we react to these, but they aren't typing
 263         '37': KEY_LEFT
 264         '38': KEY_UP
 265         '39': KEY_RIGHT
 266         '40': KEY_DOWN
 267         '35': KEY_END
 268         '8':  KEY_BACKSPACE
 269         '46': KEY_DELETE
 270         '13': KEY_ENTER
 271         '27': KEY_ESCAPE
 272         '36': KEY_HOME
 273         '45': KEY_INSERT
 274         '33': KEY_PAGE_UP
 275         '34': KEY_PAGE_DOWN
 276         '9':  KEY_TAB
 277
 278 instantiate_tree = (tree, parent) ->
 279         remove = []
 280         for c, i in tree
 281                 switch c.type
 282                         when 'text'
 283                                 c.el = parent.ownerDocument.createTextNode c.text
 284                                 parent.appendChild c.el
 285                         when 'tag'
 286                                 if c.name in ['script', 'object', 'iframe', 'link']
 287                                         # TODO put placeholders instead
 288                                         remove.unshift i
 289                                         continue
 290                                 # TODO create in correct namespace
 291                                 c.el = parent.ownerDocument.createElement c.name
 292                                 for k, v of c.attrs
 293                                         # FIXME if attr_whitelist[k]?
 294                                         if valid_attr_regex.test k
 295                                                 unless js_attr_regex.test k
 296                                                         c.el.setAttribute k, v
 297                                 parent.appendChild c.el
 298                                 if c.children.length
 299                                         instantiate_tree c.children, c.el
 300         for i in remove
 301                 tree.splice i, 1
 302
 303 traverse_tree = (tree, cb) ->
 304         done = false
 305         for c in tree
 306                 done = cb c
 307                 return done if done
 308                 if c.children.length
 309                         done = traverse_tree c.children, cb
 310                         return done if done
 311         return done
 312
 313 first_cursor_position = (tree) ->
 314         found = null
 315         traverse_tree tree, (node, state) ->
 316                 if node.type is 'text'
 317                         cursor = new_cursor_position n: node, i: 0
 318                         if cursor?
 319                                 found = cursor
 320                                 return true
 321                 return false
 322         return found # maybe null
 323
 324 # this will fail when text has non-locatable cursor positions
 325 find_next_cursor_position = (tree, cursor) ->
 326         if cursor.n.type is 'text' and cursor.n.text.length > cursor.i
 327                 new_cursor = new_cursor_position n: cursor.n, i: cursor.i + 1
 328                 if new_cursor?
 329                         return new_cursor
 330         state_before = true
 331         found = null
 332         traverse_tree tree, (node, state) ->
 333                 if node.type is 'text' and state_before is false
 334                         new_cursor = new_cursor_position n: node, i: 0
 335                         if new_cursor?
 336                                 found = new_cursor
 337                                 return true
 338                 if node is cursor.n
 339                         state_before = false
 340                 return false
 341         if found?
 342                 return found
 343         return null
 344
 345 last_cursor_position = (tree) ->
 346         found = null
 347         traverse_tree tree, (node) ->
 348                 if node.type is 'text'
 349                         cursor = new_cursor_position n: node, i: node.text.length
 350                         if cursor?
 351                                 found = cursor
 352                 return false
 353         return found # maybe null
 354
 355 # this will fail when text has non-locatable cursor positions
 356 find_prev_cursor_position = (tree, cursor) ->
 357         if cursor.n.type is 'text' and cursor.i > 0
 358                 new_cursor = new_cursor_position n: cursor.n, i: cursor.i - 1
 359                 if new_cursor?
 360                         return new_cursor
 361         found_prev = null
 362         found = null
 363         traverse_tree tree, (node) ->
 364                 if node is cursor.n
 365                         found = found_prev # maybe null
 366                         return true
 367                 if node.type is 'text'
 368                         new_cursor = new_cursor_position n: node, i: node.text.length
 369                         if new_cursor?
 370                                 found_prev = new_cursor
 371                 return false
 372         return found # maybe null
 373
 374 find_up_cursor_position = (tree, cursor, ideal_x) ->
 375         new_cursor = cursor
 376         # go prev until we're higher on y axis
 377         while new_cursor.y >= cursor.y
 378                 new_cursor = find_prev_cursor_position tree, new_cursor
 379                 return null unless new_cursor?
 380         # done early if we're already left of old cursor position
 381         if new_cursor.x <= ideal_x
 382                 return new_cursor
 383         target_y = new_cursor.y
 384         # search leftward, until we find the closest position
 385         # new_cursor is the prev-most position we've checked
 386         # prev_cursor is the older value, so it's not as prev as new_cursor
 387         while new_cursor.x > ideal_x and new_cursor.y is target_y
 388                 prev_cursor = new_cursor
 389                 new_cursor = find_prev_cursor_position tree, new_cursor
 390                 break unless new_cursor?
 391         # move cursor to prev_cursor or new_cursor
 392         if new_cursor?
 393                 if new_cursor.y is target_y
 394                         # both valid, and on the same line, use closest
 395                         if (ideal_x - new_cursor.x) < (prev_cursor.x - ideal_x)
 396                                 return new_cursor
 397                         else
 398                                 return prev_cursor
 399                 else
 400                         # new_cursor on wrong line, use prev_cursor
 401                         return prev_cursor
 402         else
 403                 # can't go any further prev, use prev_cursor
 404                 return prev_cursor
 405
 406 find_down_cursor_position = (tree, cursor, ideal_x) ->
 407         new_cursor = cursor
 408         # go next until we move on the y axis
 409         while new_cursor.y <= cursor.y
 410                 new_cursor = find_next_cursor_position tree, new_cursor
 411                 return null unless new_cursor?
 412         # done early if we're already right of old cursor position
 413         if new_cursor.x >= ideal_x
 414                 # this would be strange, but could happen due to runaround
 415                 return new_cursor
 416         target_y = new_cursor.y
 417         # search rightward, until we find the closest position
 418         # new_cursor is the next-most position we've checked
 419         # prev_cursor is the older value, so it's not as next as new_cursor
 420         while new_cursor.x < ideal_x and new_cursor.y is target_y
 421                 prev_cursor = new_cursor
 422                 new_cursor = find_next_cursor_position tree, new_cursor
 423                 break unless new_cursor?
 424         # move cursor to prev_cursor or new_cursor
 425         if new_cursor?
 426                 if new_cursor.y is target_y
 427                         # both valid, and on the same line, use closest
 428                         if (new_cursor.x - ideal_x) < (ideal_x - prev_cursor.x)
 429                                 return new_cursor
 430                         else
 431                                 return prev_cursor
 432                 else
 433                         # new_cursor on wrong line, use prev_cursor
 434                         return prev_cursor
 435         else
 436                 # can't go any further prev, use prev_cursor
 437                 return prev_cursor
 438
 439 xy_to_cursor = (tree, xy) ->
 440         for n in tree
 441                 if n.type is 'tag' or n.type is 'text'
 442                         bounds = get_el_bounds n.el
 443                         continue if xy.x < bounds.x
 444                         continue if xy.x > bounds.x + bounds.w
 445                         continue if xy.y < bounds.y
 446                         continue if xy.y > bounds.y + bounds.h
 447                         if n.children.length
 448                                 ret = xy_to_cursor n.children, xy
 449                                 return ret if ret?
 450                         if n.type is 'text'
 451                                 # click is within bounding box that contains all text.
 452                                 if n.text.length is 0
 453                                         ret = new_cursor_position n: n, i: 0
 454                                         return ret if ret?
 455                                         continue
 456                                 before = new_cursor_position n: n, i: 0
 457                                 continue unless before?
 458                                 after = new_cursor_position n: n, i: n.text.length
 459                                 continue unless after?
 460                                 if xy.y < before.y + before.h and xy.x < before.x
 461                                         # console.log 'before first char on first line'
 462                                         continue
 463                                 if xy.y > after.y and xy.x > after.x
 464                                         # console.log 'after last char on last line'
 465                                         continue
 466                                 if xy.y < before.y
 467                                         console.log "Warning: click in text bounding box but above first line"
 468                                         continue # above first line (runaround?)
 469                                 if xy.y > after.y + after.h
 470                                         console.log "Warning: click in text bounding box but below last line", xy.y, after.y, after.h
 471                                         continue # below last line (shouldn't happen?)
 472                                 while after.i - before.i > 1
 473                                         guess_i = Math.round((before.i + after.i) / 2)
 474                                         cur = new_cursor_position n: n, i: guess_i
 475                                         unless cur?
 476                                                 console.log "error: failed to find cursor pixel location for", n, guess_i
 477                                                 before = null
 478                                                 break
 479                                         if xy.y < cur.y or (xy.y <= cur.y + cur.h and xy.x < cur.x)
 480                                                 after = cur
 481                                         else
 482                                                 before = cur
 483                                 continue unless before? # signals failure to find a cursor position
 484                                 # which one is closest?
 485                                 if Math.abs(before.x - xy.x) < Math.abs(after.x - xy.x)
 486                                         return before
 487                                 else
 488                                         return after
 489         return null
 490
 491 # browsers collapse these (html5 spec calls these "space characters")
 492 is_space_code = (char_code) ->
 493         switch char_code
 494                 when 9, 10, 12, 13, 32
 495                         return true
 496         return false
 497 is_space = (chr) ->
 498         return is_space_code chr.charCodeAt 0
 499
 500 tree_remove_empty_text_nodes = (tree) ->
 501         empties = []
 502         traverse_tree tree, (n) ->
 503                 if n.type is 'text'
 504                         if n.text.length is 0
 505                                 empties.unshift n
 506                 return false
 507         for n in empties
 508                 # don't completely empty the tree
 509                 if tree.length is 1
 510                         if tree[0].type is 'text'
 511                                 console.log "oop, leaving a blank node because it's the only thing"
 512                                 return
 513                 n.el.parentNode.removeChild n.el
 514                 for c, i in n.parent.children
 515                         if c is n
 516                                 n.parent.children.splice i, 1
 517                                 break
 518
 519 # pass a array of nodes (from parser library, ie it should have .el and .text)
 520 tree_dedup_space = (tree) ->
 521         prev = cur = next = null
 522         prev_i = cur_i = next_i = 0
 523         prev_pos = pos = next_pos = null
 524         prev_px = cur_px = next_px = null
 525         first = true
 526         removed_char = null
 527
 528         tree_remove_empty_text_nodes(tree)
 529
 530         iterate = (tree, cb) ->
 531                 for n in tree
 532                         if n.type is 'text'
 533                                 i = 0
 534                                 while i < n.text.length # don't foreach, cb might remove chars
 535                                         advance = cb n, i
 536                                         if advance
 537                                                 i += 1
 538                         if n.type is 'tag'
 539                                 block = is_display_block n.el
 540                                 if block
 541                                         cb null
 542                                 if n.children.length > 0
 543                                         iterate n.children, cb
 544                                 if block
 545                                         cb null
 546         # remove cur char
 547         remove = (undo) ->
 548                 if undo
 549                         cur.el.textContent = cur.text = (cur.text.substr 0, cur_i) + removed_char + (cur.text.substr cur_i)
 550                         if next is cur # in same text node
 551                                 next_i += 1
 552                         return -1
 553                 else
 554                         removed_char = cur.text.charAt(cur_i)
 555                         cur.el.textContent = cur.text = (cur.text.substr 0, cur_i) + (cur.text.substr cur_i + 1)
 556                         if next is cur # in same text node
 557                                 if next_i is 0
 558                                         throw "how is this possible?"
 559                                 next_i -= 1
 560                         return 1
 561         whitespace_to_space = (undo) ->
 562                 if undo
 563                         cur.text = (cur.text.substr 0, cur_i) + removed_char + (cur.text.substr cur_i + 1)
 564                         cur.el.textContent = cur.text
 565                 else
 566                         removed_char = cur.text.charAt(cur_i)
 567                         cur.text = (cur.text.substr 0, cur_i) + ' ' + (cur.text.substr cur_i + 1)
 568                         cur.el.textContent = cur.text
 569                 return 0
 570         # return true if cur was removed from the dom (ie re-use same prev)
 571         operate = ->
 572                 # cur definitately set
 573                 # prev and/or next might be null, indicating the start/end of a display:block
 574                 return false unless is_space_code cur.text.charCodeAt cur_i
 575                 fixers = [remove, whitespace_to_space]
 576                 bounds = text_range_bounds cur.el, cur_i, cur_i + 1
 577                 # consistent cases:
 578                 # 1. zero rects returned by getClientRects() means collapsed space
 579                 if bounds is null
 580                         return remove()
 581                 # 2. width greater than zero means visible space
 582                 if bounds.w > 0
 583                         fixers.shift() # don't try removing
 584                 # now the weird edge cases...
 585                 #
 586                 # firefox and chromium both report zero width for characters at the end
 587                 # of a line where the text wraps (automatically, due to word-wrap) to
 588                 # the next line. These do not appear to be distinguishable from
 589                 # collapsed spaces via the range/bounds api, so...
 590                 #
 591                 # remove it from the dom, and if prev or next moves, put it back.
 592                 if prev? and not prev_px?
 593                         prev_px = new_cursor_position n: prev, i: prev_i
 594                 if next? and not next_px?
 595                         next_px = new_cursor_position n: next, i: next_i
 596                 #if prev is null and next is null
 597                 #       parent_px = cur.parent.el.getBoundingClientRect()
 598                 undo_arg = true # just for readabality
 599                 removed = 0
 600                 for fixer in fixers
 601                         break if removed > 0
 602                         removed += fixer()
 603                         need_undo = false
 604                         if prev?
 605                                 if prev_px?
 606                                         new_prev_px = new_cursor_position n: prev, i: prev_i
 607                                         if new_prev_px?
 608                                                 if new_prev_px.x isnt prev_px.x or new_prev_px.y isnt prev_px.y
 609                                                         need_undo = true
 610                                         else
 611                                                 need_undo = true
 612                                 else
 613                                         console.log "this shouldn't happen, we remove spaces that don't locate"
 614                         if next? and not need_undo
 615                                 if next_px?
 616                                         new_next_px = new_cursor_position n: next, i: next_i
 617                                         if new_next_px?
 618                                                 if new_next_px.x isnt next_px.x or new_next_px.y isnt next_px.y
 619                                                         need_undo = true
 620                                         else
 621                                                 need_undo = true
 622                                 #else
 623                                 #       console.log "removing space becase space after it is collapsed"
 624                         if need_undo
 625                                 removed += fixer undo_arg
 626                 if removed > 0
 627                         return true
 628                 else
 629                         return false
 630         # pass null at start/end of display:block
 631         queue = (n, i) ->
 632                 next = n
 633                 next_i = i
 634                 next_px = null
 635                 advance = true
 636                 if cur?
 637                         removed = operate()
 638                         # don't advance (to the next character next time) if we removed a
 639                         # character from the same text node as ``next``, because doing so
 640                         # renumbers the indexes in that string
 641                         if removed and cur is next
 642                                 advance = false
 643                 else
 644                         removed = false
 645                 unless removed
 646                         prev = cur
 647                         prev_i = cur_i
 648                         prev_px = cur_px
 649                 cur = next
 650                 cur_i = next_i
 651                 cur_px = next_px
 652                 return advance
 653         queue null
 654         iterate tree, queue
 655         queue null
 656
 657         tree_remove_empty_text_nodes(tree)
 658
 659 class PeachHTML5Editor
 660         # Options: (all optional)
 661         #   editor_id: "id" attribute for outer-most element created by/for editor
 662         #   css_file: filename of a css file to style editable content
 663         #   on_init: callback for when the editable content is in place
 664         constructor: (in_el, options) ->
 665                 @options = options ? {}
 666                 @in_el = in_el
 667                 @tree = null
 668                 @matting = []
 669                 @init_1_called = false # when iframes have loaded
 670                 @outer_iframe # iframe to hold editor
 671                 @outer_idoc # "document" object for @outer_iframe
 672                 @wrap2 = null # scrollbar is on this
 673                 @wrap2_offset = null
 674                 @wrap2_height = null # including padding
 675                 @iframe = null # iframe to hold editable content
 676                 @idoc = null # "document" object for @iframe
 677                 @cursor = null
 678                 @cursor_el = null
 679                 @cursor_visible = false
 680                 @cursor_ideal_x = null
 681                 @poll_for_blur_timeout = null
 682                 opt_fragment = @options.fragment ? true
 683                 @parser_opts = {}
 684                 if opt_fragment
 685                         @parser_opts.fragment = 'body'
 686
 687                 @outer_iframe = domify document, iframe: {}
 688                 outer_iframe_style = 'border: none !important; margin: 0 !important; padding: 0 !important; height: 100% !important; width: 100% !important;'
 689                 if @options.editor_id?
 690                         @outer_iframe.setAttribute 'id', @options.editor_id
 691                 @outer_iframe.onload = =>
 692                         @outer_idoc = @outer_iframe.contentDocument
 693                         icss = domify @outer_idoc, style: children: [
 694                                 domify @outer_idoc, text: css
 695                         ]
 696                         @outer_idoc.head.appendChild icss
 697                         @iframe = domify @outer_idoc, iframe: sandbox: 'allow-same-origin allow-scripts'
 698                         @iframe.onload = =>
 699                                 @init_1()
 700                         timeout 200, => # firefox never fires this onload
 701                                 @init_1() unless @init_1_called
 702                         @outer_idoc.body.appendChild(
 703                                 domify @outer_idoc, div: id: 'wrap1', children: [
 704                                         domify @outer_idoc, div: style: "position: absolute; top: 0; left: 1px; font-size: 10px", children: [ domify @outer_idoc, text: "Peach HTML5 Editor" ]
 705                                         @wrap2 = domify @outer_idoc, div: id: 'wrap2', children: [
 706                                                 domify @outer_idoc, div: id: 'wrap3', children: [
 707                                                         @iframe
 708                                                         @overlay = domify @outer_idoc, div: id: 'overlay'
 709                                                 ]
 710                                         ]
 711                                 ]
 712                         )
 713                 outer_wrap = domify document, div: class: 'peach_html5_editor'
 714                 @in_el.parentNode.appendChild outer_wrap
 715                 outer_bounds = get_el_bounds outer_wrap
 716                 if outer_bounds.w < 300
 717                         outer_bounds.w = 300
 718                 if outer_bounds.h < 300
 719                         outer_bounds.h = 300
 720                 outer_iframe_style += "width: #{outer_bounds.w}px; height: #{outer_bounds.h}px;"
 721                 @outer_iframe.setAttribute 'style', outer_iframe_style
 722                 css = @generate_outer_css w: outer_bounds.w, h: outer_bounds.h
 723                 outer_wrap.appendChild @outer_iframe
 724         init_1: -> # @iframe has loaded (but not it's css)
 725                 @idoc = @iframe.contentDocument
 726                 @init_1_called = true
 727                 # chromium doesn't resolve relative urls as though they were at the same domain
 728                 # so add a <base> tag
 729                 @idoc.head.appendChild domify @idoc, base: href: this_url_sans_path()
 730                 # don't let @iframe have scrollbars
 731                 @idoc.head.appendChild domify @idoc, style: children: [domify @idoc, text: "body { overflow: hidden; }"]
 732                 # load css file
 733                 if @options.css_file
 734                         istyle = domify @idoc, link: rel: 'stylesheet', href: @options.css_file
 735                         istyle.onload = =>
 736                                 @init_2()
 737                         @idoc.head.appendChild istyle
 738                 else
 739                         @init_2()
 740         init_2: -> # @iframe and it's css file(s) are ready
 741                 @overlay.onclick = (e) =>
 742                         @have_focus()
 743                         return event_return e, @onclick e
 744                 @overlay.ondoubleclick = (e) =>
 745                         @have_focus()
 746                         return event_return e, @ondoubleclick e
 747                 @outer_idoc.body.onkeyup = (e) =>
 748                         @have_focus()
 749                         return event_return e, @onkeyup e
 750                 @outer_idoc.body.onkeydown = (e) =>
 751                         @have_focus()
 752                         return event_return e, @onkeydown e
 753                 @outer_idoc.body.onkeypress = (e) =>
 754                         @have_focus()
 755                         return event_return e, @onkeypress e
 756                 @load_html @in_el.value
 757                 if @options.on_init?
 758                         @options.on_init()
 759         generate_outer_css: (args) ->
 760                 w = args.w ? 300
 761                 h = args.h ? 300
 762                 inner_padding = args.inner_padding ? overlay_padding
 763                 frame_width = args.frame_width ? inner_padding
 764                 occupy = (left, top = left, right = left, bottom = top) ->
 765                         w -= left + right
 766                         h -= top + bottom
 767                         return Math.max(left, top, right, bottom)
 768                 ret = ''
 769                 ret += 'body {'
 770                 ret +=     'margin: 0;'
 771                 ret +=     'padding: 0;'
 772                 ret +=     'color: black;'
 773                 ret +=     'background: white;'
 774                 ret += '}'
 775                 ret += '#wrap1 {'
 776                 ret +=     "border: #{occupy 1}px solid black;"
 777                 ret +=     "padding: #{occupy frame_width}px;"
 778                 ret += '}'
 779                 ret += '#wrap2 {'
 780                 ret +=     "border: #{occupy 1}px solid black;"
 781                 @wrap2_height = h # including padding because padding scrolls
 782                 ret +=     "padding: #{occupy inner_padding}px;"
 783                 ret +=     "padding-right: #{inner_padding + occupy 0, 0, 15, 0}px;" # for scroll bar
 784                 ret +=     "width: #{w}px;"
 785                 ret +=     "height: #{h}px;"
 786                 ret +=     'overflow-x: hidden;'
 787                 ret +=     'overflow-y: scroll;'
 788                 ret += '}'
 789                 ret += '#wrap3 {'
 790                 ret +=     'position: relative;'
 791                 ret +=     "width: #{w}px;"
 792                 ret +=     "min-height: #{h}px;"
 793                 ret += '}'
 794                 ret += 'iframe {'
 795                 ret +=     'box-sizing: border-box;'
 796                 ret +=     'margin: 0;'
 797                 ret +=     'border: none;'
 798                 ret +=     'padding: 0;'
 799                 ret +=     "width: #{w}px;"
 800                 #ret +=     "height: #{h}px;" # height auto-set when content set/changed
 801                 ret +=     '-ms-user-select: none;'
 802                 ret +=     '-webkit-user-select: none;'
 803                 ret +=     '-moz-user-select: none;'
 804                 ret +=     'user-select: none;'
 805                 ret += '}'
 806                 ret += '#overlay {'
 807                 ret +=     'position: absolute;'
 808                 ret +=     "left: -#{inner_padding}px;"
 809                 ret +=     "top: -#{inner_padding}px;"
 810                 ret +=     "right: -#{inner_padding}px;"
 811                 ret +=     "bottom: -#{inner_padding}px;"
 812                 ret +=     'overflow: hidden;'
 813                 ret += '}'
 814                 ret += '.lightbox {'
 815                 ret +=     'position: absolute;'
 816                 ret +=     'background: rgba(100,100,100,0.2);'
 817                 ret += '}'
 818                 ret += '#cursor {'
 819                 ret +=     'position: absolute;'
 820                 ret +=     'width: 2px;'
 821                 ret +=     'background: linear-gradient(0deg, rgba(0,0,0,1), rgba(255,255,255,1), rgba(0,0,0,1), rgba(255,255,255,1), rgba(0,0,0,1), rgba(255,255,255,1), rgba(0,0,0,1), rgba(255,255,255,1), rgba(0,0,0,1));'
 822                 ret +=     'background-size: 200% 200%;'
 823                 ret +=     '-webkit-animation: blink 1s linear normal infinite;'
 824                 ret +=     'animation: blink 1s linear normal infinite;'
 825                 ret += '}'
 826                 ret += '@-webkit-keyframes blink {'
 827                 ret +=     '0%{background-position:0% 0%}'
 828                 ret +=     '100%{background-position:0% -100%}'
 829                 ret += '}'
 830                 ret += '@keyframes blink { '
 831                 ret +=     '0%{background-position:0% 0%}'
 832                 ret +=     '100%{background-position:0% -100%}'
 833                 ret += '}'
 834                 ret += '.ann_box {'
 835                 ret +=     'z-index: 5;'
 836                 ret +=     'position: absolute;'
 837                 ret +=     'border: 1px solid rgba(0,0,0,0.1);'
 838                 ret +=     'outline: 1px solid rgba(255,255,255,0.1);' # in case there's a black background
 839                 ret += '}'
 840                 ret += '.ann_tag {'
 841                 ret +=     'z-index: 10;'
 842                 ret +=     'position: absolute;'
 843                 ret +=     'font-size: 8px;'
 844                 ret +=     'white-space: pre;'
 845                 ret +=     'background: rgba(255,255,255,0.4);'
 846                 ret +=     '-ms-user-select: none;'
 847                 ret +=     '-webkit-user-select: none;'
 848                 ret +=     '-moz-user-select: none;'
 849                 ret +=     'user-select: none;'
 850                 ret += '}'
 851                 return ret
 852         overlay_event_to_inner_xy: (e) ->
 853                 unless @wrap2_offset?
 854                         @wrap2_offset = get_el_bounds @wrap2
 855                 x = e.pageX - overlay_padding
 856                 y = e.pageY - overlay_padding + @wrap2.scrollTop
 857                 return x: x - @wrap2_offset.x, y: y - @wrap2_offset.y
 858         onclick: (e) ->
 859                 xy = @overlay_event_to_inner_xy e
 860                 new_cursor = xy_to_cursor @tree, xy
 861                 if new_cursor?
 862                         @move_cursor new_cursor
 863                 else
 864                         @kill_cursor()
 865                 return false
 866         ondoubleclick: (e) ->
 867                 return false
 868         onkeyup: (e) ->
 869                 return if e.ctrlKey
 870                 return false if ignore_key_codes[e.keyCode]?
 871                 #return false if control_key_codes[e.keyCode]?
 872         onkeydown: (e) ->
 873                 return if e.ctrlKey
 874                 return false if ignore_key_codes[e.keyCode]?
 875                 #return false if control_key_codes[e.keyCode]?
 876                 switch e.keyCode
 877                         when KEY_LEFT
 878                                 if @cursor?
 879                                         new_cursor = find_prev_cursor_position @tree, @cursor
 880                                 else
 881                                         new_cursor = first_cursor_position @tree
 882                                 if new_cursor?
 883                                         @move_cursor new_cursor
 884                                 return false
 885                         when KEY_RIGHT
 886                                 if @cursor?
 887                                         new_cursor = find_next_cursor_position @tree, @cursor
 888                                 else
 889                                         new_cursor = last_cursor_position @tree
 890                                 if new_cursor?
 891                                         @move_cursor new_cursor
 892                                 return false
 893                         when KEY_UP
 894                                 if @cursor?
 895                                         new_cursor = find_up_cursor_position @tree, @cursor, @cursor_ideal_x
 896                                         if new_cursor?
 897                                                 saved_ideal_x = @cursor_ideal_x
 898                                                 @move_cursor new_cursor
 899                                                 @cursor_ideal_x = saved_ideal_x
 900                                 else
 901                                         # move cursor to first position in document
 902                                         new_cursor = first_cursor_position @tree
 903                                         if new_cursor?
 904                                                 @move_cursor new_cursor
 905                                 return false
 906                         when KEY_DOWN
 907                                 if @cursor?
 908                                         new_cursor = find_down_cursor_position @tree, @cursor, @cursor_ideal_x
 909                                         if new_cursor?
 910                                                 saved_ideal_x = @cursor_ideal_x
 911                                                 @move_cursor new_cursor
 912                                                 @cursor_ideal_x = saved_ideal_x
 913                                 else
 914                                         # move cursor to first position in document
 915                                         new_cursor = last_cursor_position @tree
 916                                         if new_cursor?
 917                                                 @move_cursor new_cursor
 918                                 return false
 919                         when KEY_END
 920                                 new_cursor = last_cursor_position @tree
 921                                 if new_cursor?
 922                                         @move_cursor new_cursor
 923                                 return false
 924                         when KEY_BACKSPACE
 925                                 return false unless @cursor?
 926                                 return false unless @cursor.i > 0
 927                                 @remove_character @cursor.n, @cursor.i - 1
 928                                 @adjust_whitespace_style @cursor.n
 929                                 @changed()
 930                                 new_cursor = new_cursor_position n: @cursor.n, i: @cursor.i - 1
 931                                 if new_cursor?
 932                                         @move_cursor new_cursor
 933                                 else
 934                                         @kill_cursor()
 935                                 return false
 936                         when KEY_DELETE
 937                                 return false unless @cursor?
 938                                 return false unless @cursor.i < @cursor.n.text.length
 939                                 @remove_character @cursor.n, @cursor.i
 940                                 @adjust_whitespace_style @cursor.n
 941                                 @changed()
 942                                 new_cursor = new_cursor_position n: @cursor.n, i: @cursor.i
 943                                 if new_cursor?
 944                                         @move_cursor new_cursor
 945                                 else
 946                                         @kill_cursor()
 947                                 return false
 948                         when KEY_ENTER
 949                                 return false
 950                         when KEY_ESCAPE
 951                                 return false
 952                         when KEY_HOME
 953                                 new_cursor = first_cursor_position @tree
 954                                 if new_cursor?
 955                                         @move_cursor new_cursor
 956                                 return false
 957                         when KEY_INSERT
 958                                 return false
 959                         when KEY_PAGE_UP
 960                                 return false
 961                         when KEY_PAGE_DOWN
 962                                 return false
 963                         when KEY_TAB
 964                                 return false
 965         onkeypress: (e) ->
 966                 return if e.ctrlKey
 967                 return false if ignore_key_codes[e.keyCode]?
 968                 char = e.charCode ? e.keyCode
 969                 if char and @cursor?
 970                         char = String.fromCharCode char
 971                         @insert_character @cursor.n, @cursor.i, char
 972                         @adjust_whitespace_style @cursor.n
 973                         @changed()
 974                         new_cursor = new_cursor_position n: @cursor.n, i: @cursor.i + 1
 975                         if new_cursor
 976                                 @move_cursor new_cursor
 977                         else
 978                                 console.log "ERROR: couldn't find cursor position after insert"
 979                                 @kill_cursor()
 980                 return false
 981         clear_dom: -> # remove all the editable content (and cursor, overlays, etc)
 982                 while @idoc.body.childNodes.length
 983                         @idoc.body.removeChild @idoc.body.childNodes[0]
 984                 @kill_cursor()
 985                 return
 986         load_html: (html) ->
 987                 @tree = peach_parser.parse html, @parser_opts
 988                 @clear_dom()
 989                 instantiate_tree @tree, @idoc.body
 990                 tree_dedup_space @tree
 991                 @changed()
 992         changed: ->
 993                 @in_el.onchange = null
 994                 @in_el.value = @pretty_html @tree
 995                 @in_el.onchange = =>
 996                         @load_html @in_el.value
 997                 @adjust_iframe_height()
 998         adjust_iframe_height: ->
 999                 s = @wrap2.scrollTop
1000                 # when the content gets shorter, the idoc's body tag will continue to
1001                 # report the old (too big) height in Chrome. The workaround is to
1002                 # shrink the iframe before the content height:
1003                 @iframe.style.height = "10px"
1004                 h = parseInt(@idoc.body.scrollHeight, 10)
1005                 @iframe.style.height = "#{h}px"
1006                 @wrap2.scrollTop = s
1007         # does this node have whitespace that would be collapsed by white-space: normal?
1008         # note: this checks direct text children, and does _not_ recurse into child tags
1009         # tag is a node with type:"tag"
1010         has_collapsable_space: (tag) ->
1011                 for n in tag.children
1012                         if n.type is 'text'
1013                                 for i in [0...n.text.length]
1014                                         code = n.text.charCodeAt i
1015                                         if code isnt 32 and is_space_code code
1016                                                 # tab, return
1017                                                 return true
1018                                         # check for double spaces that don't surround insert location
1019                                         continue if i is 0
1020                                         if n.text.substr(i - 1, 2) is '  '
1021                                                 return true
1022                                 if n.text.length > 0
1023                                         if is_space_code n.text.charCodeAt 0
1024                                                 return true
1025                                         if is_space_code n.text.charCodeAt n.text.length - 1
1026                                                 return true
1027         # add/remove "white-space: pre[-wrap]" to/from style="" on tags with direct
1028         # child text nodes with multiple spaces in a row, or spaces at the
1029         # start/end.
1030         #
1031         # text inside child tags are not consulted. Child tags are expected to have
1032         # this function applied to them when their content changes.
1033         adjust_whitespace_style: (n) ->
1034                 if n.type is 'text'
1035                         n = n.parent
1036                         return unless n?.el?
1037                 # which css rule should be used to preserve spaces (should we need to)
1038                 style = @iframe.contentWindow.getComputedStyle n.el, null
1039                 ws = style.getPropertyValue 'white-space'
1040                 if ws_props[ws].space
1041                         preserve_rule = ws
1042                 else
1043                         preserve_rule = ws_props[ws].to_preserve
1044                 preserve_rule = "white-space: #{preserve_rule}"
1045                 if @has_collapsable_space n
1046                         # make sure preserve_rule exists
1047                         if n.el.style['white-space']
1048                                 # FIXME check that it matches
1049                                 return
1050                         if n.attrs[style]?
1051                                 n.attrs.style += "; #{preserve_rule}"
1052                         else
1053                                 n.attrs.style = preserve_rule
1054                         n.el.setAttribute 'style', n.attrs.style
1055                 else
1056                         # remove preserve_rule if it exists
1057                         return unless n.attrs.style?
1058                         # FIXME don't assume whitespace is just so
1059                         if n.attrs.style is "white-space: #{ws}"
1060                                 delete n.attrs.style
1061                                 n.el.removeAttribute 'style'
1062                         else
1063                                 # FIXME find it in the middle and at the start
1064                                 needle = "; white-space: #{ws}"
1065                                 if needle is n.attrs.style.substr n.attrs.style.length - needle
1066                                         n.attrs.style = n.attrs.style.substr 0, n.attrs.style.length - needle
1067                                         n.el.setAttribute n.attrs.style
1068         # after calling this, you MUST call changed() and adjust_whitespace_style()
1069         insert_character: (n, i, char) ->
1070                 parent = @cursor.n.parent
1071                 return unless parent
1072                 return unless parent.el?
1073                 # insert the character
1074                 if i is 0
1075                         n.text = char + n.text
1076                 else if i is n.text.length
1077                         n.text += char
1078                 else
1079                         n.text =
1080                                 n.text.substr(0, i) +
1081                                 char +
1082                                 n.text.substr(i)
1083                 n.el.nodeValue = n.text
1084         # after calling this, you MUST call changed() and adjust_whitespace_style()
1085         remove_character: (n, i) ->
1086                 n.text = n.text.substr(0, i) + n.text.substr(i + 1)
1087                 n.el.nodeValue = n.text
1088         kill_cursor: -> # remove it, forget where it was
1089                 if @cursor_visible
1090                         @cursor_el.parentNode.removeChild @cursor_el
1091                         @cursor_visible = false
1092                 @cursor = null
1093                 @annotate null
1094         move_cursor: (cursor) ->
1095                 @cursor_ideal_x = cursor.x
1096                 @cursor = cursor
1097                 unless @cursor_visible
1098                         @cursor_el = domify @outer_idoc, div: id: 'cursor'
1099                         @overlay.appendChild @cursor_el
1100                         @cursor_visible = true
1101                 @cursor_el.style.left = "#{cursor.x + overlay_padding - 1}px"
1102                 if cursor.h < 5
1103                         height = 12
1104                 else
1105                         height = cursor.h
1106                 @cursor_el.style.top = "#{cursor.y + overlay_padding + Math.round(height * .07)}px"
1107                 @cursor_el.style.height = "#{Math.round height * 0.82}px"
1108                 @annotate cursor.n
1109                 @scroll_into_view cursor.y, height
1110         scroll_into_view: (y, h = 0) ->
1111                 closest = 30 # setting: smallest pixels from top/bottom of screet that's OK
1112                 y += overlay_padding # convert units from @idoc to @wrap2
1113                 # very top of document
1114                 if y <= closest
1115                         @wrap2.scrollTop = 0
1116                         return
1117                 # very bottom of document
1118                 if y + h >= @wrap2.scrollHeight - closest
1119                         @wrap2.scrollTop = @wrap2.scrollHeight - @wrap2_height
1120                         return
1121                 # The most scrolled up (lowest value for scrollTop) that would be OK
1122                 upmost = y + h + closest - @wrap2_height
1123                 upmost = Math.max(upmost, 0)
1124                 # the most scrolled down (highest value for scrollTop) that would be OK
1125                 downmost = y - closest
1126                 downmost = Math.min(downmost, @wrap2.scrollHeight - @wrap2_height)
1127                 if upmost > downmost # means h is too big to fit
1128                         # scroll so top is visible
1129                         @wrap2.scrollTop = downmost
1130                         return
1131                 if @wrap2.scrollTop < upmost
1132                         @wrap2.scrollTop = upmost
1133                         return
1134                 if @wrap2.scrollTop > downmost
1135                         @wrap2.scrollTop = downmost
1136                         return
1137                 return
1138         annotate: (n) ->
1139                 while @matting.length > 0
1140                         @overlay.removeChild @matting[0]
1141                         @matting.shift()
1142                 return unless n?
1143                 prev_bounds = x: 0, y: 0, w: 0, h: 0
1144                 alpha = 0.1
1145                 while n?.el?
1146                         if n.type is 'text'
1147                                 n = n.parent
1148                                 continue
1149                         bounds = get_el_bounds n.el
1150                         return unless bounds?
1151                         if bounds.x is prev_bounds.x and bounds.y is prev_bounds.y and bounds.w is prev_bounds.w and bounds.h is prev_bounds.h
1152                                 n = n.parent
1153                                 continue
1154                         ann_box = domify @outer_idoc, div: class: 'ann_box', style: "left: #{bounds.x - 1 + overlay_padding}px; top: #{bounds.y - 2 + overlay_padding}px; width: #{bounds.w}px; height: #{bounds.h}px" # outline: 1000px solid rgba(0,153,255,#{alpha});
1155                         @overlay.appendChild ann_box
1156                         @matting.push ann_box
1157                         ann_tag = domify @outer_idoc, div: class: 'ann_tag', style: "left: #{bounds.x + 1 + overlay_padding}px; top: #{bounds.y - 7 + overlay_padding}px", children: [domify @outer_idoc, text: " #{n.name} "]
1158                         @overlay.appendChild ann_tag
1159                         @matting.push ann_tag
1160                         n = n.parent
1161                         alpha *= 1.5
1162         pretty_html: (tree, indent = '', parent_flags = pre_ish: false, block: true, want_nl: false) ->
1163                 ret = ''
1164                 want_nl = parent_flags.want_nl
1165                 prev_in_flow_is_text = false
1166                 prev_in_flow_is_block = false
1167                 for n, i in tree
1168                         # figure out flags
1169                         inner_flags = want_nl: true
1170                         is_br = false
1171                         switch n.type
1172                                 when 'tag'
1173                                         if n.name is 'br'
1174                                                 is_br = true
1175                                         is_text = false
1176                                         if n.el.currentStyle?
1177                                                 cs = n.el.currentStyle
1178                                                 whitespace = cs['white-space']
1179                                                 display = cs['display']
1180                                                 position = cs['position']
1181                                                 float = cs['float']
1182                                                 visibility = cs['visibility']
1183                                         else
1184                                                 cs = @iframe.contentWindow.getComputedStyle(n.el, null)
1185                                                 whitespace = cs.getPropertyValue 'white-space'
1186                                                 display = cs.getPropertyValue 'display'
1187                                                 position = cs.getPropertyValue 'position'
1188                                                 float = cs.getPropertyValue 'float'
1189                                                 visibility = cs.getPropertyValue 'visibility'
1190                                         if n.name is 'textarea'
1191                                                 inner_flags.pre_ish = true
1192                                         else
1193                                                 inner_flags.pre_ish = whitespace.substr(0, 3) is 'pre'
1194                                         switch float
1195                                                 when 'left', 'right'
1196                                                         in_flow = false
1197                                                 else
1198                                                         switch position
1199                                                                 when 'absolute', 'fixed'
1200                                                                         in_flow = false
1201                                                                 else
1202                                                                         if 'display' is 'none'
1203                                                                                 in_flow = false
1204                                                                         else
1205                                                                                 switch visibility
1206                                                                                         when 'hidden', 'collapse'
1207                                                                                                 in_flow = false
1208                                                                                         else # visible
1209                                                                                                 in_flow = true
1210                                         switch display
1211                                                 when 'inline', 'none'
1212                                                         inner_flags.block = false
1213                                                         is_block = in_flow_block = false
1214                                                 when 'inline-black'
1215                                                         inner_flags.block = true
1216                                                         is_block = in_flow_block = false
1217                                                 else # block, table, etc
1218                                                         inner_flags.block = true
1219                                                         is_block = true
1220                                                         in_flow_block = in_flow
1221                                 when 'text'
1222                                         is_text = true
1223                                         is_block = false
1224                                         in_flow = true
1225                                         in_flow_block = false
1226                                 else # 'comment', 'doctype'
1227                                         is_text = false
1228                                         is_block = false
1229                                         in_flow = false
1230                                         in_flow_block = false
1231                         # print whitespace if we can
1232                         unless parent_flags.pre_ish
1233                                 unless prev_in_flow_is_text and is_br
1234                                         if (i is 0 and parent_flags.block) or in_flow_block or prev_in_flow_is_block
1235                                                 if want_nl
1236                                                         ret += "\n"
1237                                                 ret += indent
1238                         switch n.type
1239                                 when 'tag'
1240                                         ret += '<' + n.name
1241                                         attr_keys = []
1242                                         for k of n.attrs
1243                                                 attr_keys.unshift k
1244                                         #attr_keys.sort()
1245                                         for k in attr_keys
1246                                                 ret += " #{k}"
1247                                                 if n.attrs[k].length > 0
1248                                                         ret += "=\"#{enc_attr n.attrs[k]}\""
1249                                         ret += '>'
1250                                         unless void_elements[n.name]?
1251                                                 if inner_flags.block
1252                                                         next_indent = indent + '    '
1253                                                 else
1254                                                         next_indent = indent
1255                                                 if n.children.length
1256                                                         ret += @pretty_html n.children, next_indent, inner_flags
1257                                                 ret += "</#{n.name}>"
1258                                 when 'text'
1259                                         ret += enc_text n.text
1260                                 when 'comment'
1261                                         ret += "<!--#{n.text}-->" # TODO encode?
1262                                 when 'doctype'
1263                                         ret += "<!DOCTYPE #{n.name}"
1264                                         if n.public_identifier? and n.public_identifier.length > 0
1265                                                 ret += " \"#{n.public_identifier}\""
1266                                         if n.system_identifier? and n.system_identifier.length > 0
1267                                                 ret += " \"#{n.system_identifier}\""
1268                                         ret += ">"
1269                         want_nl = true
1270                         if in_flow
1271                                 prev_in_flow_is_text = is_text
1272                                 prev_in_flow_is_block = is_block or (in_flow and is_br)
1273                 if tree.length
1274                         # output final newline if allowed
1275                         unless parent_flags.pre_ish
1276                                 if prev_in_flow_is_block or parent_flags.block
1277                                         ret += "\n#{indent.substr 4}"
1278                 return ret
1279         onblur: ->
1280                 @kill_cursor()
1281         have_focus: ->
1282                 @editor_is_focused = true
1283                 @poll_for_blur()
1284         poll_for_blur: ->
1285                 return if @poll_for_blur_timeout? # already polling
1286                 @poll_for_blur_timeout = timeout 150, =>
1287                         next_frame => # pause polling when browser knows we're not active/visible/etc.
1288                                 @poll_for_blur_timeout = null
1289                                 if document.activeElement is @outer_iframe
1290                                         @poll_for_blur()
1291                                 else
1292                                         @editor_is_focused = false
1293                                         @onblur()
1294
1295 window.peach_html5_editor = (args...) ->
1296         return new PeachHTML5Editor args...
1297
1298 # test in browser: peach_html5_editor(document.getElementsByTagName('textarea')[0])