editor.coffee

   1 # Copyright 2015 Jason Woofenden
   2 # This file implements an WYSIWYG editor in the browser (no contenteditable)
   3 #
   4 # This program is free software: you can redistribute it and/or modify it under
   5 # the terms of the GNU Affero General Public License as published by the Free
   6 # Software Foundation, either version 3 of the License, or (at your option) any
   7 # later version.
   8 #
   9 # This program is distributed in the hope that it will be useful, but WITHOUT
  10 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  11 # FOR A PARTICULAR PURPOSE.  See the GNU Affero General Public License for more
  12 # details.
  13 #
  14 # You should have received a copy of the GNU Affero General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16
  17 # SETTINGS
  18 overlay_padding = 10
  19
  20 TYPE_TAG = peach_parser.TYPE_TAG
  21 TYPE_TEXT = peach_parser.TYPE_TEXT
  22 TYPE_COMMENT = peach_parser.TYPE_COMMENT
  23 TYPE_DOCTYPE = peach_parser.TYPE_DOCTYPE
  24
  25 debug_dot_at = (doc, x, y) ->
  26         return # disabled
  27         el = doc.createElement 'div'
  28         el.setAttribute 'style', "position: absolute; left: #{x}px; top: #{y}px; width: 1px; height: 3px; background-color: red"
  29         doc.body.appendChild el
  30         #console.log(new Error().stack)
  31
  32 # text nodes don't have getBoundingClientRect(), so use selection api to find
  33 # it.
  34 get_el_bounds = (el) ->
  35         if el.getBoundingClientRect?
  36                 rect = el.getBoundingClientRect()
  37         else
  38                 # text nodes don't have getBoundingClientRect(), so use range api
  39                 range = el.ownerDocument.createRange()
  40                 range.selectNodeContents el
  41                 rect = range.getBoundingClientRect()
  42         doc = el.ownerDocument.documentElement
  43         win = el.ownerDocument.defaultView
  44         y_fix = win.pageYOffset - doc.clientTop
  45         x_fix = win.pageXOffset - doc.clientLeft
  46         return {
  47                 x: rect.left + x_fix
  48                 y: rect.top + y_fix
  49                 w: rect.width ? (rect.right - rect.left)
  50                 h: rect.height ? (rect.top - rect.bottom)
  51         }
  52
  53 is_display_block = (el) ->
  54         if el.currentStyle?
  55                 return el.currentStyle.display is 'block'
  56         else
  57                 return window.getComputedStyle(el, null).getPropertyValue('display') is 'block'
  58
  59 # Pass return value from dom event handlers to this.
  60 # If they return false, this will addinionally stop propagation and default.
  61 event_return = (e, bool) ->
  62         if bool is false
  63                 if e.stopPropagation?
  64                         e.stopPropagation()
  65                 if e.preventDefault?
  66                         e.preventDefault()
  67         return bool
  68 # Warning: currently assumes you're asking about a single character
  69 # Note: chromium returns multiple bounding rects for a space at a line-break
  70 # Note: chromium's getBoundingClientRect() is broken (when zero-area client rects)
  71 # Note: sometimes returns null (eg for whitespace that is not visible)
  72 text_range_bounds = (el, start, end) ->
  73         range = document.createRange()
  74         range.setStart el, start
  75         range.setEnd el, end
  76         rects = range.getClientRects()
  77         if rects.length > 0
  78                 rect = rects[0]
  79         else
  80                 return null
  81         doc = el.ownerDocument.documentElement
  82         win = el.ownerDocument.defaultView
  83         y_fix = win.pageYOffset - doc.clientTop
  84         x_fix = win.pageXOffset - doc.clientLeft
  85         return {
  86                 x: rect.left + x_fix
  87                 y: rect.top + y_fix
  88                 w: rect.width ? (rect.right - rect.left)
  89                 h: rect.height ? (rect.top - rect.bottom)
  90                 rects: rects
  91                 bounding: range.getBoundingClientRect()
  92         }
  93
  94 # figure out the x/y coordinates of where the cursor should be if it's at
  95 # position ``i`` within text node ``n``
  96 # sometimes returns null (eg for whitespace that is not visible)
  97 window.cursor_to_xyh = cursor_to_xyh = (n, i) ->
  98         range = document.createRange()
  99         if n.text.length is 0
 100                 ret = text_range_bounds n.el, 0, 0
 101         else if i is n.text.length
 102                 ret = text_range_bounds n.el, i - 1, i
 103                 if ret?
 104                         ret.x += ret.w
 105         else
 106                 ret = text_range_bounds n.el, i, i + 1
 107         if ret?
 108                 debug_dot_at n.el.ownerDocument, ret.x, ret.y
 109         return ret
 110
 111 # encode text so it can be safely placed inside an html attribute
 112 enc_attr_regex = new RegExp '(&)|(")|(\u00A0)', 'g'
 113 enc_attr = (txt) ->
 114         return txt.replace enc_attr_regex, (match, amp, quote) ->
 115                 return '&amp;' if (amp)
 116                 return '&quot;' if (quote)
 117                 return '&nbsp;'
 118 enc_text_regex = new RegExp '(&)|(<)|(\u00A0)', 'g'
 119 enc_text = (txt) ->
 120         return txt.replace enc_text_regex, (match, amp, lt) ->
 121                 return '&amp;' if (amp)
 122                 return '&lt;' if (lt)
 123                 return '&nbsp;'
 124
 125 void_elements = {
 126         area: true
 127         base: true
 128         br: true
 129         col: true
 130         embed: true
 131         hr: true
 132         img: true
 133         input: true
 134         keygen: true
 135         link: true
 136         meta: true
 137         param: true
 138         source: true
 139         track: true
 140         wbr: true
 141 }
 142 dom_to_html = (dom) ->
 143         ret = ''
 144         for el in dom
 145                 switch el.type
 146                         when TYPE_TAG
 147                                 ret += '<' + el.name
 148                                 attr_keys = []
 149                                 for k of el.attrs
 150                                         attr_keys.unshift k
 151                                 #attr_keys.sort()
 152                                 for k in attr_keys
 153                                         ret += " #{k}"
 154                                         if el.attrs[k].length > 0
 155                                                 ret += "=\"#{enc_attr el.attrs[k]}\""
 156                                 ret += '>'
 157                                 unless void_elements[el.name]
 158                                         if el.children.length
 159                                                 ret += dom_to_html el.children
 160                                         ret += "</#{el.name}>"
 161                         when TYPE_TEXT
 162                                 ret += enc_text el.text
 163                         when TYPE_COMMENT
 164                                 ret += "<!--#{el.text}-->"
 165                         when TYPE_DOCTYPE
 166                                 ret += "<!DOCTYPE #{el.name}"
 167                                 if el.public_identifier? and el.public_identifier.length > 0
 168                                         ret += " \"#{el.public_identifier}\""
 169                                 if el.system_identifier? and el.system_identifier.length > 0
 170                                         ret += " \"#{el.system_identifier}\""
 171                                 ret += ">\n"
 172         return ret
 173
 174 domify = (doc, hash) ->
 175         for tag, attrs of hash
 176                 if tag is 'text'
 177                         return document.createTextNode attrs
 178                 el = document.createElement tag
 179                 for k, v of attrs
 180                         if k is 'children'
 181                                 for child in v
 182                                         el.appendChild child
 183                         else
 184                                 el.setAttribute k, v
 185         return el
 186
 187 outer_css = (args) ->
 188         w = args.w ? 300
 189         h = args.h ? 300
 190         inner_padding = args.inner_padding ? overlay_padding
 191         frame_width = args.frame_width ? inner_padding
 192         # TODO editor controls height...
 193         occupy = (left, top = left, right = left, bottom = top) ->
 194                 w -= left + right
 195                 h -= top + bottom
 196                 return Math.max(left, top, right, bottom)
 197         ret = ''
 198         ret += 'body {'
 199         ret +=     'margin: 0;'
 200         ret +=     'padding: 0;'
 201         ret += '}'
 202         ret += '#wrap1 {'
 203         ret +=     "border: #{occupy 1}px solid black;"
 204         ret +=     "padding: #{occupy frame_width}px;"
 205         ret += '}'
 206         ret += '#wrap2 {'
 207         ret +=     "border: #{occupy 1}px solid black;"
 208         ret +=     "padding: #{occupy inner_padding}px;"
 209         ret +=     "padding-right: #{inner_padding + occupy 0, 0, 15, 0}px;" # for scroll bar
 210         ret +=     "width: #{w}px;"
 211         ret +=     "height: #{h}px;"
 212         ret +=     'overflow-x: hidden;'
 213         ret +=     'overflow-y: scroll;'
 214         ret += '}'
 215         ret += '#wrap3 {'
 216         ret +=     'position: relative;'
 217         ret +=     "width: #{w}px;"
 218         ret +=     "min-height: #{h}px;"
 219         ret += '}'
 220         ret += 'iframe {'
 221         ret +=     'box-sizing: border-box;'
 222         ret +=     'margin: 0;'
 223         ret +=     'border: none;'
 224         ret +=     'padding: 0;'
 225         ret +=     "width: #{w}px;"
 226         #ret +=     "height: #{h}px;" # height auto-set when content set/changed
 227         ret +=     '-ms-user-select: none;'
 228         ret +=     '-webkit-user-select: none;'
 229         ret +=     '-moz-user-select: none;'
 230         ret +=     'user-select: none;'
 231         ret += '}'
 232         ret += '#overlay {'
 233         ret +=     'position: absolute;'
 234         ret +=     "left: -#{inner_padding}px;"
 235         ret +=     "top: -#{inner_padding}px;"
 236         ret +=     "right: -#{inner_padding}px;"
 237         ret +=     "bottom: -#{inner_padding}px;"
 238         ret +=     'overflow: hidden;'
 239         ret += '}'
 240         ret += '.lightbox {'
 241         ret +=     'position: absolute;'
 242         ret +=     'background: rgba(100,100,100,0.2);'
 243         ret += '}'
 244         ret += '#cursor {'
 245         ret +=     'position: absolute;'
 246         ret +=     'height: 1em;' # FIXME adjust for hight of text
 247         ret +=     'width: 2px;'
 248         ret +=     'background: #444;'
 249         ret +=     '-webkit-animation: blink 1s steps(2, start) infinite;'
 250         ret +=     'animation: blink 1s steps(2, start) infinite;'
 251         ret += '}'
 252         ret += '@-webkit-keyframes blink {'
 253         ret +=     'to { visibility: hidden; }'
 254         ret += '}'
 255         ret += '@keyframes blink {'
 256         ret +=     'to { visibility: hidden; }'
 257         ret += '}'
 258         return ret
 259
 260 # key codes:
 261 KEY_LEFT = 37
 262 KEY_UP = 38
 263 KEY_RIGHT = 39
 264 KEY_DOWN = 40
 265 KEY_BACKSPACE = 8 # <--
 266 KEY_DELETE = 46 # -->
 267 KEY_END = 35
 268 KEY_ENTER = 13
 269 KEY_ESCAPE = 27
 270 KEY_HOME = 36
 271 KEY_INSERT = 45
 272 KEY_PAGE_UP = 33
 273 KEY_PAGE_DOWN = 34
 274 KEY_TAB = 9
 275
 276 ignore_key_codes =
 277         '18': true # alt
 278         '20': true # capslock
 279         '17': true # ctrl
 280         '144': true # numlock
 281         '16': true # shift
 282         '91': true # windows "start" key
 283 control_key_codes = # we react to these, but they aren't typing
 284         '37': KEY_LEFT
 285         '38': KEY_UP
 286         '39': KEY_RIGHT
 287         '40': KEY_DOWN
 288         '35': KEY_END
 289         '8':  KEY_BACKSPACE
 290         '46': KEY_DELETE
 291         '13': KEY_ENTER
 292         '27': KEY_ESCAPE
 293         '36': KEY_HOME
 294         '45': KEY_INSERT
 295         '33': KEY_PAGE_UP
 296         '34': KEY_PAGE_DOWN
 297         '9':  KEY_TAB
 298
 299 instantiate_tree = (tree, parent) ->
 300         remove = []
 301         for c, i in tree
 302                 switch c.type
 303                         when TYPE_TEXT
 304                                 c.el = parent.ownerDocument.createTextNode c.text
 305                                 parent.appendChild c.el
 306                         when TYPE_TAG
 307                                 if c.name in ['script', 'object', 'iframe', 'link']
 308                                         # TODO put placeholders instead
 309                                         remove.unshift i
 310                                 # TODO create in correct namespace
 311                                 c.el = parent.ownerDocument.createElement c.name
 312                                 for k, v of c.attrs
 313                                         # FIXME if attr_whitelist[k]?
 314                                         c.el.setAttribute k, v
 315                                 parent.appendChild c.el
 316                                 if c.children.length
 317                                         instantiate_tree c.children, c.el
 318         for i in remove
 319                 tree.splice i, 1
 320
 321 traverse_tree = (tree, state, cb) ->
 322         for c in tree
 323                 cb c, state
 324                 break if state.done?
 325                 if c.children.length
 326                         traverse_tree c.children, state, cb
 327                         break if state.done?
 328         return state
 329 # find the next element in tree (and decendants) that is after n and can contain text
 330 # TODO make it so cursor can go places that don't have text but could
 331 find_next_cursor_position = (tree, n, i) ->
 332         if n? and n.type is TYPE_TEXT and n.text.length > i
 333                 orig_xyh = cursor_to_xyh n, i
 334                 unless orig_xyh?
 335                         console.log "ERROR: couldn't find xy for current cursor location"
 336                         return
 337                 for next_i in [i+1 .. n.text.length] # inclusive is valid (after last char)
 338                         next_xyh = cursor_to_xyh n, next_i
 339                         if next_xyh?
 340                                 if next_xyh.x > orig_xyh.x or next_xyh.y > orig_xyh.y
 341                                         return [n, next_i]
 342         found = traverse_tree tree, before: n?, (node, state) ->
 343                 if node.type is TYPE_TEXT and state.before is false
 344                         state.node = node
 345                         state.done = true
 346                 if node is n
 347                         state.before = false
 348         if found.node?
 349                 return [found.node, 0]
 350         return null
 351
 352 # TODO make it so cursor can go places that don't have text but could
 353 find_prev_cursor_position = (tree, n, i) ->
 354         if n? and n.type is TYPE_TEXT and i > 0
 355                 orig_xyh = cursor_to_xyh n, i
 356                 unless orig_xyh?
 357                         console.log "ERROR: couldn't find xy for current cursor location"
 358                         return
 359                 for prev_i in [i-1 .. 0]
 360                         prev_xyh = cursor_to_xyh n, prev_i
 361                         if prev_xyh?
 362                                 if prev_xyh.x < orig_xyh.x or prev_xyh.y < orig_xyh.y
 363                                         return [n, prev_i]
 364                 return [n, i - 1]
 365         found = traverse_tree tree, before: n?, (node, state) ->
 366                 if node.type is TYPE_TEXT
 367                         unless n?
 368                                 state.node = node
 369                                 state.done = true
 370                         if node is n
 371                                 if state.prev?
 372                                         state.node = state.prev
 373                                 state.done = true
 374                         if node
 375                                 state.prev = node
 376         if found.node?
 377                 return [found.node, found.node.text.length]
 378         return null
 379
 380 find_loc_cursor_position = (tree, loc) ->
 381         for c in tree
 382                 if c.type is TYPE_TAG or c.type is TYPE_TEXT
 383                         bounds = get_el_bounds c.el
 384                         continue if loc.x < bounds.x
 385                         continue if loc.x > bounds.x + bounds.w
 386                         continue if loc.y < bounds.y
 387                         continue if loc.y > bounds.y + bounds.h
 388                         if c.children.length
 389                                 ret = find_loc_cursor_position c.children, loc
 390                                 return ret if ret?
 391                         if c.type is TYPE_TEXT
 392                                 # click is within bounding box that contains all text.
 393                                 return [c, 0] if c.text.length is 0
 394                                 before_i = 0
 395                                 before = cursor_to_xyh c, before_i
 396                                 unless before?
 397                                         console.log "error: failed to find cursor pixel location for start of", c
 398                                         return
 399                                 after_i = c.text.length
 400                                 after = cursor_to_xyh c, after_i
 401                                 unless after?
 402                                         console.log "error: failed to find cursor pixel location for end of", c
 403                                         return
 404                                 if loc.y < before.y + before.h and loc.x < before.x
 405                                         # console.log 'before first char on first line'
 406                                         continue
 407                                 if loc.y > after.y and loc.x > after.x
 408                                         # console.log 'after last char on last line'
 409                                         continue
 410                                 if loc.y < before.y
 411                                         console.log "Warning: click in bounding box but above first line"
 412                                         continue # above first line (runaround?)
 413                                 if loc.y > after.y + after.h
 414                                         console.log "Warning: click in bounding box but below last line", loc.y, after.y, after.h
 415                                         continue # below last line (shouldn't happen?)
 416                                 while after_i - before_i > 1
 417                                         cur_i = Math.round((before_i + after_i) / 2)
 418                                         cur = cursor_to_xyh c, cur_i
 419                                         unless loc?
 420                                                 console.log "error: failed to find cursor pixel location for", c, cur_i
 421                                                 return
 422                                         if loc.y < cur.y or (loc.y <= cur.y + cur.h and loc.x < cur.x)
 423                                                 after_i = cur_i
 424                                                 after = cur
 425                                         else
 426                                                 before_i = cur_i
 427                                                 before = cur
 428                                 # which one is closest?
 429                                 if Math.abs(before.x - loc.x) < Math.abs(after.x - loc.x)
 430                                         return [c, before_i]
 431                                 else
 432                                         return [c, after_i]
 433         return null
 434
 435 # browsers collapse these (html5 spec calls these "space characters")
 436 is_space_code = (char_code) ->
 437         switch char_code
 438                 when 9, 10, 12, 13, 32
 439                         return true
 440         return false
 441 is_space = (chr) ->
 442         return is_space_code chr.charCodeAt 0
 443
 444 # pass a array of nodes (from parser library, ie it should have .el and .text)
 445 tree_dedup_space = (tree) ->
 446         prev = cur = next = null
 447         prev_i = cur_i = next_i = 0
 448         prev_pos = pos = next_pos = null
 449         prev_px = cur_px = next_px = null
 450         first = true
 451         removed_char = null
 452
 453         iterate = (tree, cb) ->
 454                 for n in tree
 455                         if n.type is TYPE_TEXT
 456                                 i = 0
 457                                 while i < n.text.length # don't foreach, cb might remove chars
 458                                         advance = cb n, i
 459                                         if advance
 460                                                 i += 1
 461                         if n.type is TYPE_TAG
 462                                 block = is_display_block n.el
 463                                 if block
 464                                         cb null
 465                                 if n.children.length > 0
 466                                         iterate n.children, cb
 467                                 if block
 468                                         cb null
 469         # remove cur char
 470         remove = ->
 471                 removed_char = cur.text.charAt(cur_i)
 472                 cur.el.textContent = cur.text = (cur.text.substr 0, cur_i) + (cur.text.substr cur_i + 1)
 473                 if next is cur # in same text node
 474                         if next_i is 0
 475                                 throw "how is this possible?"
 476                         next_i -= 1
 477                 return true
 478         # undo remove()
 479         put_it_back = ->
 480                 cur.el.textContent = cur.text = (cur.text.substr 0, cur_i) + removed_char + (cur.text.substr cur_i)
 481                 if next is cur # in same text node
 482                         next_i += 1
 483                 return false
 484         # return true if cur was removed from the dom (ie re-use same prev)
 485         operate = ->
 486                 # cur definitately set
 487                 # prev and/or next might be null, indicating the start/end of a display:block
 488                 return false unless is_space_code cur.text.charCodeAt cur_i
 489                 bounds = text_range_bounds cur.el, cur_i, cur_i + 1
 490                 # consistent cases:
 491                 # 1. zero rects returned by getClientRects() means collapsed space
 492                 if bounds is null
 493                         return remove()
 494                 # 2. width greater than zero means visible space
 495                 if bounds.w > 0
 496                         return false
 497                 # now the weird edge cases...
 498                 #
 499                 # firefox and chromium both report zero width for characters at the end
 500                 # of a line where the text wraps (automatically, due to word-wrap) to
 501                 # the next line. These do not appear to be distinguishable from
 502                 # collapsed spaces via the range/bounds api, so...
 503                 #
 504                 # remove it from the dom, and if prev or next moves, put it back.
 505                 if prev? and not prev_px?
 506                         prev_px = cursor_to_xyh prev, prev_i
 507                 if next? and not next_px?
 508                         next_px = cursor_to_xyh next, next_i
 509                 #if prev is null and next is null
 510                 #       parent_px = cur.parent.el.getBoundingClientRect()
 511                 remove()
 512                 if prev?
 513                         if prev_px?
 514                                 new_prev_px = cursor_to_xyh prev, prev_i
 515                                 if new_prev_px.x isnt prev_px.x or new_prev_px.y isnt prev_px.y
 516                                         return put_it_back()
 517                         else
 518                                 console.log "this shouldn't happen, we remove spaces that don't locate"
 519                 if next?
 520                         if next_px?
 521                                 new_next_px = cursor_to_xyh next, next_i
 522                                 if new_next_px.x isnt next_px.x or new_next_px.y isnt next_px.y
 523                                         return put_it_back()
 524                         #else
 525                         #       console.log "removing space becase space after it is collapsed"
 526                 # if there's no prev or next (single space inside a block-level element?) check
 527                 # TODO scrapt this, or fix it so it works when there's no parent
 528                 # if prev is null and next is null
 529                 #       new_parent_px = cur.parent.el.getBoundingClientRect()
 530                 #       if new_parent_px.left isnt parent_px.left or new_parent_px.top isnt parent_px.top or new_parent_px.right isnt parent_px.right or new_parent_px.bottom isnt parent_px.bottom
 531                 #               console.log "WEIRD: parent moved"
 532                 #               return put_it_back()
 533                 # we didn't put it back
 534                 return true
 535         # pass null at start/end of display:block
 536         queue = (n, i) ->
 537                 next = n
 538                 next_i = i
 539                 next_px = null
 540                 advance = true
 541                 if cur?
 542                         removed = operate()
 543                         # don't advance (to the next character next time) if we removed a
 544                         # character from the same text node as ``next``, because doing so
 545                         # renumbers the indexes in that string
 546                         if removed and cur is next
 547                                 advance = false
 548                 else
 549                         removed = false
 550                 unless removed
 551                         prev = cur
 552                         prev_i = cur_i
 553                         prev_px = cur_px
 554                 cur = next
 555                 cur_i = next_i
 556                 cur_px = next_px
 557                 return advance
 558         queue null
 559         iterate tree, queue
 560         queue null
 561
 562 class PeachHTML5Editor
 563         # Options: (all optional)
 564         #   editor_id: "id" attribute for outer-most element created by/for editor
 565         #   on_init: callback for when the editable content is in place
 566         constructor: (in_el, options) ->
 567                 @options = options ? {}
 568                 @in_el = in_el
 569                 @tree = []
 570                 @inited = false # when iframes have loaded
 571                 @outer_iframe # iframe to hold editor
 572                 @outer_idoc # "document" object for @outer_iframe
 573                 @iframe = null # iframe to hold editable content
 574                 @idoc = null # "document" object for @iframe
 575                 @cursor = null
 576                 @cursor_el = null
 577                 @cursor_visible = false
 578                 opt_fragment = @options.fragment ? true
 579                 @parser_opts = {}
 580                 if opt_fragment
 581                         @parser_opts.fragment = 'body'
 582
 583                 @outer_iframe = domify document, iframe: {}
 584                 outer_iframe_style = 'border: none !important; margin: 0 !important; padding: 0 !important; height: 100% !important; width: 100% !important;'
 585                 if @options.editor_id?
 586                         @outer_iframe.setAttribute 'id', @options.editor_id
 587                 @outer_iframe.onload = =>
 588                         @outer_idoc = @outer_iframe.contentDocument
 589                         icss = domify @outer_idoc, style: children: [
 590                                 domify @outer_idoc, text: css
 591                         ]
 592                         @outer_idoc.head.appendChild icss
 593                         @iframe = domify @outer_idoc, iframe: {}
 594                         @iframe.onload = =>
 595                                 @init()
 596                         setTimeout (=> @init() unless @inited), 200 # firefox never fires this onload
 597                         @outer_idoc.body.appendChild(
 598                                 domify @outer_idoc, div: id: 'wrap1', children: [
 599                                         domify @outer_idoc, div: id: 'wrap2', children: [
 600                                                 domify @outer_idoc, div: id: 'wrap3', children: [
 601                                                         @iframe
 602                                                         @overlay = domify @outer_idoc, div: id: 'overlay'
 603                                                 ]
 604                                         ]
 605                                 ]
 606                         )
 607                 outer_wrap = domify document, div: class: 'peach_html5_editor'
 608                 @in_el.parentNode.appendChild outer_wrap
 609                 outer_bounds = get_el_bounds outer_wrap
 610                 if outer_bounds.w < 300
 611                         outer_bounds.w = 300
 612                 if outer_bounds.h < 300
 613                         outer_bounds.h = 300
 614                 outer_iframe_style += "width: #{outer_bounds.w}px; height: #{outer_bounds.h}px;"
 615                 @outer_iframe.setAttribute 'style', outer_iframe_style
 616                 css = outer_css w: outer_bounds.w, h: outer_bounds.h
 617                 outer_wrap.appendChild @outer_iframe
 618         init: -> # called by @iframe's onload (or timeout on firefox)
 619                 @idoc = @iframe.contentDocument
 620                 @overlay.onclick = (e) =>
 621                         return event_return @onclick e
 622                 @overlay.ondoubleclick = (e) =>
 623                         return event_return @ondoubleclick e
 624                 @outer_idoc.body.onkeyup = (e) =>
 625                         return event_return @onkeyup e
 626                 @outer_idoc.body.onkeydown = (e) =>
 627                         return event_return @onkeydown e
 628                 @outer_idoc.body.onkeypress = (e) =>
 629                         return event_return @onkeypress e
 630                 if @options.stylesheet
 631                         # TODO test this
 632                         @idoc.head.appendChild domify @idoc, style: src: @options.stylesheet
 633                 @load_html @in_el.value
 634                 @inited = true
 635                 if @options.on_init?
 636                         @options.on_init()
 637         onclick: (e) ->
 638                 x = (e.offsetX ? e.layerX) - overlay_padding
 639                 y = (e.offsetY ? e.layerY) - overlay_padding
 640                 new_cursor = find_loc_cursor_position @tree, x: x, y: y
 641                 if new_cursor?
 642                         @move_cursor new_cursor
 643                 return false
 644         ondoubleclick: (e) ->
 645                 return false
 646         onkeyup: (e) ->
 647                 return if e.ctrlKey
 648                 return false if ignore_key_codes[e.keyCode]?
 649                 #return false if control_key_codes[e.keyCode]?
 650         onkeydown: (e) ->
 651                 return if e.ctrlKey
 652                 return false if ignore_key_codes[e.keyCode]?
 653                 #return false if control_key_codes[e.keyCode]?
 654                 switch e.keyCode
 655                         when KEY_LEFT
 656                                 if @cursor?
 657                                         new_cursor = find_prev_cursor_position @tree, @cursor...
 658                                         if new_cursor?
 659                                                 @move_cursor new_cursor
 660                                 else
 661                                         for c in @tree
 662                                                 new_cursor = find_next_cursor_position @tree, c, -1
 663                                                 if new_cursor?
 664                                                         @move_cursor new_cursor
 665                                                         break
 666                                 return false
 667                         when KEY_UP
 668                                 return false
 669                         when KEY_RIGHT
 670                                 if @cursor?
 671                                         new_cursor = find_next_cursor_position @tree, @cursor...
 672                                         if new_cursor?
 673                                                 @move_cursor new_cursor
 674                                 else
 675                                         for c in @tree
 676                                                 new_cursor = find_prev_cursor_position @tree, c, -1
 677                                                 if new_cursor?
 678                                                         @move_cursor new_cursor
 679                                                         break
 680                                 return false
 681                         when KEY_DOWN
 682                                 return false
 683                         when KEY_END
 684                                 return false
 685                         when KEY_BACKSPACE
 686                                 return false unless @cursor?
 687                                 return false unless @cursor[1] > 0
 688                                 @cursor[0].text = @cursor[0].text.substr(0, @cursor[1] - 1) + @cursor[0].text.substr(@cursor[1])
 689                                 @cursor[0].el.nodeValue = @cursor[0].text
 690                                 @move_cursor [@cursor[0], @cursor[1] - 1]
 691                                 return false
 692                         when KEY_DELETE
 693                                 return false unless @cursor?
 694                                 return false unless @cursor[1] < @cursor[0].text.length
 695                                 @cursor[0].text = @cursor[0].text.substr(0, @cursor[1]) + @cursor[0].text.substr(@cursor[1] + 1)
 696                                 @cursor[0].el.nodeValue = @cursor[0].text
 697                                 @move_cursor [@cursor[0], @cursor[1]]
 698                                 return false
 699                         when KEY_ENTER
 700                                 return false
 701                         when KEY_ESCAPE
 702                                 return false
 703                         when KEY_HOME
 704                                 return false
 705                         when KEY_INSERT
 706                                 return false
 707                         when KEY_PAGE_UP
 708                                 return false
 709                         when KEY_PAGE_DOWN
 710                                 return false
 711                         when KEY_TAB
 712                                 return false
 713         onkeypress: (e) ->
 714                 return if e.ctrlKey
 715                 return false if ignore_key_codes[e.keyCode]?
 716                 return false if control_key_codes[e.keyCode]? # handled in keydown
 717                 char = e.charCode ? e.keyCode
 718                 if char and @cursor?
 719                         char = String.fromCharCode char
 720                         if @cursor[1] is 0
 721                                 @cursor[0].text = char + @cursor[0].text
 722                         else if @cursor[1] is @cursor[0].text.length - 1
 723                                 @cursor[0].text += char
 724                         else
 725                                 @cursor[0].text =
 726                                         @cursor[0].text.substr(0, @cursor[1]) +
 727                                         char +
 728                                         @cursor[0].text.substr(@cursor[1])
 729                         @cursor[0].el.nodeValue = @cursor[0].text
 730                         @move_cursor [@cursor[0], @cursor[1] + 1]
 731                         @changed()
 732                 return false
 733         clear_dom: -> # remove all the editable content (and cursor, overlays, etc)
 734                 while @idoc.body.childNodes.length
 735                         @idoc.body.removeChild @idoc.body.childNodes[0]
 736                 @kill_cursor()
 737                 return
 738         load_html: (html) ->
 739                 @tree = peach_parser.parse html, @parser_opts
 740                 @clear_dom()
 741                 instantiate_tree @tree, @idoc.body
 742                 tree_dedup_space @tree
 743                 @changed()
 744         changed: ->
 745                 # FIXME don't export cursor placeholder (when cursor is between space characters)
 746                 @in_el.onchange = null
 747                 @in_el.value = dom_to_html @tree
 748                 @in_el.onchange = =>
 749                         @load_html @in_el.value
 750                 @iframe.style.height = "0"
 751                 @iframe.style.height = "#{@idoc.body.scrollHeight}px"
 752         kill_cursor: -> # remove it, forget where it was
 753                 if @cursor_visible
 754                         @cursor_el.parentNode.removeChild @cursor_el
 755                         @cursor_visible = false
 756                 @cursor = null
 757         move_cursor: (cursor) ->
 758                 loc = cursor_to_xyh cursor[0], cursor[1]
 759                 unless loc?
 760                         console.log "error: tried to move cursor to position that has no pixel location", cursor[0], cursor[1]
 761                         return
 762                 @cursor = cursor
 763                 # replace cursor, to reset blink animation
 764                 if @cursor_visible
 765                         @cursor_el.parentNode.removeChild @cursor_el
 766                 @cursor_el = domify @outer_idoc, div: id: 'cursor'
 767                 @overlay.appendChild @cursor_el
 768                 @cursor_visible = true
 769                 # TODO figure out x,y coords for cursor
 770                 @cursor_el.style.left = "#{loc.x + overlay_padding - 1}px"
 771                 @cursor_el.style.top = "#{loc.y + overlay_padding}px"
 772
 773 window.peach_html5_editor = (args...) ->
 774         return new PeachHTML5Editor args...
 775
 776 # test in browser: peach_html5_editor(document.getElementsByTagName('textarea')[0])