editor.coffee

   1 # Copyright 2015 Jason Woofenden
   2 # This file implements an WYSIWYG editor in the browser (no contenteditable)
   3 #
   4 # This program is free software: you can redistribute it and/or modify it under
   5 # the terms of the GNU Affero General Public License as published by the Free
   6 # Software Foundation, either version 3 of the License, or (at your option) any
   7 # later version.
   8 #
   9 # This program is distributed in the hope that it will be useful, but WITHOUT
  10 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  11 # FOR A PARTICULAR PURPOSE.  See the GNU Affero General Public License for more
  12 # details.
  13 #
  14 # You should have received a copy of the GNU Affero General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16
  17 # SETTINGS
  18 overlay_padding = 10
  19
  20 timeout = (ms, cb) -> return setTimeout cb, ms
  21 next_frame = (cb) ->
  22         if (window.requestAnimationFrame?)
  23                 window.requestAnimationFrame cb
  24         else
  25                 timeout 16, cb
  26
  27 this_url_sans_path = ->
  28         ret = "#{window.location.href}"
  29         clip = ret.lastIndexOf '#'
  30         if clip > -1
  31                 ret = ret.substr 0, clip
  32         clip = ret.lastIndexOf '?'
  33         if clip > -1
  34                 ret = ret.substr 0, clip
  35         clip = ret.lastIndexOf '/'
  36         if clip > -1
  37                 ret = ret.substr 0, clip + 1
  38         return ret
  39
  40 # xml 1.0 spec, chromium and firefox accept these, plus lots of unicode chars
  41 valid_attr_regex = new RegExp '^[a-zA-Z_:][-a-zA-Z0-9_:.]*$'
  42 # html5 spec is much more lax, but chromium won't let me make at attribute with the name "4"
  43 js_attr_regex = new RegExp '^[oO][nN].'
  44
  45 debug_dot_at = (doc, x, y) ->
  46         return # disabled
  47         el = doc.createElement 'div'
  48         el.setAttribute 'style', "position: absolute; left: #{x}px; top: #{y}px; width: 1px; height: 3px; background-color: red"
  49         doc.body.appendChild el
  50         #console.log(new Error().stack)
  51
  52 # text nodes don't have getBoundingClientRect(), so use selection api to find
  53 # it.
  54 get_el_bounds = (el) ->
  55         if el.getBoundingClientRect?
  56                 rect = el.getBoundingClientRect()
  57         else
  58                 # text nodes don't have getBoundingClientRect(), so use range api
  59                 range = el.ownerDocument.createRange()
  60                 range.selectNodeContents el
  61                 rect = range.getBoundingClientRect()
  62         doc = el.ownerDocument.documentElement
  63         win = el.ownerDocument.defaultView
  64         y_fix = win.pageYOffset - doc.clientTop
  65         x_fix = win.pageXOffset - doc.clientLeft
  66         return {
  67                 x: rect.left + x_fix
  68                 y: rect.top + y_fix
  69                 w: rect.width ? (rect.right - rect.left)
  70                 h: rect.height ? (rect.top - rect.bottom)
  71         }
  72
  73 is_display_block = (el) ->
  74         if el.currentStyle?
  75                 return el.currentStyle.display is 'block'
  76         else
  77                 return window.getComputedStyle(el, null).getPropertyValue('display') is 'block'
  78
  79 # Pass return value from dom event handlers to this.
  80 # If they return false, this will addinionally stop propagation and default.
  81 event_return = (e, bool) ->
  82         if bool is false
  83                 if e.stopPropagation?
  84                         e.stopPropagation()
  85                 if e.preventDefault?
  86                         e.preventDefault()
  87         return bool
  88 # Warning: currently assumes you're asking about a single character
  89 # Note: chromium returns multiple bounding rects for a space at a line-break
  90 # Note: chromium's getBoundingClientRect() is broken (when zero-area client rects)
  91 # Note: sometimes returns null (eg for whitespace that is not visible)
  92 text_range_bounds = (el, start, end) ->
  93         range = document.createRange()
  94         range.setStart el, start
  95         range.setEnd el, end
  96         rects = range.getClientRects()
  97         if rects.length > 0
  98                 rect = rects[0]
  99         else
 100                 return null
 101         doc = el.ownerDocument.documentElement
 102         win = el.ownerDocument.defaultView
 103         y_fix = win.pageYOffset - doc.clientTop
 104         x_fix = win.pageXOffset - doc.clientLeft
 105         return {
 106                 x: rect.left + x_fix
 107                 y: rect.top + y_fix
 108                 w: rect.width ? (rect.right - rect.left)
 109                 h: rect.height ? (rect.top - rect.bottom)
 110                 rects: rects
 111                 bounding: range.getBoundingClientRect()
 112         }
 113
 114 # figure out the x/y coordinates of where the cursor should be if it's at
 115 # position ``i`` within text node ``n``
 116 # sometimes returns null (eg for whitespace that is not visible)
 117 window.cursor_to_xyh = cursor_to_xyh = (n, i) ->
 118         range = document.createRange()
 119         if n.text.length is 0
 120                 ret = text_range_bounds n.el, 0, 0
 121         else if i is n.text.length
 122                 ret = text_range_bounds n.el, i - 1, i
 123                 if ret?
 124                         ret.x += ret.w
 125         else
 126                 ret = text_range_bounds n.el, i, i + 1
 127         if ret?
 128                 debug_dot_at n.el.ownerDocument, ret.x, ret.y
 129         return ret
 130
 131 # encode text so it can be safely placed inside an html attribute
 132 enc_attr_regex = new RegExp '(&)|(")|(\u00A0)', 'g'
 133 enc_attr = (txt) ->
 134         return txt.replace enc_attr_regex, (match, amp, quote) ->
 135                 return '&amp;' if (amp)
 136                 return '&quot;' if (quote)
 137                 return '&nbsp;'
 138 enc_text_regex = new RegExp '(&)|(<)|(\u00A0)', 'g'
 139 enc_text = (txt) ->
 140         return txt.replace enc_text_regex, (match, amp, lt) ->
 141                 return '&amp;' if (amp)
 142                 return '&lt;' if (lt)
 143                 return '&nbsp;'
 144
 145 void_elements = {
 146         area: true
 147         base: true
 148         br: true
 149         col: true
 150         embed: true
 151         hr: true
 152         img: true
 153         input: true
 154         keygen: true
 155         link: true
 156         meta: true
 157         param: true
 158         source: true
 159         track: true
 160         wbr: true
 161 }
 162 # TODO make these always pretty-print (on the inside) like blocks
 163 no_text_elements = { # these elements never contain text
 164         select: true
 165         table: true
 166         tr: true
 167         thead: true
 168         tbody: true
 169         ul: true
 170         ol: true
 171 }
 172
 173 domify = (doc, hash) ->
 174         for tag, attrs of hash
 175                 if tag is 'text'
 176                         return document.createTextNode attrs
 177                 el = document.createElement tag
 178                 for k, v of attrs
 179                         if k is 'children'
 180                                 for child in v
 181                                         el.appendChild child
 182                         else
 183                                 el.setAttribute k, v
 184         return el
 185
 186 outer_css = (args) ->
 187         w = args.w ? 300
 188         h = args.h ? 300
 189         inner_padding = args.inner_padding ? overlay_padding
 190         frame_width = args.frame_width ? inner_padding
 191         # TODO editor controls height...
 192         occupy = (left, top = left, right = left, bottom = top) ->
 193                 w -= left + right
 194                 h -= top + bottom
 195                 return Math.max(left, top, right, bottom)
 196         ret = ''
 197         ret += 'body {'
 198         ret +=     'margin: 0;'
 199         ret +=     'padding: 0;'
 200         ret +=     'color: black;'
 201         ret +=     'background: white;'
 202         ret += '}'
 203         ret += '#wrap1 {'
 204         ret +=     "border: #{occupy 1}px solid black;"
 205         ret +=     "padding: #{occupy frame_width}px;"
 206         ret += '}'
 207         ret += '#wrap2 {'
 208         ret +=     "border: #{occupy 1}px solid black;"
 209         ret +=     "padding: #{occupy inner_padding}px;"
 210         ret +=     "padding-right: #{inner_padding + occupy 0, 0, 15, 0}px;" # for scroll bar
 211         ret +=     "width: #{w}px;"
 212         ret +=     "height: #{h}px;"
 213         ret +=     'overflow-x: hidden;'
 214         ret +=     'overflow-y: scroll;'
 215         ret += '}'
 216         ret += '#wrap3 {'
 217         ret +=     'position: relative;'
 218         ret +=     "width: #{w}px;"
 219         ret +=     "min-height: #{h}px;"
 220         ret += '}'
 221         ret += 'iframe {'
 222         ret +=     'box-sizing: border-box;'
 223         ret +=     'margin: 0;'
 224         ret +=     'border: none;'
 225         ret +=     'padding: 0;'
 226         ret +=     "width: #{w}px;"
 227         #ret +=     "height: #{h}px;" # height auto-set when content set/changed
 228         ret +=     '-ms-user-select: none;'
 229         ret +=     '-webkit-user-select: none;'
 230         ret +=     '-moz-user-select: none;'
 231         ret +=     'user-select: none;'
 232         ret += '}'
 233         ret += '#overlay {'
 234         ret +=     'position: absolute;'
 235         ret +=     "left: -#{inner_padding}px;"
 236         ret +=     "top: -#{inner_padding}px;"
 237         ret +=     "right: -#{inner_padding}px;"
 238         ret +=     "bottom: -#{inner_padding}px;"
 239         ret +=     'overflow: hidden;'
 240         ret += '}'
 241         ret += '.lightbox {'
 242         ret +=     'position: absolute;'
 243         ret +=     'background: rgba(100,100,100,0.2);'
 244         ret += '}'
 245         ret += '#cursor {'
 246         ret +=     'position: absolute;'
 247         ret +=     'width: 2px;'
 248         ret +=     'background: linear-gradient(0deg, rgba(0,0,0,1), rgba(255,255,255,1), rgba(0,0,0,1), rgba(255,255,255,1), rgba(0,0,0,1), rgba(255,255,255,1), rgba(0,0,0,1), rgba(255,255,255,1), rgba(0,0,0,1));'
 249         ret +=     'background-size: 200% 200%;'
 250         ret +=     '-webkit-animation: blink 1s linear normal infinite;'
 251         ret +=     'animation: blink 1s linear normal infinite;'
 252         ret += '}'
 253         ret += '@-webkit-keyframes blink {'
 254         ret +=     '0%{background-position:0% 0%}'
 255         ret +=     '100%{background-position:0% -100%}'
 256         ret += '}'
 257         ret += '@keyframes blink { '
 258         ret +=     '0%{background-position:0% 0%}'
 259         ret +=     '100%{background-position:0% -100%}'
 260         ret += '}'
 261         ret += '.ann_box {'
 262         ret +=     'z-index: 5;'
 263         ret +=     'position: absolute;'
 264         ret +=     'border: 1px solid rgba(0,0,0,0.1);'
 265         ret +=     'outline: 1px solid rgba(255,255,255,0.1);' # in case there's a black background
 266         ret += '}'
 267         ret += '.ann_tag {'
 268         ret +=     'z-index: 10;'
 269         ret +=     'position: absolute;'
 270         ret +=     'font-size: 8px;'
 271         ret +=     'white-space: pre;'
 272         ret +=     'background: rgba(255,255,255,0.4);'
 273         ret +=     '-ms-user-select: none;'
 274         ret +=     '-webkit-user-select: none;'
 275         ret +=     '-moz-user-select: none;'
 276         ret +=     'user-select: none;'
 277         ret += '}'
 278         return ret
 279
 280
 281 ignore_key_codes =
 282         '18': true # alt
 283         '20': true # capslock
 284         '17': true # ctrl
 285         '144': true # numlock
 286         '16': true # shift
 287         '91': true # windows "start" key
 288 # key codes: (valid on keydown, not keypress)
 289 KEY_LEFT = 37
 290 KEY_UP = 38
 291 KEY_RIGHT = 39
 292 KEY_DOWN = 40
 293 KEY_BACKSPACE = 8 # <--
 294 KEY_DELETE = 46 # -->
 295 KEY_END = 35
 296 KEY_ENTER = 13
 297 KEY_ESCAPE = 27
 298 KEY_HOME = 36
 299 KEY_INSERT = 45
 300 KEY_PAGE_UP = 33
 301 KEY_PAGE_DOWN = 34
 302 KEY_TAB = 9
 303 control_key_codes = # we react to these, but they aren't typing
 304         '37': KEY_LEFT
 305         '38': KEY_UP
 306         '39': KEY_RIGHT
 307         '40': KEY_DOWN
 308         '35': KEY_END
 309         '8':  KEY_BACKSPACE
 310         '46': KEY_DELETE
 311         '13': KEY_ENTER
 312         '27': KEY_ESCAPE
 313         '36': KEY_HOME
 314         '45': KEY_INSERT
 315         '33': KEY_PAGE_UP
 316         '34': KEY_PAGE_DOWN
 317         '9':  KEY_TAB
 318
 319 instantiate_tree = (tree, parent) ->
 320         remove = []
 321         for c, i in tree
 322                 switch c.type
 323                         when 'text'
 324                                 c.el = parent.ownerDocument.createTextNode c.text
 325                                 parent.appendChild c.el
 326                         when 'tag'
 327                                 if c.name in ['script', 'object', 'iframe', 'link']
 328                                         # TODO put placeholders instead
 329                                         remove.unshift i
 330                                         continue
 331                                 # TODO create in correct namespace
 332                                 c.el = parent.ownerDocument.createElement c.name
 333                                 for k, v of c.attrs
 334                                         # FIXME if attr_whitelist[k]?
 335                                         if valid_attr_regex.test k
 336                                                 unless js_attr_regex.test k
 337                                                         c.el.setAttribute k, v
 338                                 parent.appendChild c.el
 339                                 if c.children.length
 340                                         instantiate_tree c.children, c.el
 341         for i in remove
 342                 tree.splice i, 1
 343
 344 traverse_tree = (tree, cb) ->
 345         done = false
 346         for c in tree
 347                 done = cb c
 348                 return done if done
 349                 if c.children.length
 350                         done = traverse_tree c.children, cb
 351                         return done if done
 352         return done
 353
 354 find_next_cursor_position = (tree, n, i) ->
 355         if n.type is 'text' and n.text.length > i
 356                 orig_xyh = cursor_to_xyh n, i
 357                 unless orig_xyh?
 358                         console.log "ERROR: couldn't find xy for current cursor location"
 359                         return
 360                 for next_i in [i+1 .. n.text.length] # inclusive is valid (after last char)
 361                         next_xyh = cursor_to_xyh n, next_i
 362                         if next_xyh?
 363                                 if next_xyh.x > orig_xyh.x or next_xyh.y > orig_xyh.y
 364                                         return [n, next_i]
 365         state_before = true
 366         found = null
 367         traverse_tree tree, (node, state) ->
 368                 if node.type is 'text' and state_before is false
 369                         if cursor_to_xyh(node, 0)?
 370                                 found = node
 371                                 return true
 372                 if node is n
 373                         state_before = false
 374                 return false
 375         if found?
 376                 return [found, 0]
 377         return null
 378
 379 find_prev_cursor_position = (tree, n, i) ->
 380         if n? and n.type is 'text' and i > 0
 381                 orig_xyh = cursor_to_xyh n, i
 382                 unless orig_xyh?
 383                         console.log "ERROR: couldn't find xy for current cursor location"
 384                         return
 385                 for prev_i in [i-1 .. 0]
 386                         prev_xyh = cursor_to_xyh n, prev_i
 387                         if prev_xyh?
 388                                 if prev_xyh.x < orig_xyh.x or prev_xyh.y < orig_xyh.y
 389                                         return [n, prev_i]
 390                 return [n, i - 1]
 391         found_prev = null
 392         found = null
 393         traverse_tree tree, (node) ->
 394                 if node.type is 'text'
 395                         unless n?
 396                                 found = node
 397                                 return true
 398                         if node is n
 399                                 found = found_prev # null if n is the first text node
 400                                 return true
 401                         found_prev = node
 402                 return false
 403         if found?
 404                 if cursor_to_xyh found, found.text.length # text visible?
 405                         return [found, found.text.length]
 406                 return find_prev_cursor_position tree, found, 0
 407         return null
 408
 409 find_loc_cursor_position = (tree, loc) ->
 410         for c in tree
 411                 if c.type is 'tag' or c.type is 'text'
 412                         bounds = get_el_bounds c.el
 413                         continue if loc.x < bounds.x
 414                         continue if loc.x > bounds.x + bounds.w
 415                         continue if loc.y < bounds.y
 416                         continue if loc.y > bounds.y + bounds.h
 417                         if c.children.length
 418                                 ret = find_loc_cursor_position c.children, loc
 419                                 return ret if ret?
 420                         if c.type is 'text'
 421                                 # click is within bounding box that contains all text.
 422                                 return [c, 0] if c.text.length is 0
 423                                 before_i = 0
 424                                 before = cursor_to_xyh c, before_i
 425                                 unless before?
 426                                         console.log "error: failed to find cursor pixel location for start of", c
 427                                         return
 428                                 after_i = c.text.length
 429                                 after = cursor_to_xyh c, after_i
 430                                 unless after?
 431                                         console.log "error: failed to find cursor pixel location for end of", c
 432                                         return
 433                                 if loc.y < before.y + before.h and loc.x < before.x
 434                                         # console.log 'before first char on first line'
 435                                         continue
 436                                 if loc.y > after.y and loc.x > after.x
 437                                         # console.log 'after last char on last line'
 438                                         continue
 439                                 if loc.y < before.y
 440                                         console.log "Warning: click in bounding box but above first line"
 441                                         continue # above first line (runaround?)
 442                                 if loc.y > after.y + after.h
 443                                         console.log "Warning: click in bounding box but below last line", loc.y, after.y, after.h
 444                                         continue # below last line (shouldn't happen?)
 445                                 while after_i - before_i > 1
 446                                         cur_i = Math.round((before_i + after_i) / 2)
 447                                         cur = cursor_to_xyh c, cur_i
 448                                         unless loc?
 449                                                 console.log "error: failed to find cursor pixel location for", c, cur_i
 450                                                 return
 451                                         if loc.y < cur.y or (loc.y <= cur.y + cur.h and loc.x < cur.x)
 452                                                 after_i = cur_i
 453                                                 after = cur
 454                                         else
 455                                                 before_i = cur_i
 456                                                 before = cur
 457                                 # which one is closest?
 458                                 if Math.abs(before.x - loc.x) < Math.abs(after.x - loc.x)
 459                                         return [c, before_i]
 460                                 else
 461                                         return [c, after_i]
 462         return null
 463
 464 # browsers collapse these (html5 spec calls these "space characters")
 465 is_space_code = (char_code) ->
 466         switch char_code
 467                 when 9, 10, 12, 13, 32
 468                         return true
 469         return false
 470 is_space = (chr) ->
 471         return is_space_code chr.charCodeAt 0
 472
 473 tree_remove_empty_text_nodes = (tree) ->
 474         empties = []
 475         traverse_tree tree, (n) ->
 476                 if n.type is 'text'
 477                         if n.text.length is 0
 478                                 empties.unshift n
 479                 return false
 480         for n in empties
 481                 # don't completely empty the tree
 482                 if tree.length is 1
 483                         if tree[0].type is 'text'
 484                                 console.log "oop, leaving a blank node because it's the only thing"
 485                                 return
 486                 n.el.parentNode.removeChild n.el
 487                 for c, i in n.parent.children
 488                         if c is n
 489                                 n.parent.children.splice i, 1
 490                                 break
 491
 492 # pass a array of nodes (from parser library, ie it should have .el and .text)
 493 tree_dedup_space = (tree) ->
 494         prev = cur = next = null
 495         prev_i = cur_i = next_i = 0
 496         prev_pos = pos = next_pos = null
 497         prev_px = cur_px = next_px = null
 498         first = true
 499         removed_char = null
 500
 501         tree_remove_empty_text_nodes(tree)
 502
 503         iterate = (tree, cb) ->
 504                 for n in tree
 505                         if n.type is 'text'
 506                                 i = 0
 507                                 while i < n.text.length # don't foreach, cb might remove chars
 508                                         advance = cb n, i
 509                                         if advance
 510                                                 i += 1
 511                         if n.type is 'tag'
 512                                 block = is_display_block n.el
 513                                 if block
 514                                         cb null
 515                                 if n.children.length > 0
 516                                         iterate n.children, cb
 517                                 if block
 518                                         cb null
 519         # remove cur char
 520         remove = ->
 521                 removed_char = cur.text.charAt(cur_i)
 522                 cur.el.textContent = cur.text = (cur.text.substr 0, cur_i) + (cur.text.substr cur_i + 1)
 523                 if next is cur # in same text node
 524                         if next_i is 0
 525                                 throw "how is this possible?"
 526                         next_i -= 1
 527                 return true
 528         # undo remove()
 529         put_it_back = ->
 530                 cur.el.textContent = cur.text = (cur.text.substr 0, cur_i) + removed_char + (cur.text.substr cur_i)
 531                 if next is cur # in same text node
 532                         next_i += 1
 533                 return false
 534         # return true if cur was removed from the dom (ie re-use same prev)
 535         operate = ->
 536                 # cur definitately set
 537                 # prev and/or next might be null, indicating the start/end of a display:block
 538                 return false unless is_space_code cur.text.charCodeAt cur_i
 539                 bounds = text_range_bounds cur.el, cur_i, cur_i + 1
 540                 # consistent cases:
 541                 # 1. zero rects returned by getClientRects() means collapsed space
 542                 if bounds is null
 543                         return remove()
 544                 # 2. width greater than zero means visible space
 545                 if bounds.w > 0
 546                         return false
 547                 # now the weird edge cases...
 548                 #
 549                 # firefox and chromium both report zero width for characters at the end
 550                 # of a line where the text wraps (automatically, due to word-wrap) to
 551                 # the next line. These do not appear to be distinguishable from
 552                 # collapsed spaces via the range/bounds api, so...
 553                 #
 554                 # remove it from the dom, and if prev or next moves, put it back.
 555                 if prev? and not prev_px?
 556                         prev_px = cursor_to_xyh prev, prev_i
 557                 if next? and not next_px?
 558                         next_px = cursor_to_xyh next, next_i
 559                 #if prev is null and next is null
 560                 #       parent_px = cur.parent.el.getBoundingClientRect()
 561                 remove()
 562                 if prev?
 563                         if prev_px?
 564                                 new_prev_px = cursor_to_xyh prev, prev_i
 565                                 if new_prev_px.x isnt prev_px.x or new_prev_px.y isnt prev_px.y
 566                                         return put_it_back()
 567                         else
 568                                 console.log "this shouldn't happen, we remove spaces that don't locate"
 569                 if next?
 570                         if next_px?
 571                                 new_next_px = cursor_to_xyh next, next_i
 572                                 if new_next_px.x isnt next_px.x or new_next_px.y isnt next_px.y
 573                                         return put_it_back()
 574                         #else
 575                         #       console.log "removing space becase space after it is collapsed"
 576                 return true
 577         # pass null at start/end of display:block
 578         queue = (n, i) ->
 579                 next = n
 580                 next_i = i
 581                 next_px = null
 582                 advance = true
 583                 if cur?
 584                         removed = operate()
 585                         # don't advance (to the next character next time) if we removed a
 586                         # character from the same text node as ``next``, because doing so
 587                         # renumbers the indexes in that string
 588                         if removed and cur is next
 589                                 advance = false
 590                 else
 591                         removed = false
 592                 unless removed
 593                         prev = cur
 594                         prev_i = cur_i
 595                         prev_px = cur_px
 596                 cur = next
 597                 cur_i = next_i
 598                 cur_px = next_px
 599                 return advance
 600         queue null
 601         iterate tree, queue
 602         queue null
 603
 604         tree_remove_empty_text_nodes(tree)
 605
 606 class PeachHTML5Editor
 607         # Options: (all optional)
 608         #   editor_id: "id" attribute for outer-most element created by/for editor
 609         #   css_file: filename of a css file to style editable content
 610         #   on_init: callback for when the editable content is in place
 611         constructor: (in_el, options) ->
 612                 @options = options ? {}
 613                 @in_el = in_el
 614                 @tree = null
 615                 @matting = []
 616                 @init_1_called = false # when iframes have loaded
 617                 @outer_iframe # iframe to hold editor
 618                 @outer_idoc # "document" object for @outer_iframe
 619                 @wrap2 = null # scrollbar is on this
 620                 @iframe = null # iframe to hold editable content
 621                 @idoc = null # "document" object for @iframe
 622                 @cursor = null
 623                 @cursor_el = null
 624                 @cursor_visible = false
 625                 @poll_for_blur_timeout = null
 626                 @iframe_offset = null
 627                 @iframe_height = null
 628                 opt_fragment = @options.fragment ? true
 629                 @parser_opts = {}
 630                 if opt_fragment
 631                         @parser_opts.fragment = 'body'
 632
 633                 @outer_iframe = domify document, iframe: {}
 634                 outer_iframe_style = 'border: none !important; margin: 0 !important; padding: 0 !important; height: 100% !important; width: 100% !important;'
 635                 if @options.editor_id?
 636                         @outer_iframe.setAttribute 'id', @options.editor_id
 637                 @outer_iframe.onload = =>
 638                         @outer_idoc = @outer_iframe.contentDocument
 639                         icss = domify @outer_idoc, style: children: [
 640                                 domify @outer_idoc, text: css
 641                         ]
 642                         @outer_idoc.head.appendChild icss
 643                         @iframe = domify @outer_idoc, iframe: sandbox: 'allow-same-origin allow-scripts'
 644                         @iframe.onload = =>
 645                                 @init_1()
 646                         timeout 200, => # firefox never fires this onload
 647                                 @init_1() unless @init_1_called
 648                         @outer_idoc.body.appendChild(
 649                                 domify @outer_idoc, div: id: 'wrap1', children: [
 650                                         domify @outer_idoc, div: style: "position: absolute; top: 0; left: 1px; font-size: 10px", children: [ domify @outer_idoc, text: "Peach HTML5 Editor" ]
 651                                         @wrap2 = domify @outer_idoc, div: id: 'wrap2', children: [
 652                                                 domify @outer_idoc, div: id: 'wrap3', children: [
 653                                                         @iframe
 654                                                         @overlay = domify @outer_idoc, div: id: 'overlay'
 655                                                 ]
 656                                         ]
 657                                 ]
 658                         )
 659                 outer_wrap = domify document, div: class: 'peach_html5_editor'
 660                 @in_el.parentNode.appendChild outer_wrap
 661                 outer_bounds = get_el_bounds outer_wrap
 662                 if outer_bounds.w < 300
 663                         outer_bounds.w = 300
 664                 if outer_bounds.h < 300
 665                         outer_bounds.h = 300
 666                 outer_iframe_style += "width: #{outer_bounds.w}px; height: #{outer_bounds.h}px;"
 667                 @outer_iframe.setAttribute 'style', outer_iframe_style
 668                 css = outer_css w: outer_bounds.w, h: outer_bounds.h
 669                 outer_wrap.appendChild @outer_iframe
 670         init_1: -> # @iframe has loaded (but not it's css)
 671                 @idoc = @iframe.contentDocument
 672                 @init_1_called = true
 673                 # chromium doesn't resolve relative urls as though they were at the same domain
 674                 # so add a <base> tag
 675                 @idoc.head.appendChild domify @idoc, base: href: this_url_sans_path()
 676                 # don't let @iframe have scrollbars
 677                 @idoc.head.appendChild domify @idoc, style: children: [domify @idoc, text: "body { overflow: hidden; }"]
 678                 # load css file
 679                 if @options.css_file
 680                         istyle = domify @idoc, link: rel: 'stylesheet', href: @options.css_file
 681                         istyle.onload = =>
 682                                 @init_2()
 683                         @idoc.head.appendChild istyle
 684                 else
 685                         @init_2()
 686         init_2: -> # @iframe and it's css file(s) are ready
 687                 @overlay.onclick = (e) =>
 688                         @have_focus()
 689                         return event_return e, @onclick e
 690                 @overlay.ondoubleclick = (e) =>
 691                         @have_focus()
 692                         return event_return e, @ondoubleclick e
 693                 @outer_idoc.body.onkeyup = (e) =>
 694                         @have_focus()
 695                         return event_return e, @onkeyup e
 696                 @outer_idoc.body.onkeydown = (e) =>
 697                         @have_focus()
 698                         return event_return e, @onkeydown e
 699                 @outer_idoc.body.onkeypress = (e) =>
 700                         @have_focus()
 701                         return event_return e, @onkeypress e
 702                 @load_html @in_el.value
 703                 if @options.on_init?
 704                         @options.on_init()
 705         overlay_event_to_inner_xy: (e) ->
 706                 unless @iframe_offset?
 707                         @iframe_offset = get_el_bounds @iframe
 708                 x = e.pageX # TODO ?cross-browserify
 709                 y = e.pageY + @wrap2.scrollTop # TODO ?cross-browserify
 710                 # TODO adjust for scrolling
 711                 return x: x - @iframe_offset.x, y: y - @iframe_offset.y
 712         onclick: (e) ->
 713                 xy = @overlay_event_to_inner_xy e
 714                 new_cursor = find_loc_cursor_position @tree, xy
 715                 if new_cursor?
 716                         @move_cursor new_cursor
 717                 else
 718                         @kill_cursor()
 719                 return false
 720         ondoubleclick: (e) ->
 721                 return false
 722         onkeyup: (e) ->
 723                 return if e.ctrlKey
 724                 return false if ignore_key_codes[e.keyCode]?
 725                 #return false if control_key_codes[e.keyCode]?
 726         onkeydown: (e) ->
 727                 return if e.ctrlKey
 728                 return false if ignore_key_codes[e.keyCode]?
 729                 #return false if control_key_codes[e.keyCode]?
 730                 switch e.keyCode
 731                         when KEY_LEFT
 732                                 if @cursor?
 733                                         new_cursor = find_prev_cursor_position @tree, @cursor...
 734                                         if new_cursor?
 735                                                 @move_cursor new_cursor
 736                                 else
 737                                         for c in @tree
 738                                                 new_cursor = find_next_cursor_position @tree, c, -1
 739                                                 if new_cursor?
 740                                                         @move_cursor new_cursor
 741                                                         break
 742                                 return false
 743                         when KEY_UP
 744                                 if @cursor?
 745                                         new_cursor = @cursor
 746                                         old_loc = cursor_to_xyh new_cursor[0], new_cursor[1]
 747                                         new_loc = x: old_loc.x, y: old_loc.y
 748                                         while new_loc.y >= old_loc.y
 749                                                 new_cursor = find_prev_cursor_position @tree, new_cursor[0], new_cursor[1]
 750                                                 return false unless new_cursor?
 751                                                 new_loc = cursor_to_xyh new_cursor[0], new_cursor[1]
 752                                         if new_cursor?
 753                                                 # now we're above
 754                                                 if new_loc.x <= old_loc.x
 755                                                         @move_cursor new_cursor
 756                                                         return false
 757                                                 target_y = new_loc.y
 758                                                 # search leftward, until we find the closest position
 759                                                 while new_loc.x > old_loc.x and new_loc.y is target_y
 760                                                         prev_loc = new_loc
 761                                                         prev_cursor = new_cursor
 762                                                         new_cursor = find_prev_cursor_position @tree, new_cursor[0], new_cursor[1]
 763                                                         break unless new_cursor?
 764                                                         new_loc = cursor_to_xyh new_cursor[0], new_cursor[1]
 765                                                 # move cursor to prev_cursor or new_cursor
 766                                                 if new_cursor?
 767                                                         if new_loc.y is target_y
 768                                                                 # both valid, and on the same line, use closest
 769                                                                 if (old_loc.x - new_loc.x) < (prev_loc.x - old_loc.x)
 770                                                                         @move_cursor new_cursor
 771                                                                 else
 772                                                                         @move_cursor prev_cursor
 773                                                         else
 774                                                                 # new_cursor on wrong line, use prev_cursor
 775                                                                 @move_cursor prev_cursor
 776                                                 else
 777                                                         # can't go any further prev, use prev_cursor
 778                                                         @move_cursor prev_cursor
 779                                 else
 780                                         # move cursor to first position in document
 781                                         new_cursor = find_prev_cursor_position @tree
 782                                         if new_cursor?
 783                                                 @move_cursor new_cursor
 784                                                 break
 785                                 return false
 786                         when KEY_RIGHT
 787                                 if @cursor?
 788                                         new_cursor = find_next_cursor_position @tree, @cursor...
 789                                         if new_cursor?
 790                                                 @move_cursor new_cursor
 791                                 else
 792                                         # move cursor to first position in document
 793                                         new_cursor = find_prev_cursor_position @tree
 794                                         if new_cursor?
 795                                                 @move_cursor new_cursor
 796                                                 break
 797                                 return false
 798                         when KEY_DOWN
 799                                 return false
 800                         when KEY_END
 801                                 return false
 802                         when KEY_BACKSPACE
 803                                 return false unless @cursor?
 804                                 return false unless @cursor[1] > 0
 805                                 @cursor[0].text = @cursor[0].text.substr(0, @cursor[1] - 1) + @cursor[0].text.substr(@cursor[1])
 806                                 @cursor[0].el.nodeValue = @cursor[0].text
 807                                 @move_cursor [@cursor[0], @cursor[1] - 1]
 808                                 @changed()
 809                                 return false
 810                         when KEY_DELETE
 811                                 return false unless @cursor?
 812                                 return false unless @cursor[1] < @cursor[0].text.length
 813                                 @cursor[0].text = @cursor[0].text.substr(0, @cursor[1]) + @cursor[0].text.substr(@cursor[1] + 1)
 814                                 @cursor[0].el.nodeValue = @cursor[0].text
 815                                 @move_cursor [@cursor[0], @cursor[1]]
 816                                 @changed()
 817                                 return false
 818                         when KEY_ENTER
 819                                 return false
 820                         when KEY_ESCAPE
 821                                 return false
 822                         when KEY_HOME
 823                                 return false
 824                         when KEY_INSERT
 825                                 return false
 826                         when KEY_PAGE_UP
 827                                 return false
 828                         when KEY_PAGE_DOWN
 829                                 return false
 830                         when KEY_TAB
 831                                 return false
 832         onkeypress: (e) ->
 833                 return if e.ctrlKey
 834                 return false if ignore_key_codes[e.keyCode]?
 835                 # return false if control_key_codes[e.keyCode]? # handled in keydown
 836                 char = e.charCode ? e.keyCode
 837                 if char and @cursor?
 838                         char = String.fromCharCode char
 839                         if @cursor[1] is 0
 840                                 @cursor[0].text = char + @cursor[0].text
 841                         else if @cursor[1] is @cursor[0].text.length - 1
 842                                 @cursor[0].text += char
 843                         else
 844                                 @cursor[0].text =
 845                                         @cursor[0].text.substr(0, @cursor[1]) +
 846                                         char +
 847                                         @cursor[0].text.substr(@cursor[1])
 848                         @cursor[0].el.nodeValue = @cursor[0].text
 849                         @move_cursor [@cursor[0], @cursor[1] + 1]
 850                         @changed()
 851                 return false
 852         clear_dom: -> # remove all the editable content (and cursor, overlays, etc)
 853                 while @idoc.body.childNodes.length
 854                         @idoc.body.removeChild @idoc.body.childNodes[0]
 855                 @kill_cursor()
 856                 return
 857         load_html: (html) ->
 858                 @tree = peach_parser.parse html, @parser_opts
 859                 @clear_dom()
 860                 instantiate_tree @tree, @idoc.body
 861                 tree_dedup_space @tree
 862                 @changed()
 863         changed: ->
 864                 @in_el.onchange = null
 865                 @in_el.value = @pretty_html @tree
 866                 @in_el.onchange = =>
 867                         @load_html @in_el.value
 868                 @adjust_iframe_height()
 869         adjust_iframe_height: ->
 870                 h = parseInt(@idoc.body.scrollHeight, 10)
 871                 if @iframe_height isnt h
 872                         @iframe_height = h
 873                         s = @wrap2.scrollTop
 874                         @iframe.style.height = "0"
 875                         @iframe.style.height = "#{h}px"
 876                         @wrap2.scrollTop = s
 877         kill_cursor: -> # remove it, forget where it was
 878                 if @cursor_visible
 879                         @cursor_el.parentNode.removeChild @cursor_el
 880                         @cursor_visible = false
 881                 @cursor = null
 882                 @matt null
 883         move_cursor: (cursor) ->
 884                 loc = cursor_to_xyh cursor[0], cursor[1]
 885                 unless loc?
 886                         console.log "error: tried to move cursor to position that has no pixel location", cursor[0], cursor[1]
 887                         return
 888                 @cursor = cursor
 889                 # replace cursor element, to reset blink animation
 890                 if @cursor_visible
 891                         @cursor_el.parentNode.removeChild @cursor_el
 892                 @cursor_el = domify @outer_idoc, div: id: 'cursor'
 893                 @overlay.appendChild @cursor_el
 894                 @cursor_visible = true
 895                 @cursor_el.style.left = "#{loc.x + overlay_padding - 1}px"
 896                 if loc.h < 5
 897                         height = 12
 898                 else
 899                         height = loc.h
 900                 @cursor_el.style.top = "#{loc.y + overlay_padding + Math.round(height * .07)}px"
 901                 @cursor_el.style.height = "#{Math.round height * 0.82}px"
 902                 @matt cursor[0]
 903         matt: (n) ->
 904                 while @matting.length > 0
 905                         @overlay.removeChild @matting[0]
 906                         @matting.shift()
 907                 return unless n?
 908                 prev_bounds = x: 0, y: 0, w: 0, h: 0
 909                 alpha = 0.1
 910                 while n?.el?
 911                         if n.type is 'text'
 912                                 n = n.parent
 913                                 continue
 914                         bounds = get_el_bounds n.el
 915                         return unless bounds?
 916                         if bounds.x is prev_bounds.x and bounds.y is prev_bounds.y and bounds.w is prev_bounds.w and bounds.h is prev_bounds.h
 917                                 n = n.parent
 918                                 continue
 919                         matt = domify @outer_idoc, div: class: 'ann_box', style: "left: #{bounds.x - 1 + overlay_padding}px; top: #{bounds.y - 2 + overlay_padding}px; width: #{bounds.w}px; height: #{bounds.h}px" # outline: 1000px solid rgba(0,153,255,#{alpha});
 920                         @overlay.appendChild matt
 921                         @matting.push matt
 922                         ann = domify @outer_idoc, div: class: 'ann_tag', style: "left: #{bounds.x + 1 + overlay_padding}px; top: #{bounds.y - 7 + overlay_padding}px", children: [domify @outer_idoc, text: " #{n.name} "]
 923                         @overlay.appendChild ann
 924                         @matting.push ann
 925                         n = n.parent
 926                         alpha *= 1.5
 927         pretty_html: (tree, indent = '', parent_flags = pre_ish: false, block: true, want_nl: false) ->
 928                 ret = ''
 929                 want_nl = parent_flags.want_nl
 930                 prev_in_flow_is_text = false
 931                 prev_in_flow_is_block = false
 932                 for n, i in tree
 933                         # figure out flags
 934                         inner_flags = want_nl: true
 935                         is_br = false
 936                         switch n.type
 937                                 when 'tag'
 938                                         if n.name is 'br'
 939                                                 is_br = true
 940                                         is_text = false
 941                                         if n.el.currentStyle?
 942                                                 cs = n.el.currentStyle
 943                                                 whitespace = cs['white-space']
 944                                                 display = cs['display']
 945                                                 position = cs['position']
 946                                                 float = cs['float']
 947                                                 visibility = cs['visibility']
 948                                         else
 949                                                 cs = @iframe.contentWindow.getComputedStyle(n.el, null)
 950                                                 whitespace = cs.getPropertyValue 'white-space'
 951                                                 display = cs.getPropertyValue 'display'
 952                                                 position = cs.getPropertyValue 'position'
 953                                                 float = cs.getPropertyValue 'float'
 954                                                 visibility = cs.getPropertyValue 'visibility'
 955                                         if n.name is 'textarea'
 956                                                 inner_flags.pre_ish = true
 957                                         else
 958                                                 inner_flags.pre_ish = whitespace.substr(0, 3) is 'pre'
 959                                         switch float
 960                                                 when 'left', 'right'
 961                                                         in_flow = false
 962                                                 else
 963                                                         switch position
 964                                                                 when 'absolute', 'fixed'
 965                                                                         in_flow = false
 966                                                                 else
 967                                                                         if 'display' is 'none'
 968                                                                                 in_flow = false
 969                                                                         else
 970                                                                                 switch visibility
 971                                                                                         when 'hidden', 'collapse'
 972                                                                                                 in_flow = false
 973                                                                                         else # visible
 974                                                                                                 in_flow = true
 975                                         switch display
 976                                                 when 'inline', 'none'
 977                                                         inner_flags.block = false
 978                                                         is_block = in_flow_block = false
 979                                                 when 'inline-black'
 980                                                         inner_flags.block = true
 981                                                         is_block = in_flow_block = false
 982                                                 else # block, table, etc
 983                                                         inner_flags.block = true
 984                                                         is_block = true
 985                                                         in_flow_block = in_flow
 986                                 when 'text'
 987                                         is_text = true
 988                                         is_block = false
 989                                         in_flow = true
 990                                         in_flow_block = false
 991                                 else # 'comment', 'doctype'
 992                                         is_text = false
 993                                         is_block = false
 994                                         in_flow = false
 995                                         in_flow_block = false
 996                         # print whitespace if we can
 997                         unless parent_flags.pre_ish
 998                                 unless prev_in_flow_is_text and is_br
 999                                         if (i is 0 and parent_flags.block) or in_flow_block or prev_in_flow_is_block
1000                                                 if want_nl
1001                                                         ret += "\n"
1002                                                 ret += indent
1003                         switch n.type
1004                                 when 'tag'
1005                                         ret += '<' + n.name
1006                                         attr_keys = []
1007                                         for k of n.attrs
1008                                                 attr_keys.unshift k
1009                                         #attr_keys.sort()
1010                                         for k in attr_keys
1011                                                 ret += " #{k}"
1012                                                 if n.attrs[k].length > 0
1013                                                         ret += "=\"#{enc_attr n.attrs[k]}\""
1014                                         ret += '>'
1015                                         unless void_elements[n.name]?
1016                                                 if inner_flags.block
1017                                                         next_indent = indent + '    '
1018                                                 else
1019                                                         next_indent = indent
1020                                                 if n.children.length
1021                                                         ret += @pretty_html n.children, next_indent, inner_flags
1022                                                 ret += "</#{n.name}>"
1023                                 when 'text'
1024                                         ret += enc_text n.text
1025                                 when 'comment'
1026                                         ret += "<!--#{n.text}-->" # TODO encode?
1027                                 when 'doctype'
1028                                         ret += "<!DOCTYPE #{n.name}"
1029                                         if n.public_identifier? and n.public_identifier.length > 0
1030                                                 ret += " \"#{n.public_identifier}\""
1031                                         if n.system_identifier? and n.system_identifier.length > 0
1032                                                 ret += " \"#{n.system_identifier}\""
1033                                         ret += ">"
1034                         want_nl = true
1035                         if in_flow
1036                                 prev_in_flow_is_text = is_text
1037                                 prev_in_flow_is_block = is_block or (in_flow and is_br)
1038                 if tree.length
1039                         # output final newline if allowed
1040                         unless parent_flags.pre_ish
1041                                 if prev_in_flow_is_block or parent_flags.block
1042                                         ret += "\n#{indent.substr 4}"
1043                 return ret
1044         onblur: ->
1045                 @kill_cursor()
1046         have_focus: ->
1047                 @editor_is_focused = true
1048                 @poll_for_blur()
1049         poll_for_blur: ->
1050                 return if @poll_for_blur_timeout? # already polling
1051                 @poll_for_blur_timeout = timeout 150, =>
1052                         next_frame => # pause polling when browser knows we're not active/visible/etc.
1053                                 @poll_for_blur_timeout = null
1054                                 if document.activeElement is @outer_iframe
1055                                         @poll_for_blur()
1056                                 else
1057                                         @editor_is_focused = false
1058                                         @onblur()
1059
1060 window.peach_html5_editor = (args...) ->
1061         return new PeachHTML5Editor args...
1062
1063 # test in browser: peach_html5_editor(document.getElementsByTagName('textarea')[0])